summaryrefslogtreecommitdiff
blob: ebe9f72367f5409b74dd900e0bba2a9d40650c94 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="2"

inherit autotools gnome2

DESCRIPTION="C++ bindings for libgda"
HOMEPAGE="http://gtkmm.sourceforge.net/"
LICENSE="LGPL-2.1 examples? ( GPL-2 )"
SLOT="4"
KEYWORDS="~amd64 ~ppc ~sparc ~x86"
IUSE="berkdb doc examples"

RDEPEND=">=dev-cpp/glibmm-2.12.8
	>=gnome-extra/libgda-4.0.0:4[berkdb?]"
DEPEND="${RDEPEND}
	dev-util/pkgconfig
	doc? ( app-doc/doxygen )"

DOCS="AUTHORS ChangeLog NEWS README TODO"

src_prepare() {
	gnome2_src_prepare

	sed -i -e 's/^\(^SUBDIRS.*\)examples\(.*\)/\1\2/' \
		Makefile.am || die "sed failed"

	epatch "${FILESDIR}/${PV}-bdb_automagic.patch"

	AT_M4DIR="scripts/"
	eautoreconf
}

src_configure() {
	G2CONF="
		$(use_enable doc reference)
		$(use_with berkdb bdb)"
	gnome2_src_configure
}

src_install() {
	gnome2_src_install referencedir="/usr/share/doc/${PF}/html"

	if use examples ; then
		rm -rf examples/Makefile* examples/*/Makefile*
		insinto /usr/share/doc/${PF}
		doins -r examples
	fi
}