# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $
# This ebuild is intended for macbook pro users.

inherit linux-mod subversion flag-o-matic

ESVN_REPO_URI="http://svn.madwifi.org/madwifi/trunk/"
ESVN_UPDATE_CMD="svn -r ${PV} update"
ESVN_PROJECT="madwifi-ng"

DESCRIPTION="Wireless-ng driver for Atheros chipset a/b/g cards"
HOMEPAGE="http://www.madwifi.org/"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~x86"
IUSE=""
DEPEND="app-arch/sharutils"
RDEPEND=""
S=${WORKDIR}/madwifi

CONFIG_CHECK="CRYPTO SYSCTL"
ERROR_CRYPTO="${P} requires Cryptographic API support (CONFIG_CRYPTO)."
ERROR_SYSCTL="${P} requires Sysctl support (CONFIG_SYSCTL)."

pkg_setup() {

	if ! ( kernel_is ge 2 6 22 ); then
		die "This only works on >=2.6.22 kernels"
	fi

	linux-mod_pkg_setup

	use x86 && ARCH=i386
	use amd64 && ARCH=x86_64
	MODULE_NAMES="ath_hal(net:${S}/ath_hal)
		wlan(net:${S}/net80211)
		wlan_acl(net:${S}/net80211)
		wlan_ccmp(net:${S}/net80211)
		wlan_tkip(net:${S}/net80211)
		wlan_wep(net:${S}/net80211)
		wlan_xauth(net:${S}/net80211)
		wlan_scan_sta(net:${S}/net80211)
		wlan_scan_ap(net:${S}/net80211)
		ath_rate_amrr(net:${S}/ath_rate/amrr)
		ath_rate_onoe(net:${S}/ath_rate/onoe)
		ath_rate_sample(net:${S}/ath_rate/sample)
		ath_rate_minstrel(net:${S}/ath_rate/minstrel)
		ath_pci(net:${S}/ath)"
	BUILD_PARAMS="KERNELPATH=${ROOT}${KV_OUT_DIR} KERNELRELEASE=${KV_FULL}
		ARCH=${ARCH} TOOLPREFIX=/usr/bin/"
	BUILD_TARGETS="all"
}

src_unpack() {
	subversion_src_unpack

	epatch ${FILESDIR}/madwifi-ng-0.9.3-uudecode-gcda-fix.patch

	for dir in ath ath_hal net80211 ath_rate/amrr ath_rate/onoe ath_rate/sample ath_rate/minstrel
	do
		convert_to_m "${S}/${dir}/Makefile"
	done

	cp ${FILESDIR}/svnversion.h ${S}
}

src_compile() {
	emake DESTDIR="${D}"|| die "emake failed"
}

src_install() {
	linux-mod_src_install

	cd "${S}"

	dodoc README COPYRIGHT

# install headers for use by
# net-wireless/wpa_supplicant and net-wireless/hostapd
	insinto /usr/include/madwifi/include/
	doins "${S}/include/*.h"
	insinto /usr/include/madwifi/include/sys/
	doins "${S}/include/sys/*.h"
	insinto /usr/include/madwifi/net80211
	doins "${S}/net80211/*.h"

	cd "${S}/tools"
	make install DESTDIR="${D}" BINDIR=/sbin
}

pkg_postinst() {
	linux-mod_pkg_postinst
	einfo ""
	einfo "The madwifi drivers create an interface named 'wifiX'"
	einfo ""
	einfo "Any bugs with this ebuild report to je_fro@gentoo.org"
}