# Copyright 1999-2011 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $

EAPI="1"

EBZR_REVISION="1877"
EBZR_REPO_URI="http://bazaar.launchpad.net/~ltsp-upstream/ltsp/ltsp-trunk"

inherit bzr

DESCRIPTION="LTSP server"
HOMEPAGE="http://www.ltsp.org/"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
# Default to nfs until nbd works
IUSE="doc dhcp examples nbd +nfs"
DEPEND=""

# NOTES on the dependencies
# xdm - we currently have to rely on /usr/lib/X11/xdm/Xsession
# iproute2 - ltsp-update-sshkeys requires ip
RDEPEND="!net-misc/ltsp-client
	x11-apps/xdm
	media-sound/pulseaudio
	x11-base/xorg-server
	net-misc/openssh
	virtual/tftp
	dhcp? ( || ( net-misc/dhcp net-dns/dnsmasq ) )
	nfs? (
		>net-fs/nfs-utils-1.1.5
	)
	nbd? (
		sys-apps/xinetd
		sys-block/nbd
		sys-fs/squashfs-tools
	)
	sys-fs/ltspfs
	sys-apps/lsb-release
	>sys-apps/quickstart-0.6
	sys-apps/iproute2
	>=app-portage/layman-1.3
	sys-boot/syslinux
	net-misc/ldminfod"

src_unpack() {
	bzr_src_unpack
}

src_install() {
	ltspdir="/usr/share/ltsp"

	insinto /etc/ltsp/quickstart
	doins server/configs/quickstart/*

	insinto ${ltspdir}
	doins ltsp-common-functions

	insinto ${ltspdir}/plugins
	doins -r server/plugins/*

	dobin localapps/ltsp-localapps

	dosbin server/ltsp-info
	dosbin server/ltsp-keys
	dosbin server/ltsp-build-client
	dosbin server/ltsp-update-kernels
	dosbin server/ltsp-update-sshkeys

	doman localapps/doc/ltsp-localapps.1
	doman server/doc/ltsp-build-client.8
	doman server/doc/ltsp-info.1
	doman server/doc/ltsp-update-kernels.8
	doman server/doc/ltsp-update-sshkeys.8

    if use nbd; then
		dosbin server/ltsp-update-image
		dosbin server/nbd-update-config
		dosbin server/nbdrootd
		dosbin server/nbdswapd

		insinto /etc/xinetd.d
		doins server/xinetd.d/nbd*

		doman server/doc/ltsp-update-image.8
		doman server/doc/nbdrootd.8
		doman server/doc/nbdswapd.8
    fi

    if use doc; then
		dodoc TODO
		dodoc server/doc/CodingStyle
		dodoc server/doc/QuickInstall
		dodoc server/doc/lts-parameters.txt
		dodoc server/doc/plugins
		dodoc server/doc/swap
	fi

	if use examples; then
		docinto examples
		dodoc localapps/doc/examples/*
		dodoc server/doc/examples/*
	fi
}

pkg_postinst(){
	einfo "Don't forget to install a window manager,"
	einfo "you can't log in to your ltsp-client without one."
}