# Copyright 1999-2013 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

EAPI=4

PHP_EXT_NAME="mapi"
PHP_EXT_INI="yes"
PHP_EXT_ZENDEXT="no"
USE_PHP="php5-3"

inherit versionator php-ext-source-r2 eutils

ZARAFA_MAJOR=$(get_version_component_range 1 ${PV})
ZARAFA_MINOR=$(get_version_component_range 2 ${PV})
ZARAFA_MICRO=$(get_version_component_range 3 ${PV})
ZARAFA_REV=31537

DESCRIPTION="Open Source Groupware Solution"
HOMEPAGE="http://zarafa.com/"
SRC_URI="http://download.zarafa.com/community/final/${ZARAFA_MAJOR}.${ZARAFA_MINOR}/${PV}-${ZARAFA_REV}/sourcecode/zcp-${PV}.tar.gz"

LICENSE="AGPL-3"
SLOT="0"
KEYWORDS="~x86 ~amd64"
IUSE="debug ldap +logrotate static"

RDEPEND=">=dev-libs/libical-0.44
	=dev-cpp/libvmime-0.7.1
	>=dev-lang/php-5.2.0
	app-text/catdoc
	app-text/poppler
	dev-cpp/clucene
	virtual/mysql
	dev-libs/libxml2
	dev-libs/openssl
	net-misc/curl
	sys-libs/e2fsprogs-libs
	sys-libs/zlib
	dev-libs/boost
	ldap? ( net-nds/openldap )
	logrotate? ( app-admin/logrotate )"
DEPEND="${RDEPEND}
	sys-devel/gettext
	virtual/pkgconfig"

#src_unpack() {
#	unpack ${P}.tar.bz2
#}

src_prepare() {
	# Don't install php ini file, as installation doesn't
	# respect Gentoo way of handling SAPIs
	epatch "${FILESDIR}"/"${PN}"-6.40.1-no-php-conf.patch

	# Fix for zarafa-server crash - bug ID 8842
	# https://jira.zarafa.com/browse/ZCP-8842
	epatch "${FILESDIR}"/"${PN}"-fix-8842.patch
}

src_configure() {
	econf \
		--enable-oss \
		--enable-release \
		--disable-perl \
		--disable-testtools \
		--with-userscript-prefix=/etc/zarafa/userscripts \
		--with-quotatemplate-prefix=/etc/zarafa/quotamails \
		--with-indexerscripts-prefix=/etc/zarafa/indexerscripts \
		$(use_enable static) \
		$(use_enable debug)
}

src_install() {
	default

	# Use only some parts of PHP eclass
	php-ext-source-r2_buildinilist php${slot}
	php-ext-source-r2_addextension "${PHP_EXT_NAME}.so"

	# Symlink the <ext>.ini files from ext/ to ext-active/
	for inifile in ${PHPINIFILELIST} ; do
		inidir="${inifile/${PHP_EXT_NAME}.ini/}"
		inidir="${inidir/ext/ext-active}"
		dodir "/${inidir}"
		dosym "/${inifile}" "/${inifile/ext/ext-active}"
	done

	# Install PHP module
	php-ext-source-r2_addtoinifiles ";mapi.cache_max_sessions" "128"
	php-ext-source-r2_addtoinifiles ";mapi.cache_lifetime" "300"

	if use logrotate; then
		insinto /etc/logrotate.d
		newins "${FILESDIR}"/zarafa.logrotate zarafa
	fi

	insinto /etc/zarafa
	doins "${S}"/installer/linux/*.cfg

	dodir /var/log/zarafa
	keepdir /var/log/zarafa

	newinitd "${FILESDIR}"/zarafa-gateway.rc6 zarafa-gateway
	newinitd "${FILESDIR}"/zarafa-ical.rc6 zarafa-ical
	newinitd "${FILESDIR}"/zarafa-indexer.rc6 zarafa-indexer
	newinitd "${FILESDIR}"/zarafa-monitor.rc6 zarafa-monitor
	newinitd "${FILESDIR}"/zarafa-server.rc6 zarafa-server
	newinitd "${FILESDIR}"/zarafa-spooler.rc6 zarafa-spooler

}