summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
-rw-r--r--media-tv/kodi/Manifest8
-rw-r--r--media-tv/kodi/kodi-18.2.ebuild322
-rw-r--r--media-tv/kodi/metadata.xml28
3 files changed, 358 insertions, 0 deletions
diff --git a/media-tv/kodi/Manifest b/media-tv/kodi/Manifest
new file mode 100644
index 0000000..2d09631
--- /dev/null
+++ b/media-tv/kodi/Manifest
@@ -0,0 +1,8 @@
+DIST ffmpeg-kodi-4.0.3-Leia-18.2.tar.gz 12426917 BLAKE2B 83da9511d7b4ef6a8c813561a061c4fe86712e4424c30c9005500751c6c79f4232910caaf13cd34d2db1867f592b042dd291d6c32a77f80107ce87a3a7db1760 SHA512 b4d4bf16f05b953ba81769446c8fd90246e1919b9ef671fb212008151c83d8445e4123ad37c352aa6243074962832e817749d2de318eb721d5bb5d655fd77ab2
+DIST kodi-18.2-no-java-required.patch 991361 BLAKE2B ec58367d2ac378107bf84ab0b675a74f4eac620984811f50051e1fa0ccae5b52520eb106e3508c4bf4d98899a5068279370a2ddcebe33278d20642208d3a17e2 SHA512 8267f3ca7156c9498473ac33c24419f62541f68beffbb090a5e3da18fc6e9c32e509c10c91bc2721d07fc0d3ffc723966306d44cc0a00a51e363b1c24ac5d03f
+DIST kodi-18.2.tar.gz 51012621 BLAKE2B 363e7a36c236bec3a962a786ac1f2ba27cf45aa32046f5f66196e8ed4786631e00c525b4ddd975abd419b9fd1f5831aac52a18187cead8e54527cf67159859fb SHA512 7b63dc9c082f538690d28dd6da10999888af2b9de2e532bca54420753f64238f42e1c2aa0f7481c823e544260a1e4d68e1ba50f84db53307d08f0749992dff2f
+DIST libdvdcss-1.4.2-Leia-Beta-5.tar.gz 101068 BLAKE2B 283aa2cec0a2200d3569bc280cb9659e9224a6b3a77db8a35b269cd8caf1337ac9d8b92b806df66f63ef7458a46bd6261f0b8b14678b10e26644a79dcbeea5da SHA512 5185dbdbeb1bd13ea9d8723f1f4ab599d6f3102f5ba1096cd085aa1cda252c045f327c719227bba8e1b742352ade5e335106c8d0c1637a5a6b93ce661620dd7e
+DIST libdvdnav-6.0.0-Leia-Alpha-3.tar.gz 137942 BLAKE2B 7573434a0ae8e8ccabf48173f81fcde29074eb138e119a2ae9156cde3c3d8bfd716f5d0e605b97f2dcac21f570781137c8533c5ae306b51e3905822fda318355 SHA512 11c93eaacd156f8fd7dec7c43d366438b201f31ad55b2870463a9e286912b6ada08882319a021fb7992190f87b909a49f2b83e0321cc17aedc29f7fe5898fa72
+DIST libdvdread-6.0.0-Leia-Alpha-3.tar.gz 130649 BLAKE2B 0c206acdaf0776841ab792c74e023af07d9539eb72e03ae164382a31ed950f60e5e15f1d055979d28f1398924471b294d11f064b11b8373353b3962a3777ff3c SHA512 b3419ba0a1a2dd70f1bb6236afdfe1c6e88c9ad4264198b289e3bba9375e077cecf7f89848c7b09debaa445327f3507101f3d157e692f7a7163b2bb52643e1e7
+EBUILD kodi-18.2.ebuild 9510 BLAKE2B b2bb4da4f33df7ff70091c2577ac715d6f2f9b23002f27213afb0bd6ba17557f23833b292444d2b9fb939a9c3182dfa977e084e2f8ccd401a75c0ec713f3ac0c SHA512 e1c71c4f75e27eb69cda6214a0491a148e753a91e450cb89b3f1df36736543d7a89ab8094ab6349dbda856f69eba28888ac924d0495aa57e57d8715d282ec284
+MISC metadata.xml 1649 BLAKE2B c102ccbe3a0d3ca203b445b6ee98b6fd68e75678fd034bc72cdeebfb06c7afe85ab947cf1264d1ba64449a42d05ee3ab5334885f01b656582f69b1dbdb39d2a1 SHA512 caf69d7fc2ab53692ec44ba75bf7aef9adf3b85d768e4d930b8b7889971128aecd1c3e186ad48ccbe3970cd98e2ec3d3fd249f6b5d19513980bfc6f42c9b9f39
diff --git a/media-tv/kodi/kodi-18.2.ebuild b/media-tv/kodi/kodi-18.2.ebuild
new file mode 100644
index 0000000..ebb1bc4
--- /dev/null
+++ b/media-tv/kodi/kodi-18.2.ebuild
@@ -0,0 +1,322 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+: ${CMAKE_MAKEFILE_GENERATOR:=ninja}
+PYTHON_REQ_USE="libressl?,sqlite,ssl"
+LIBDVDCSS_VERSION="1.4.2-Leia-Beta-5"
+LIBDVDREAD_VERSION="6.0.0-Leia-Alpha-3"
+LIBDVDNAV_VERSION="6.0.0-Leia-Alpha-3"
+FFMPEG_VERSION="4.0.3"
+CODENAME="Leia"
+FFMPEG_KODI_VERSION="18.2"
+SRC_URI="https://github.com/xbmc/libdvdcss/archive/${LIBDVDCSS_VERSION}.tar.gz -> libdvdcss-${LIBDVDCSS_VERSION}.tar.gz
+ https://github.com/xbmc/libdvdread/archive/${LIBDVDREAD_VERSION}.tar.gz -> libdvdread-${LIBDVDREAD_VERSION}.tar.gz
+ https://github.com/xbmc/libdvdnav/archive/${LIBDVDNAV_VERSION}.tar.gz -> libdvdnav-${LIBDVDNAV_VERSION}.tar.gz
+ !system-ffmpeg? ( https://github.com/xbmc/FFmpeg/archive/${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz -> ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz )
+ https://dev.gentoo.org/~anarchy/patches/${P}-no-java-required.patch"
+
+if [[ ${PV} == *9999 ]] ; then
+ PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+ EGIT_REPO_URI="https://github.com/xbmc/xbmc.git"
+ inherit git-r3
+else
+ PYTHON_COMPAT=( python2_7 )
+ MY_PV=${PV/_p/_r}
+ MY_PV=${MY_PV/_alpha/a}
+ MY_PV=${MY_PV/_beta/b}
+ MY_PV=${MY_PV/_rc/rc}
+ MY_P="${PN}-${MY_PV}"
+ SRC_URI+=" https://github.com/xbmc/xbmc/archive/${MY_PV}-${CODENAME}.tar.gz -> ${MY_P}.tar.gz"
+ KEYWORDS="~amd64 ~x86"
+ S=${WORKDIR}/xbmc-${MY_PV}-${CODENAME}
+fi
+
+inherit autotools cmake-utils eutils gnome2-utils linux-info pax-utils python-single-r1 xdg-utils
+
+DESCRIPTION="A free and open source media-player and entertainment hub"
+HOMEPAGE="https://kodi.tv/ https://kodi.wiki/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+# use flag is called libusb so that it doesn't fool people in thinking that
+# it is _required_ for USB support. Otherwise they'll disable udev and
+# that's going to be worse.
+IUSE="airplay alsa bluetooth bluray caps cec +css dbus dvd gbm gles lcms libressl libusb lirc mariadb mysql nfs +opengl pulseaudio samba systemd +system-ffmpeg test +udev udisks upnp upower vaapi vdpau wayland webserver +X +xslt zeroconf"
+REQUIRED_USE="
+ ${PYTHON_REQUIRED_USE}
+ || ( gles opengl )
+ ^^ ( gbm wayland X )
+ ?? ( mariadb mysql )
+ udev? ( !libusb )
+ udisks? ( dbus )
+ upower? ( dbus )
+"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+ airplay? (
+ >=app-pda/libplist-2.0.0
+ net-libs/shairplay
+ )
+ alsa? ( >=media-libs/alsa-lib-1.1.4.1 )
+ bluetooth? ( net-wireless/bluez )
+ bluray? ( >=media-libs/libbluray-1.0.2 )
+ caps? ( sys-libs/libcap )
+ dbus? ( sys-apps/dbus )
+ dev-db/sqlite
+ dev-libs/expat
+ dev-libs/flatbuffers
+ >=dev-libs/fribidi-0.19.7
+ cec? ( >=dev-libs/libcec-4.0 )
+ dev-libs/libpcre[cxx]
+ >=dev-libs/libinput-1.10.5
+ >=dev-libs/libxml2-2.9.4
+ >=dev-libs/lzo-2.04
+ dev-libs/tinyxml[stl]
+ dev-python/pillow[${PYTHON_USEDEP}]
+ $(python_gen_cond_dep 'dev-python/pycryptodome[${PYTHON_USEDEP}]' 'python3*')
+ >=dev-libs/libcdio-0.94
+ dev-libs/libfmt
+ dev-libs/libfstrcmp
+ gbm? ( media-libs/mesa[gbm] )
+ gles? ( media-libs/mesa[gles2] )
+ lcms? ( media-libs/lcms:2 )
+ libusb? ( virtual/libusb:1 )
+ virtual/ttf-fonts
+ media-fonts/roboto
+ >=media-libs/fontconfig-2.12.4
+ >=media-libs/freetype-2.8
+ >=media-libs/libass-0.13.4
+ media-libs/mesa[egl]
+ >=media-libs/taglib-1.11.1
+ system-ffmpeg? (
+ >=media-video/ffmpeg-${FFMPEG_VERSION}:=[encode,postproc]
+ libressl? ( media-video/ffmpeg[libressl,-openssl] )
+ !libressl? ( media-video/ffmpeg[-libressl,openssl] )
+ )
+ mysql? ( dev-db/mysql-connector-c:= )
+ mariadb? ( dev-db/mariadb-connector-c:= )
+ >=net-misc/curl-7.56.1[http2]
+ nfs? ( >=net-fs/libnfs-2.0.0:= )
+ opengl? ( media-libs/glu )
+ !libressl? ( >=dev-libs/openssl-1.0.2l:0= )
+ libressl? ( dev-libs/libressl:0= )
+ pulseaudio? ( media-sound/pulseaudio )
+ samba? ( >=net-fs/samba-3.4.6[smbclient(+)] )
+ >=sys-libs/zlib-1.2.11
+ udev? ( virtual/udev )
+ vaapi? (
+ x11-libs/libva:=
+ opengl? ( x11-libs/libva[opengl] )
+ system-ffmpeg? ( media-video/ffmpeg[vaapi] )
+ vdpau? ( x11-libs/libva[vdpau] )
+ wayland? ( x11-libs/libva[wayland] )
+ X? ( x11-libs/libva[X] )
+ )
+ virtual/libiconv
+ vdpau? (
+ || ( >=x11-libs/libvdpau-1.1 >=x11-drivers/nvidia-drivers-180.51 )
+ system-ffmpeg? ( media-video/ffmpeg[vdpau] )
+ )
+ wayland? (
+ >=dev-cpp/waylandpp-0.2.3:=
+ media-libs/mesa[wayland]
+ >=dev-libs/wayland-protocols-1.7
+ >=x11-libs/libxkbcommon-0.4.1
+ )
+ webserver? ( >=net-libs/libmicrohttpd-0.9.55[messages] )
+ X? (
+ x11-libs/libX11
+ x11-libs/libXrandr
+ x11-libs/libXrender
+ system-ffmpeg? ( media-video/ffmpeg[X] )
+ )
+ x11-libs/libdrm
+ xslt? ( dev-libs/libxslt )
+ zeroconf? ( net-dns/avahi[dbus] )
+"
+RDEPEND="${COMMON_DEPEND}
+ lirc? ( app-misc/lirc )
+ !media-tv/xbmc
+ udisks? ( sys-fs/udisks:2 )
+ upower? ( sys-power/upower )
+"
+DEPEND="${COMMON_DEPEND}
+ app-arch/bzip2
+ app-arch/xz-utils
+ dev-lang/swig
+ dev-libs/crossguid
+ dev-libs/rapidjson
+ dev-util/cmake
+ dev-util/gperf
+ media-libs/giflib
+ >=media-libs/libjpeg-turbo-1.5.1:=
+ >=media-libs/libpng-1.6.26:0=
+ test? ( dev-cpp/gtest )
+ virtual/pkgconfig
+ x86? ( dev-lang/nasm )
+"
+
+PATCHES=( "${DISTDIR}"/${P}-no-java-required.patch )
+
+CONFIG_CHECK="~IP_MULTICAST"
+ERROR_IP_MULTICAST="
+In some cases Kodi needs to access multicast addresses.
+Please consider enabling IP_MULTICAST under Networking options.
+"
+
+pkg_setup() {
+ check_extra_config
+ python-single-r1_pkg_setup
+}
+
+src_unpack() {
+ if [[ ${PV} == *9999 ]] ; then
+ if python_is_python3; then
+ EGIT_BRANCH="feature_python3"
+ ewarn "Using the experimental Python 3 branch!"
+ ewarn "See https://kodi.wiki/view/Migration_to_Python_3 for more information."
+ ewarn "To use the non-experimental Python 2 version:"
+ ewarn "echo '~${CATEGORY}/${P} PYTHON_TARGETS: -* python2_7 PYTHON_SINGLE_TARGET: -* python2_7' >> /etc/portage/package.use"
+ ewarn "then re-merge using: emerge -a =${CATEGORY}/${PF}"
+ fi
+ git-r3_src_unpack
+ else
+ default
+ fi
+}
+
+src_prepare() {
+ cmake-utils_src_prepare
+
+ # avoid long delays when powerkit isn't running #348580
+ sed -i \
+ -e '/dbus_connection_send_with_reply_and_block/s:-1:3000:' \
+ xbmc/platform/linux/*.cpp || die
+
+ # Prepare tools and libs witch are configured with autotools during compile time
+ AUTOTOOLS_DIRS=(
+ "${S}"/lib/cpluff
+ "${S}"/tools/depends/native/TexturePacker/src
+ "${S}"/tools/depends/native/JsonSchemaBuilder/src
+ )
+
+ local d
+ for d in "${AUTOTOOLS_DIRS[@]}" ; do
+ pushd ${d} >/dev/null || die
+ AT_NOELIBTOOLIZE="yes" AT_TOPLEVEL_EAUTORECONF="yes" eautoreconf
+ popd >/dev/null || die
+ done
+ elibtoolize
+
+ # Prevent autoreconf rerun
+ sed -e 's/autoreconf -vif/echo "autoreconf already done in src_prepare()"/' -i \
+ "${S}"/cmake/modules/FindCpluff.cmake \
+ "${S}"/tools/depends/native/TexturePacker/src/autogen.sh \
+ "${S}"/tools/depends/native/JsonSchemaBuilder/src/autogen.sh \
+ || die
+}
+
+src_configure() {
+ local mycmakeargs=(
+ -Ddocdir="${EPREFIX}/usr/share/doc/${PF}"
+ -DENABLE_LDGOLD=OFF # https://bugs.gentoo.org/show_bug.cgi?id=606124
+ -DENABLE_ALSA=$(usex alsa)
+ -DENABLE_AIRTUNES=$(usex airplay)
+ -DENABLE_AVAHI=$(usex zeroconf)
+ -DENABLE_BLUETOOTH=$(usex bluetooth)
+ -DENABLE_BLURAY=$(usex bluray)
+ -DENABLE_CCACHE=OFF
+ -DENABLE_CEC=$(usex cec)
+ -DENABLE_DBUS=$(usex dbus)
+ -DENABLE_DVDCSS=$(usex css)
+ -DENABLE_INTERNAL_CROSSGUID=OFF
+ -DENABLE_INTERNAL_FFMPEG="$(usex !system-ffmpeg)"
+ -DENABLE_INTERNAL_FSTRCMP=OFF
+ -DENABLE_CAP=$(usex caps)
+ -DENABLE_LCMS2=$(usex lcms)
+ -DENABLE_LIRCCLIENT=$(usex lirc)
+ -DENABLE_MARIADBCLIENT=$(usex mariadb)
+ -DENABLE_MYSQLCLIENT=$(usex mysql)
+ -DENABLE_MICROHTTPD=$(usex webserver)
+ -DENABLE_MYSQLCLIENT=$(usex mysql)
+ -DENABLE_NFS=$(usex nfs)
+ -DENABLE_OPENGLES=$(usex gles)
+ -DENABLE_OPENGL=$(usex opengl)
+ -DENABLE_OPTICAL=$(usex dvd)
+ -DENABLE_PLIST=$(usex airplay)
+ -DENABLE_PULSEAUDIO=$(usex pulseaudio)
+ -DENABLE_SMBCLIENT=$(usex samba)
+ -DENABLE_UDEV=$(usex udev)
+ -DENABLE_UPNP=$(usex upnp)
+ -DENABLE_VAAPI=$(usex vaapi)
+ -DENABLE_VDPAU=$(usex vdpau)
+ -DENABLE_XSLT=$(usex xslt)
+ -Dlibdvdread_URL="${DISTDIR}/libdvdread-${LIBDVDREAD_VERSION}.tar.gz"
+ -Dlibdvdnav_URL="${DISTDIR}/libdvdnav-${LIBDVDNAV_VERSION}.tar.gz"
+ -Dlibdvdcss_URL="${DISTDIR}/libdvdcss-${LIBDVDCSS_VERSION}.tar.gz"
+ )
+
+ use libusb && mycmakeargs+=( -DENABLE_LIBUSB=$(usex libusb) )
+
+ if use system-ffmpeg; then
+ mycmakeargs+=( -DWITH_FFMPEG="yes" )
+ else
+ mycmakeargs+=( -DFFMPEG_URL="${DISTDIR}/ffmpeg-${PN}-${FFMPEG_VERSION}-${CODENAME}-${FFMPEG_KODI_VERSION}.tar.gz" )
+ fi
+
+ if use gbm; then
+ mycmakeargs+=(
+ -DCORE_PLATFORM_NAME="gbm"
+ -DGBM_RENDER_SYSTEM="$(usex opengl gl gles)"
+ )
+ fi
+
+ if use wayland; then
+ mycmakeargs+=(
+ -DCORE_PLATFORM_NAME="wayland"
+ -DWAYLAND_RENDER_SYSTEM="$(usex opengl gl gles)"
+ )
+ fi
+
+ if use X; then
+ mycmakeargs+=( -DCORE_PLATFORM_NAME="x11" )
+ fi
+
+ cmake-utils_src_configure
+}
+
+src_compile() {
+ cmake-utils_src_compile all
+ use test && emake -C "${BUILD_DIR}" kodi-test
+}
+
+src_test() {
+ emake -C "${BUILD_DIR}" test
+}
+
+src_install() {
+ cmake-utils_src_install
+
+ pax-mark Em "${ED%/}"/usr/$(get_libdir)/${PN}/${PN}.bin
+
+ newicon media/icon48x48.png kodi.png
+
+ rm "${ED%/}"/usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf || die
+ dosym ../../../../fonts/roboto/Roboto-Thin.ttf \
+ usr/share/kodi/addons/skin.estuary/fonts/Roboto-Thin.ttf
+
+ python_domodule tools/EventClients/lib/python/xbmcclient.py
+ python_newscript "tools/EventClients/Clients/KodiSend/kodi-send.py" kodi-send
+}
+
+pkg_postinst() {
+ gnome2_icon_cache_update
+ xdg_desktop_database_update
+}
+
+pkg_postrm() {
+ gnome2_icon_cache_update
+ xdg_desktop_database_update
+}
diff --git a/media-tv/kodi/metadata.xml b/media-tv/kodi/metadata.xml
new file mode 100644
index 0000000..1f21b8a
--- /dev/null
+++ b/media-tv/kodi/metadata.xml
@@ -0,0 +1,28 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="person">
+ <email>candrews@gentoo.org</email>
+ <name>Craig Andrews</name>
+ </maintainer>
+ <use>
+ <flag name="airplay">enable AirPlay support</flag>
+ <flag name="bluray">Enable playback of Blu-ray filesystems</flag>
+ <flag name="cec">Enable support for HDMI-CEC devices via libcec</flag>
+ <flag name="gbm">Use the Graphics Buffer Manager for EGL on KMS.</flag>
+ <flag name="gles">Enable support for GLES</flag>
+ <flag name="lirc">Enable support for controlling Totem with a remote control using <pkg>app-misc/lirc</pkg></flag>
+ <flag name="mariadb">Add MariaDB support</flag>
+ <flag name="nfs">Enable NFS client support</flag>
+ <flag name="dvd">Enable optical (CD/DVD drive) support</flag>
+ <flag name="system-ffmpeg">Use system ffmpeg instead of the bundled one</flag>
+ <flag name="libusb">Use <pkg>virtual/libusb</pkg> for usb device hotplug support. This flag should only be enabled if you're running a non-Linux kernel or you don't want to use <pkg>sys-fs/udev</pkg>.</flag>
+ <flag name="udev">Use <pkg>sys-fs/udev</pkg> rules to handle devices' permissions and hotplug support. Unless you know what you're doing do not disable this flag on Linux kernels. This is provided as an option for completeness.</flag>
+ <flag name="webserver">Enable internal webserver</flag>
+ <flag name="xslt">Enable XSLT support using <pkg>dev-libs/libxslt</pkg></flag>
+ </use>
+ <upstream>
+ <bugs-to>https://trac.kodi.tv/</bugs-to>
+ <remote-id type="github">xbmc/xbmc</remote-id>
+ </upstream>
+</pkgmetadata>