# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gpe-base/gpe-login/gpe-login-0.95-r1.ebuild,v 1.1 2009/04/07 15:28:41 miknix Exp $

GPE_TARBALL_SUFFIX="bz2"
inherit gpe eutils

DESCRIPTION="The GPE user login screen"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~arm ~amd64 ~x86"
IUSE="branding"

DEPEND="${DEPEND}
	>=gpe-base/libgpewidget-0.102"
RDEPEND="${RDEPEND}
	${DEPEND}
	x11-misc/xkbd
	gpe-utils/gpe-ownerinfo"

src_unpack() {
	local gentoo_files="gpe-login.setup
	                    gpe-login.xinit
						gpe-login.session"

	gpe_src_unpack "$@"

	# Patch login to show up a beaty gentoo logo (if found)
	# solar says conditional patching is bad
	epatch "${FILESDIR}/gpe-login-0.95-gentoologo.patch"

	# Use our gentooish scripts instead
	for gfile in $gentoo_files; do
		einfo "Replacing ${gfile}"
		cp "${FILESDIR}/${gfile}-gentoo" "${gfile}" \
			|| die "Replace ${gfile} fail"
		chmod 0755 ${gfile} || die "Cannot chmod ${gfile}"
	done

	# We dont want these
	sed -i -e 's;X11/gpe-login.gtkrc;;g' \
	       -e 's;gpe-login.keylaunchrc;;g' \
		   -e 's;mv gpe-login.sysconfig gpelogin;true;' \
		   -e 's;gpe-login.sysconfig;;g' Makefile.in \
		|| die "Sed failed 0xff"

	# We fixed gpe-dm to use this path
	sed -i -e 's;/X11/Xinit.d;/X11/gpe-dm/Xinit.d;g' Makefile.in \
		|| die "Sed failed for file Xinit.d"
}

src_install() {
	gpe_src_install "$@"

	insinto /etc/X11/
	newins "${FILESDIR}/gpe-login.geometry-gentoo" gpe-login.geometry
	insinto /etc/gpe/
	newins "${FILESDIR}/locale.default-gentoo" locale.default

	# Install the gentoo logo into pixmaps, see above
	if use branding; then
		insinto /usr/share/pixmaps/
		newins "${FILESDIR}/gentoo-badge2.png" gpe-login-gentoo.png
	fi
}

pkg_postinst() {
	einfo "Have a look on the following files to fine tune"
	einfo "your brand new login manager:"
	einfo "/etc/X11/gpe-login.setup"
	einfo "/etc/X11/gpe-login.geometry"
	einfo "/etc/gpe/gpe-login.conf"
	einfo "/etc/gpe/locale.default"
}