aboutsummaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAisha Tammy <gentoo@aisha.cc>2020-09-26 15:43:58 +0000
committerAisha Tammy <gentoo@aisha.cc>2020-09-26 19:11:03 +0000
commit4d41973331898406b86f2a3f11da50b7a1812336 (patch)
tree0d440f4f2e458d74b5d873e67508bc0671852ea5 /sys-cluster/modules/modules-4.6.0.ebuild
parentsci-libs/ensmallen: fast numerical library (diff)
downloadsci-4d41973331898406b86f2a3f11da50b7a1812336.tar.gz
sci-4d41973331898406b86f2a3f11da50b7a1812336.tar.bz2
sci-4d41973331898406b86f2a3f11da50b7a1812336.zip
sys-cluster/modules: version bump + new maintainer
Closes: https://github.com/gentoo/sci/pull/952 Package-Manager: Portage-3.0.8, Repoman-3.0.1 Signed-off-by: Aisha Tammy <gentoo@aisha.cc>
Diffstat (limited to 'sys-cluster/modules/modules-4.6.0.ebuild')
-rw-r--r--sys-cluster/modules/modules-4.6.0.ebuild64
1 files changed, 64 insertions, 0 deletions
diff --git a/sys-cluster/modules/modules-4.6.0.ebuild b/sys-cluster/modules/modules-4.6.0.ebuild
new file mode 100644
index 000000000..d4053b39c
--- /dev/null
+++ b/sys-cluster/modules/modules-4.6.0.ebuild
@@ -0,0 +1,64 @@
+# Copyright 2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit autotools python-single-r1
+
+DESCRIPTION="Dynamic modification of a user's environment via modulefiles"
+HOMEPAGE="http://modules.sourceforge.net/"
+SRC_URI="https://github.com/cea-hpc/modules/releases/download/v${PV}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="compat test"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND="
+ ${PYTHON_DEPS}
+ dev-lang/tcl:0=
+ dev-tcltk/tclx
+ compat? ( x11-libs/libX11 )
+"
+RDEPEND="${DEPEND}"
+BDEPEND="
+ test? ( dev-util/dejagnu )
+"
+
+src_prepare() {
+ default
+
+ cd "${S}/lib" || die
+ eautoreconf
+
+ if use compat; then
+ cd "${S}/compat" || die
+ eautoreconf
+ fi
+}
+
+src_configure() {
+ local myconf=(
+ --disable-versioning
+ --prefix="${EPREFIX}/usr/share/Modules"
+ --mandir="${EPREFIX}/usr/share/man"
+ --docdir="${EPREFIX}/usr/share/doc/${P}"
+ --libdir="${EPREFIX}/usr/share/Modules/$(get_libdir)"
+ --datarootdir="${EPREFIX}/usr/share"
+ --modulefilesdir="${EPREFIX}/etc/modulefiles"
+ --with-tcl="${EPREFIX}/usr/$(get_libdir)"
+ --with-python="${PYTHON}"
+ $(use_enable compat compat-version)
+ )
+ ./configure "${myconf[@]}" ${EXTRA_ECONF[@]} || die "configure failed"
+}
+
+src_install() {
+ default
+ dosym ../../usr/share/Modules/init/profile.sh /etc/profile.d/modules.sh
+ dosym ../../usr/share/Modules/init/profile.csh /etc/profile.d/modules.csh
+ dodir /etc/modulefiles
+}