# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

inherit toolchain-funcs

DESCRIPTION="Maximum likelihood superpositioning and analysis of macromolecular structures"
HOMEPAGE="http://www.theseus3d.org/"
SRC_URI="${HOMEPAGE}src/${PN}_${PV}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~ppc ~x86 ~amd64"
IUSE=""
RDEPEND="virtual/lapack
	virtual/blas
	sci-biology/muscle"
DEPEND="${RDEPEND}"
S="${WORKDIR}/${PN}"

src_unpack() {
	unpack ${A}

	sed -i \
		-e "s:^\(SYSLIBS\).*:\1 = -lm -lc:g" \
		-e "s:^\(BLASLIB\).*:\1 = -lblas:g" \
		-e "s:^\(LAPACKLIB\).*:\1 = -llapack:g" \
		-e "s:^\(INSTALLDIR\).*:\1 = \"${D}usr/bin\":g" \
		-e "s:^\(OPT\).*:\1 = ${CFLAGS}:g" \
		-e "s:^\(WARN\).*:\1 = :g" \
		-e "s:^\(CFLAGS\).*:\1 = \$(WARN) -std=c99 -pthread:g" \
		-e "s:^\(CC\).*:\1 = $(tc-getCC):g" \
		-e "s:^\(ARCH \).*:\1 = $(tc-getAR):g" \
		-e "s:^\(ARCHFLAGS\).*:\1 = -rvs:g" \
		"${S}"/make.inc

	sed -i \
		-e "s:/local::g" \
		-e "s:clustlaw:clustalw:g" \
		"${S}"/theseus_align
}

src_compile() {
	# Build system is crap
	emake -j1 || die "emake failed"
}

src_install() {
	dodir /usr/bin
	emake install || die "emake install failed"

	doman theseus.1
	# the README is just a copy of the formatted man page, don't install it
	dodoc AUTHORS
	docinto examples; dodoc examples/*
}

pkg_postinst() {
	elog "You may use theseus_align to create a sequence alignment, then superpose"
	elog "the aligned sequences. It is not a structure-based alignment."
	elog "By default, it uses MUSCLE. You may edit the script to change this."
}