From 897e158defe43daa0b753f68f285c169eefb2e7a Mon Sep 17 00:00:00 2001
From: Andreas Proschofsky <suka@gentoo.org>
Date: Fri, 28 Sep 2012 19:25:40 +0000
Subject: Bump Shotwell to newest release

svn path=/; revision=351
---
 media-gfx/shotwell/shotwell-0.13.0.ebuild | 63 +++++++++++++++++++++++++++++++
 1 file changed, 63 insertions(+)
 create mode 100644 media-gfx/shotwell/shotwell-0.13.0.ebuild

(limited to 'media-gfx/shotwell/shotwell-0.13.0.ebuild')

diff --git a/media-gfx/shotwell/shotwell-0.13.0.ebuild b/media-gfx/shotwell/shotwell-0.13.0.ebuild
new file mode 100644
index 0000000..de78d80
--- /dev/null
+++ b/media-gfx/shotwell/shotwell-0.13.0.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-gfx/shotwell/shotwell-0.12.2.ebuild,v 1.2 2012/05/11 21:37:05 hwoarang Exp $
+
+EAPI=4
+GCONF_DEBUG="no"
+inherit gnome2 versionator eutils multilib toolchain-funcs
+
+MY_PV=$(get_version_component_range 1-2)
+DESCRIPTION="Open source photo manager for GNOME"
+HOMEPAGE="http://www.yorba.org/shotwell/"
+SRC_URI="http://www.yorba.org/download/${PN}/${MY_PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	>=dev-db/sqlite-3.5.9:3
+	>=dev-libs/dbus-glib-0.80
+	>=dev-libs/glib-2.30.0:2
+	>=dev-libs/json-glib-0.7.6
+	>=dev-libs/libgee-0.5.0:0
+	>=dev-libs/libxml2-2.6.32:2
+	>=media-libs/gexiv2-0.3.92
+	media-libs/gst-plugins-base:0.10
+	media-libs/gstreamer:0.10
+	media-libs/lcms:2
+	>=media-libs/libexif-0.6.16
+	>=media-libs/libgphoto2-2.4.2
+	>=media-libs/libraw-0.14.0
+	>=net-libs/libsoup-2.26.0:2.4
+	net-libs/rest:0.7
+	net-libs/webkit-gtk:3
+	|| ( >=sys-fs/udev-171[gudev] >=sys-fs/udev-145[extras] )
+	x11-libs/gtk+:3"
+DEPEND="${RDEPEND}
+	dev-lang/vala:0.18
+	sys-devel/m4"
+
+DOCS=( AUTHORS MAINTAINERS NEWS README THANKS )
+
+pkg_setup() {
+	tc-export CC
+	G2CONF="${G2CONF}
+		--disable-schemas-compile
+		--disable-desktop-update
+		--disable-icon-update
+		--lib=$(get_libdir)"
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-dark-theme.patch
+#	epatch "${FILESDIR}"/${P}-libgphoto25.patch
+	sed \
+		-e 's|CFLAGS :|CFLAGS +|g' \
+		-i plugins/Makefile.plugin.mk || die
+}
+
+src_compile() {
+	emake VALAC="$(type -p valac-0.18)"
+}
-- 
cgit v1.2.3-65-gdbad