1 files changed, 55 insertions, 0 deletions
diff --git a/sci-chemistry/molrep/molrep-10.2.33.ebuild b/sci-chemistry/molrep/molrep-10.2.33.ebuild
new file mode 100644
index 000000000..09be4f2a0
--- /dev/null
+++ b/sci-chemistry/molrep/molrep-10.2.33.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="2"
+
+inherit base multilib toolchain-funcs
+
+DESCRIPTION="molecular replacement program"
+HOMEPAGE="http://www.ysbl.york.ac.uk/~alexei/molrep.html"
+SRC_URI="http://dev.gentooexperimental.org/~jlec/science-dist/${P}.tar.gz"
+
+LICENSE="ccp4"
+
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE=""
+RDEPEND=">=sci-libs/ccp4-libs-6.1.1
+	virtual/lapack"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${PN}"
+
+PATCHES=(
+	"${FILESDIR}"/${PV}-respect-FLAGS.patch
+	)
+
+src_compile() {
+	cd "${S}"/src
+	emake \
+		MR_FORT=$(tc-getFC) \
+		FFLAGS="${FFLAGS}" \
+		LDFLAGS="${LDFLAGS}" \
+		MR_LIBRARY="-L/usr/$(get_libdir) -lccp4f -lccp4c -lmmdb -lccif -llapack -lstdc++ -lm" \
+	|| die
+}
+
+src_test() {
+	ewarn "Can take a long, long time ..."
+	ewarn "Go, take a coffee, lunch, go to sleep and have breakfast ..."
+	cd molrep_check && \
+		sed 's:\.\.:\.:g' -i em.bat && \
+		mkdir out && \
+		mkdir scr && \
+		MR_TEST="${S}/bin" bash em.bat && \
+		MR_TEST="${S}/bin" bash mr.bat || \
+		die "test failed"
+}
+
+src_install() {
+	dobin bin/${PN} || die
+
+	dodoc readme doc/${PN}.rtf || die
+}