1 files changed, 89 insertions, 0 deletions
diff --git a/media-libs/capseo/capseo-0.3.0_pre200706031.ebuild b/media-libs/capseo/capseo-0.3.0_pre200706031.ebuild
new file mode 100644
index 0000000..1f561f5
--- /dev/null
+++ b/media-libs/capseo/capseo-0.3.0_pre200706031.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+inherit flag-o-matic multilib
+
+DESCRIPTION="Capseo Video Codec Library"
+HOMEPAGE="http://rm-rf.in/captury/wiki/CapseoCodec"
+SRC_URI="http://upstream.rm-rf.in/captury/captury-${PV}.tar.bz2"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug theora"
+
+RDEPEND=">=media-libs/libtheora-1.0_alpha6-r1"
+
+DEPEND="${RDEPEND}
+		>=dev-lang/yasm-0.4.0
+		dev-util/pkgconfig"
+
+RESTRICT="multilib-pkg-force"
+
+S="${WORKDIR}/captury-${PV}/${PN}"
+
+src_compile() {
+	if [[ -z ${OABI} ]] && has_multilib_profile; then
+		use debug && append-flags -O0 -g3
+		use debug || append-flags -DNDEBUG=1
+
+		einfo "Building multilib ${PN} for ABIs: $(get_install_abis)"
+		OABI=${ABI}
+		for ABI in $(get_install_abis); do
+			export ABI=${ABI}
+			src_compile
+		done
+		ABI=${OABI}
+		return
+	fi
+
+	cd ${S} || die
+
+	if [[ ! -f configure ]]; then
+		./autogen.sh || die "autogen.sh failed"
+	fi
+
+	mkdir abi-${ABI}
+	cd abi-${ABI}
+
+	local myconf=
+	case ${ABI} in
+		amd64|x86)
+			myconf="${myconf} --with-accel=${ABI}"
+			;;
+	esac
+	myconf="${myconf} $(use_enable theora)"
+
+	../configure ${myconf} \
+		--prefix="/usr" \
+		--host="$(get_abi_CHOST ${ABI})" \
+		--libdir="/usr/$(get_libdir)" \
+		|| die "./configure for ABI ${ABI} failed"
+
+	emake || die "make for ABI ${ABI} failed"
+}
+
+src_install() {
+	for ABI in $(get_install_abis); do
+		make -C abi-${ABI} install DESTDIR="${D}" || die "make install for ABI ${ABI} failed."
+	done
+
+	rm "${D}/usr/bin/cpsplay" # currently unsupported
+
+	dodoc AUTHORS ChangeLog* NEWS README* TODO
+}
+
+pkg_postinst() {
+	einfo "Use the following command to re-encode your screen captures to a"
+	einfo "file format current media players do understand:"
+	einfo
+	einfo "    cpsrecode -i capture.cps -o - | mencoder - -o capture.avi \\"
+	einfo "              -ovc lavc -lavcopts vcodec=xvid:autoaspect=1"
+	einfo
+	einfo "or if use-flag theora enabled, create your ogg/theora file inplace:"
+	einfo
+	einfo "    cpsrecode -i capture.cps -o capture.ogg -c theora"
+	echo
+}
+
+# vim:ai:noet:ts=4:nowrap