app-portage/g-octave: Migrate to new python eclasses, git2 eclass and EAPI=5

Package-Manager: portage-2.2.0_alpha164

1 files changed, 16 insertions, 28 deletions

diff --git a/app-portage/g-octave/g-octave-9999.ebuild b/app-portage/g-octave/g-octave-9999.ebuild
index 7bec90ae5..2e05b3fc4 100644
--- a/app-portage/g-octave/g-octave-9999.ebuild
+++ b/app-portage/g-octave/g-octave-9999.ebuild
@@ -1,13 +1,12 @@
-# Copyright 1999-2010 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
 # $Header: $
 
-EAPI="2"
+EAPI=5
 
-SUPPORT_PYTHON_ABIS="1"
-PYTHON_DEPEND="*:2.6"
+PYTHON_COMPAT=( python{2_5,2_6,2_7,3_1,3_2} pypy{1_9,2_0} )
 
-inherit distutils git
+inherit distutils-r1 git-2
 
 DESCRIPTION="A tool that generates and installs ebuilds for Octave-Forge"
 HOMEPAGE="http://www.g-octave.org/"
@@ -18,35 +17,24 @@ SLOT="0"
 KEYWORDS=""
 IUSE="doc test"
 
-DEPEND=">=dev-python/docutils-0.6
-	doc? ( >=dev-python/sphinx-1.0 )"
+DEPEND="
+	dev-python/docutils[${PYTHON_USEDEP}]
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )"
 RDEPEND="sys-apps/portage"
 
 S="${WORKDIR}/${PN}"
 
-PYTHON_MODNAME="g_octave"
-
-src_compile() {
-	distutils_src_compile
-	if use doc; then
-		emake -C docs html
-	fi
+python_compile_all() {
+	use doc && emake -C docs html
 }
 
-src_install() {
-	distutils_src_install
-	dohtml ${PN}.html
-	doman ${PN}.1
-	if use doc; then
-		mv docs/_build/{html,sphinx}
-		dohtml -r docs/_build/sphinx
-	fi
+python_test() {
+	${PYTHON} scripts/run_tests.py || die
 }
 
-src_test() {
-	testing() {
-		PYTHONPATH="build-${PYTHON_ABI}/lib" "$(PYTHON)" \
-			scripts/run_tests.py || die 'test failed.'
-	}
-	python_execute_function testing
+python_install_all() {
+	doman ${PN}.1
+	use doc && HTML_DOCS=( docs/_build/html/. )
+	HTML_DOCS+=( ${PN}.html )
+	distutils-r1_python_install_all
 }