aboutsummaryrefslogtreecommitdiff
diff options
context:
space:
mode:
Diffstat (limited to 'dev-qt/assistant/assistant-5.12.1.ebuild')
-rw-r--r--dev-qt/assistant/assistant-5.12.1.ebuild55
1 files changed, 55 insertions, 0 deletions
diff --git a/dev-qt/assistant/assistant-5.12.1.ebuild b/dev-qt/assistant/assistant-5.12.1.ebuild
new file mode 100644
index 00000000..6d109d6a
--- /dev/null
+++ b/dev-qt/assistant/assistant-5.12.1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+QT5_MODULE="qttools"
+inherit desktop gnome2-utils qt5-build
+
+DESCRIPTION="Tool for viewing on-line documentation in Qt help file format"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+ KEYWORDS="~amd64 ~arm ~hppa ~ppc64 ~sparc ~x86"
+fi
+
+IUSE="webkit"
+
+DEPEND="
+ ~dev-qt/qtcore-${PV}
+ ~dev-qt/qtgui-${PV}
+ ~dev-qt/qthelp-${PV}
+ ~dev-qt/qtnetwork-${PV}
+ ~dev-qt/qtprintsupport-${PV}
+ ~dev-qt/qtsql-${PV}[sqlite]
+ ~dev-qt/qtwidgets-${PV}
+ webkit? ( >=dev-qt/qtwebkit-5.9.1:5 )
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+ src/assistant/assistant
+)
+
+src_prepare() {
+ qt_use_disable_mod webkit webkitwidgets \
+ src/assistant/assistant/assistant.pro
+
+ qt5-build_src_prepare
+}
+
+src_install() {
+ qt5-build_src_install
+
+ doicon -s 32 src/assistant/assistant/images/assistant.png
+ newicon -s 128 src/assistant/assistant/images/assistant-128.png assistant.png
+ make_desktop_entry "${QT5_BINDIR}"/assistant 'Qt 5 Assistant' assistant 'Qt;Development;Documentation'
+}
+
+pkg_postinst() {
+ qt5-build_pkg_postinst
+ gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+ qt5-build_pkg_postrm
+ gnome2_icon_cache_update
+}