media-libs/alsa-lib: version bump to 1.1.6

4 files changed, 89 insertions, 6 deletions

diff --git a/media-libs/alsa-lib/Manifest b/media-libs/alsa-lib/Manifest
index 7101b636..05d198b6 100644
--- a/media-libs/alsa-lib/Manifest
+++ b/media-libs/alsa-lib/Manifest
@@ -1,2 +1,3 @@
-DIST alsa-lib-1.1.4.1.tar.bz2 974584 SHA256 91bb870c14d1c7c269213285eeed874fa3d28112077db061a3af8010d0885b76 SHA512 7b548c4ee29c4a1230a0edcd5d19219831290f96a214180a6530628acc05278d1348376195287d188f4f44d6be1914391c63994f1b50985c3eee74352da26b0b WHIRLPOOL 2fc84b8a3c6023dac7953f1d2960a8eb5279f58cf2e59b8f5d04293df7595b9f0ebca5738bf4a333f8b20586c7fd579b9e7bdeeffd64518649be3a8c5d588fd8
-DIST alsa-lib-1.1.5.tar.bz2 979225 SHA256 f4f68ad3c6da36b0b5241ac3c798a7a71e0e97d51f972e9f723b3f20a9650ae6 SHA512 c79ceaa1ebfeda2caf41a0495ea31dd2748a11795989aebc341ae13a5c96d21495e4542571d5590e68b2575ceddd6e84059a950ddb78e6c0b9d94861faee4f58 WHIRLPOOL 7b327499e8576c07e4ed7fe293f788283e158f08efd10ad5b7ca9f980cbe5dcd9fcc290a9880726a971bd180f5a0c57215d5f337e5294ace25fe5923ea6fbcbd
+DIST alsa-lib-1.1.4.1.tar.bz2 974584 BLAKE2B f3221fa55dc11c04f4a1bc3ee90d2a679ca9b8bde65e2801ae5762fa456ef8e45532624efa57bf7d62f82e5c172eaf10f2286f9acace5a47e20123acf5ce04d2 SHA512 7b548c4ee29c4a1230a0edcd5d19219831290f96a214180a6530628acc05278d1348376195287d188f4f44d6be1914391c63994f1b50985c3eee74352da26b0b
+DIST alsa-lib-1.1.5.tar.bz2 979225 BLAKE2B 75683b17bfd51c1e54f1a460ed32a170b07eb227bd6b9ee481d123116464f5c16bbb49f29dfc8d08baaf2f69c5333bf71b70c33b5d420c43e56ae4ace76a6ab0 SHA512 c79ceaa1ebfeda2caf41a0495ea31dd2748a11795989aebc341ae13a5c96d21495e4542571d5590e68b2575ceddd6e84059a950ddb78e6c0b9d94861faee4f58
+DIST alsa-lib-1.1.6.tar.bz2 989316 BLAKE2B 2aec62d262148571cc1b93ac8053002b61266951caf8b2855fc65b699ec928672748a21ba11a25e14e752a4a85f68b2f77b5ad6af9b2f1fc5e9de41313ace54a SHA512 00117769a3d5c609019b975188d6e7a07d035bd0461f54c5f291e14667620506f1adb6d61350f78d54648850f31965aae3ab0e697bf9e09c988e2d15bf6b09f0
diff --git a/media-libs/alsa-lib/alsa-lib-1.1.4.1.ebuild b/media-libs/alsa-lib/alsa-lib-1.1.4.1.ebuild
index 444e11ea..a9bd0ec8 100644
--- a/media-libs/alsa-lib/alsa-lib-1.1.4.1.ebuild
+++ b/media-libs/alsa-lib/alsa-lib-1.1.4.1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -9,7 +9,7 @@ PYTHON_COMPAT=( python2_7 )
 inherit autotools eutils multilib multilib-minimal python-single-r1
 
 DESCRIPTION="Advanced Linux Sound Architecture Library"
-HOMEPAGE="http://www.alsa-project.org/"
+HOMEPAGE="https://alsa-project.org/"
 SRC_URI="mirror://alsaproject/lib/${P}.tar.bz2"
 
 LICENSE="LGPL-2.1"
diff --git a/media-libs/alsa-lib/alsa-lib-1.1.5.ebuild b/media-libs/alsa-lib/alsa-lib-1.1.5.ebuild
index 0c76804c..7ff825cd 100644
--- a/media-libs/alsa-lib/alsa-lib-1.1.5.ebuild
+++ b/media-libs/alsa-lib/alsa-lib-1.1.5.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2017 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=6
@@ -9,7 +9,7 @@ PYTHON_COMPAT=( python2_7 )
 inherit autotools eutils multilib multilib-minimal python-single-r1
 
 DESCRIPTION="Advanced Linux Sound Architecture Library"
-HOMEPAGE="http://www.alsa-project.org/"
+HOMEPAGE="https://alsa-project.org/"
 SRC_URI="mirror://alsaproject/lib/${P}.tar.bz2"
 
 LICENSE="LGPL-2.1"
diff --git a/media-libs/alsa-lib/alsa-lib-1.1.6.ebuild b/media-libs/alsa-lib/alsa-lib-1.1.6.ebuild
new file mode 100644
index 00000000..50564396
--- /dev/null
+++ b/media-libs/alsa-lib/alsa-lib-1.1.6.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+# no support for python3_2 or above yet wrt #471326
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools multilib multilib-minimal python-single-r1
+
+DESCRIPTION="Advanced Linux Sound Architecture Library"
+HOMEPAGE="https://alsa-project.org/"
+SRC_URI="mirror://alsaproject/lib/${P}.tar.bz2"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ia64 ~mips ~ppc ~sh ~sparc ~x86"
+IUSE="alisp debug doc elibc_uclibc python +thread-safety"
+
+RDEPEND="python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}
+	doc? ( >=app-doc/doxygen-1.2.6 )"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	find . -name Makefile.am -exec sed -i -e '/CFLAGS/s:-g -O2::' {} + || die
+	# https://bugs.gentoo.org/509886
+	use elibc_uclibc && { sed -i -e 's:oldapi queue_timer:queue_timer:' test/Makefile.am || die; }
+	# https://bugs.gentoo.org/545950
+	sed -i -e '5s:^$:\nAM_CPPFLAGS = -I$(top_srcdir)/include:' test/lsb/Makefile.am || die
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--disable-maintainer-mode
+		--disable-resmgr
+		--enable-aload
+		--enable-rawmidi
+		--enable-seq
+		--enable-shared
+		# enable Python only on final ABI
+		$(multilib_native_use_enable python)
+		$(use_enable alisp)
+		$(use_enable thread-safety)
+		$(use_with debug)
+		$(usex elibc_uclibc --without-versioned '')
+		$(usex elibc_musl --without-versioned '')
+	)
+
+	ECONF_SOURCE="${S}" \
+	econf "${myeconfargs[@]}"
+}
+
+multilib_src_compile() {
+	emake
+
+	if multilib_is_native_abi && use doc; then
+		emake doc
+		grep -FZrl "${S}" doc/doxygen/html | \
+			xargs -0 sed -i -e "s:${S}::"
+	fi
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+	if multilib_is_native_abi && use doc; then
+		docinto html
+		dodoc -r doc/doxygen/html/.
+	fi
+}
+
+multilib_src_install_all() {
+	find "${ED}" \( -name '*.a' -o -name '*.la' \) -delete || die
+	dodoc ChangeLog doc/asoundrc.txt NOTES TODO
+}