now gnome-base/gconf-2.26.2-r1 on branch master

2 files changed, 105 insertions, 0 deletions

diff --git a/gnome-base/gconf/Manifest b/gnome-base/gconf/Manifest
index 8b143e987..3c771458b 100644
--- a/gnome-base/gconf/Manifest
+++ b/gnome-base/gconf/Manifest
@@ -8,4 +8,5 @@ DIST GConf-2.26.2.tar.bz2 1474738 RMD160 280cd55dc3562445c716b88dfddba4ddd250878
 EBUILD gconf-2.22.0.ebuild 2088 RMD160 12e7e6d1d1a18ac4d6a9a9ba4d0f0fc269e9ec4b SHA1 6819377d9543a1cc68a79d6aa3c2f574b53d3062 SHA256 b332e5ba915c92cbe695e2bd250bf2aeedbbb94b4be65473f11a1bcc1f3153fb
 EBUILD gconf-2.24.0.ebuild 2375 RMD160 d4809f807b4d17c8506cab43624334173f5d5651 SHA1 e490bfd2b85e4ee780d1eb4fa8d796dba8ca7218 SHA256 262988655781d84fd0881cb558c13c7e9cb274462700ccaabb1c16c50f4bdd31
 EBUILD gconf-2.26.0.ebuild 2421 RMD160 a7c3ef57c8762b0a4cd21cba28e9cb9c10ccc0ee SHA1 800c9da551be9e6f370cc34b28e4eaf63c00ce56 SHA256 75aa01b4f75e3cbb6e740ea7009b236bc526020bb4aafa8188583ecae544998e
+EBUILD gconf-2.26.2-r1.ebuild 2714 RMD160 60234812015029eb5adf5faa3c799fddcb46cbaf SHA1 26d43c180ee5edda5cdfc6e9b890f45caeca89a1 SHA256 5479e244d94fae5b2bd135e6e338e4c130dedc6e6254bd2860e55435a7c7a55d
 EBUILD gconf-2.26.2.ebuild 2729 RMD160 7337c80eab58b58ebcb073325e80a0f0352a388a SHA1 2eb60c1e37a0b7b8d4ae3b42040cf73c17400566 SHA256 2dd2d02fc31f070a8e2b8534833049c2f86efd0ea496a71845f477d5a89f5797
diff --git a/gnome-base/gconf/gconf-2.26.2-r1.ebuild b/gnome-base/gconf/gconf-2.26.2-r1.ebuild
new file mode 100644
index 000000000..d7fbdc63a
--- /dev/null
+++ b/gnome-base/gconf/gconf-2.26.2-r1.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-base/gconf/gconf-2.26.2-r1.ebuild,v 1.1 2009/06/16 20:31:19 mrpouet Exp $
+
+EAPI="2"
+
+inherit eutils gnome2 multilib-native
+
+MY_PN=GConf
+MY_P=${MY_PN}-${PV}
+PVP=(${PV//[-\._]/ })
+
+DESCRIPTION="Gnome Configuration System and Daemon"
+HOMEPAGE="http://www.gnome.org/"
+SRC_URI="mirror://gnome/sources/${MY_PN}/${PVP[0]}.${PVP[1]}/${MY_P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="debug doc ldap policykit"
+
+RDEPEND=">=dev-libs/glib-2.14[lib32?]
+	>=x11-libs/gtk+-2.8.16[lib32?]
+	>=dev-libs/dbus-glib-0.74[lib32?]
+	>=sys-apps/dbus-1[lib32?]
+	>=gnome-base/orbit-2.4[lib32?]
+	>=dev-libs/libxml2-2[lib32?]
+	ldap? ( net-nds/openldap )
+	policykit? ( >=sys-auth/policykit-0.7[lib32?] )"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.35
+	>=dev-util/pkgconfig-0.9
+	>=dev-util/gtk-doc-am-1.10
+	doc? ( >=dev-util/gtk-doc-1 )"
+
+DOCS="AUTHORS ChangeLog NEWS README TODO"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--enable-gtk
+		--disable-static
+		$(use_with ldap openldap)
+		$(use_enable policykit defaults-service)"
+	kill_gconf
+
+	# Need host's IDL compiler for cross or native build, bug #262747
+	export EXTRA_EMAKE="${EXTRA_EMAKE} ORBIT_IDL=/usr/bin/orbit-idl-2"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Do not start gconfd when installing schemas, fix bug #238276, upstream ?
+	epatch "${FILESDIR}/${PN}-2.24.0-no-gconfd.patch"
+
+	# Fix intltoolize broken file, see upstream #577133
+	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in || die "sed failed"
+}
+
+# Can't run tests, missing script.
+#src_test() {
+#	emake -C tests || die "make tests failed"
+#	sh "${S}"/tests/runtests.sh || die "running tests failed"
+#}
+
+multilib-native_src_install_internal() {
+	gnome2_src_install
+
+	keepdir /etc/gconf/gconf.xml.mandatory
+	keepdir /etc/gconf/gconf.xml.defaults
+	# Make sure this directory exists, bug #268070, upstream #572027
+	keepdir /etc/gconf/gconf.xml.system
+
+	echo 'CONFIG_PROTECT_MASK="/etc/gconf"' > 50gconf
+	doenvd 50gconf || die "doenv failed"
+	dodir /root/.gconfd
+}
+
+pkg_preinst() {
+	kill_gconf
+}
+
+pkg_postinst() {
+	kill_gconf
+
+	# change the permissions to avoid some gconf bugs
+	einfo "changing permissions for gconf dirs"
+	find  /etc/gconf/ -type d -exec chmod ugo+rx "{}" \;
+
+	einfo "changing permissions for gconf files"
+	find  /etc/gconf/ -type f -exec chmod ugo+r "{}" \;
+}
+
+kill_gconf() {
+	# This function will kill all running gconfd-2 that could be causing troubles
+	if [ -x /usr/bin/gconftool-2 ]
+	then
+		/usr/bin/gconftool-2 --shutdown
+	fi
+
+	return 0
+}