1 files changed, 47 insertions, 0 deletions
diff --git a/dev-ml/ocamlgraph/ocamlgraph-1.5.ebuild b/dev-ml/ocamlgraph/ocamlgraph-1.5.ebuild
new file mode 100644
index 000000000..dffb06128
--- /dev/null
+++ b/dev-ml/ocamlgraph/ocamlgraph-1.5.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="2"
+
+inherit eutils autotools
+
+DESCRIPTION="A graph library for Objective Caml"
+HOMEPAGE="http://ocamlgraph.lri.fr/"
+SRC_URI="http://ocamlgraph.lri.fr/download/${P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="doc examples gtk +ocamlopt"
+
+DEPEND=">=dev-lang/ocaml-3.10.2[ocamlopt?]
+	gtk? ( >=dev-ml/lablgtk-2.6 )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-makefile.patch"
+	eautoreconf
+}
+
+src_compile() {
+	emake -j1 DESTDIR="/" || die "emake failed"
+
+	if use doc; then
+		emake doc || die "emake doc failed"
+	fi
+}
+
+src_install() {
+	emake install DESTDIR="${D}" || die "emake install failed"
+	dodoc CHANGES CREDITS FAQ README
+
+	if use doc; then
+		dohtml doc/*
+	fi
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}
+		doins -r examples
+	fi
+}