dev-vcs/dandi-cli: add 0.55.1

Signed-off-by: Horea Christian <chr@chymera.eu>

2 files changed, 93 insertions, 0 deletions

diff --git a/dev-vcs/dandi-cli/Manifest b/dev-vcs/dandi-cli/Manifest
index f2694bd1c..d2ca6b1f1 100644
--- a/dev-vcs/dandi-cli/Manifest
+++ b/dev-vcs/dandi-cli/Manifest
@@ -1,3 +1,4 @@
 DIST dandi-0.50.0.tar.gz 236960 BLAKE2B b36f890e7d7de77ed2202d54516c897fb293ca5b360849199a0cd5fbe61ff07056b328eb3454f72b974a53ddef24ede5180c7f32b32b663c4bbe77f513301fa3 SHA512 91beb1b2330ab425a7cb4f744e2f11c3e5ab5f631903b05b676be898dba4ca16c42c2f9abb21b45858b50bb00c181fab341303846c9ccf416ddcd88c19136ffa
 DIST dandi-0.51.0.tar.gz 233955 BLAKE2B 500a6290cba32f413610879357c0ee525d877575c4ad520818a556ae7f58f90c2aec88387dbb0ca78e7906b48673c2c2d3c9c457833727fb312e5ca6d75ce088 SHA512 e77fa803dd2707df8cab2318377a71c28abb8bdc6e2d086cb43daf24512f361e533d249dabd88bfc6c0de06e6332606ac2f3c57482ae9717fedb66da4e2e8d89
 DIST dandi-0.55.0.tar.gz 292471 BLAKE2B 2ccdba123c61025894a327d56163fd71cd0294b315b83396688903d969ba243fe2bb3ad9d2db5cf24d36254395a7de452d6e4ff4a65cf264f001a0cda527cd08 SHA512 e41f699a55cd75161048dd0e0334b84527ae0f4e02c81eedf7c8811b8bc50229488599f9601263e65a97fd815ce1d2cb41c94968fcc9ffde7726b72fe4e0180c
+DIST dandi-0.55.1.tar.gz 296372 BLAKE2B 06d1b020bc3362f64779da8a4d229c9919c1edee83b530bf248c7dfa591f97c10b08eb1e9cb2f54ec30d8e7a1bcc0ffe9ee8f925e0a51fb0ba3882699a605a33 SHA512 341f82b8b59ececf8addbb0a9087e2a5ace3b0c452d4da1d94c413daef594590d8350ba4421a077865a4eafbcefe4189478f385e8cfe0dd53a9e46c7782b3ce5
diff --git a/dev-vcs/dandi-cli/dandi-cli-0.55.1.ebuild b/dev-vcs/dandi-cli/dandi-cli-0.55.1.ebuild
new file mode 100644
index 000000000..964cee45d
--- /dev/null
+++ b/dev-vcs/dandi-cli/dandi-cli-0.55.1.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+
+inherit distutils-r1 pypi
+
+MY_PN="dandi"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="DANDI command line client to facilitate common operations"
+HOMEPAGE="https://github.com/dandi/dandi-cli"
+SRC_URI="$(pypi_sdist_url dandi)"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test etelemetry"
+
+# Urllib dependency is a workaround for vcrpy::gentoo
+# Remove when https://github.com/gentoo/gentoo/pull/31141 is merged
+RDEPEND="
+	<dev-python/urllib3-2[${PYTHON_USEDEP}]
+	=dev-python/dandi-schema-0.8*[${PYTHON_USEDEP}]
+	>=dev-python/pydantic-1.9.0[${PYTHON_USEDEP}]
+	>=sci-biology/bidsschematools-0.7.0[${PYTHON_USEDEP}]
+	dev-python/appdirs[${PYTHON_USEDEP}]
+	dev-python/click-didyoumean[${PYTHON_USEDEP}]
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/fasteners[${PYTHON_USEDEP}]
+	dev-python/fscacher[${PYTHON_USEDEP}]
+	dev-python/humanize[${PYTHON_USEDEP}]
+	dev-python/interleave[${PYTHON_USEDEP}]
+	dev-python/joblib[${PYTHON_USEDEP}]
+	dev-python/keyring[${PYTHON_USEDEP}]
+	dev-python/keyrings-alt[${PYTHON_USEDEP}]
+	dev-python/nwbinspector[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	dev-python/pycryptodome[${PYTHON_USEDEP}]
+	dev-python/pynwb[${PYTHON_USEDEP}]
+	dev-python/pyout[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	dev-python/semantic_version[${PYTHON_USEDEP}]
+	dev-python/tenacity[${PYTHON_USEDEP}]
+	dev-python/wheel[${PYTHON_USEDEP}]
+	dev-python/zarr[${PYTHON_USEDEP}]
+	dev-python/zarr_checksum[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	test? (
+		dev-python/anys[${PYTHON_USEDEP}]
+		dev-python/pyfakefs[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
+		dev-python/responses[${PYTHON_USEDEP}]
+		dev-python/vcrpy[${PYTHON_USEDEP}]
+		media-libs/opencv[ffmpeg,${PYTHON_USEDEP}]
+	)
+"
+# Upstream might be amenable to dropping opencv:
+# https://github.com/dandi/dandi-cli/issues/944
+
+S="${WORKDIR}/${MY_P}"
+
+# Reported upstream:
+# https://github.com/dandi/dandi-cli/issues/1297
+EPYTEST_DESELECT=(
+	dandi/tests/test_files.py::test_validate_bogus
+)
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	if use etelemetry; then
+		default
+	else
+		eapply "${FILESDIR}/${PN}-0.28.0-no-etelemetry.patch"
+		default
+		sed -i "/etelemetry/d" setup.cfg
+	fi
+}
+
+python_test() {
+	export DANDI_TESTS_NONETWORK=1
+	epytest
+}