1 files changed, 51 insertions, 0 deletions
diff --git a/dev-java/flexdock/flexdock-1.2.0.ebuild b/dev-java/flexdock/flexdock-1.2.0.ebuild
new file mode 100644
index 000000000..f24cc2510
--- /dev/null
+++ b/dev-java/flexdock/flexdock-1.2.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="2"
+JAVA_PKG_IUSE="doc source"
+
+inherit java-pkg-2 java-ant-2
+
+DESCRIPTION="A Java docking framework for use in cross-platform Swing applications"
+HOMEPAGE="http://flexdock.dev.java.net/"
+SRC_URI="http://forge.scilab.org/index.php/p/flexdock/downloads/get/${P}-src.zip"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~x86 ~amd64"
+
+IUSE=""
+
+RDEPEND=">=virtual/jre-1.4"
+DEPEND=">=virtual/jdk-1.4
+	app-arch/unzip
+	dev-java/skinlf"
+
+EANT_BUILD_TARGET="jar"
+EANT_DOC_TARGET="doc"
+
+src_unpack() {
+	mkdir "${WORKDIR}/${P}"
+	cd "${S}"
+	unpack ${A}
+}
+
+java_prepare() {
+	epatch "${FILESDIR}"/${P}-nodemo.patch
+
+	#some cleanups
+	find . -name '*.so' -exec rm -v {} \;|| die
+	find . -name '*.dll' -exec rm -v {} \;|| die
+
+	#remove built-in jars and use the system ones
+	cd lib || die
+	rm -rvf *.jar jmf|| die
+	java-pkg_jar-from skinlf
+}
+
+src_install() {
+	java-pkg_newjar "build/${P}.jar" "${PN}.jar"
+	use doc && java-pkg_dojavadoc build/docs/api
+	use source && java-pkg_dosrc src
+}