From 1e02b3e237b90e9f0ca460cd564bfae868662345 Mon Sep 17 00:00:00 2001
From: Sébastien Fabbro <bicatali@gentoo.org>
Date: Mon, 24 Jun 2013 09:04:27 -0700
Subject: app-admin/eselect: Version bump

Package-Manager: portage-2.2.01.22013-prefix
RepoMan-Options: --force
---
 app-admin/eselect/eselect-1.3.5-r100.ebuild | 73 +++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)
 create mode 100644 app-admin/eselect/eselect-1.3.5-r100.ebuild

(limited to 'app-admin/eselect/eselect-1.3.5-r100.ebuild')

diff --git a/app-admin/eselect/eselect-1.3.5-r100.ebuild b/app-admin/eselect/eselect-1.3.5-r100.ebuild
new file mode 100644
index 000000000..02d4c4308
--- /dev/null
+++ b/app-admin/eselect/eselect-1.3.5-r100.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-admin/eselect/eselect-1.3.4.ebuild,v 1.1 2013/01/06 19:10:44 ulm Exp $
+
+EAPI=4
+
+inherit autotools eutils bash-completion-r1
+
+DESCRIPTION="Gentoo's multi-purpose configuration and management tool"
+HOMEPAGE="http://www.gentoo.org/proj/en/eselect/"
+SRC_URI="mirror://gentoo/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="doc"
+
+RDEPEND="sys-apps/sed
+	|| (
+		sys-apps/coreutils
+		sys-freebsd/freebsd-bin
+		app-misc/realpath
+	)"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	doc? ( dev-python/docutils )"
+RDEPEND="!app-admin/eselect-news
+	${RDEPEND}
+	sys-apps/file
+	sys-libs/ncurses"
+
+# Commented out: only few users of eselect will edit its source
+#PDEPEND="emacs? ( app-emacs/gentoo-syntax )
+#	vim-syntax? ( app-vim/eselect-syntax )"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-alternatives.patch
+	AT_M4DIR="." eautoreconf
+}
+
+src_compile() {
+	emake
+	use doc && emake html
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	newbashcomp misc/${PN}.bashcomp ${PN}
+	dodoc AUTHORS ChangeLog NEWS README TODO doc/*.txt
+	use doc && dohtml *.html doc/*
+
+	# needed by news module
+	keepdir /var/lib/gentoo/news
+	if ! use prefix; then
+		fowners root:portage /var/lib/gentoo/news
+		fperms g+w /var/lib/gentoo/news
+	fi
+
+	# band aid for prefix
+	if use prefix; then
+		cd "${ED}"/usr/share/eselect/libs
+		sed -i "s:ALTERNATIVESDIR_ROOTLESS=\"${EPREFIX}:ALTERNATIVESDIR_ROOTLESS=\":" alternatives.bash || die
+	fi
+}
+
+pkg_postinst() {
+	# fowners in src_install doesn't work for the portage group:
+	# merging changes the group back to root
+	if ! use prefix; then
+		chgrp portage "${EROOT}/var/lib/gentoo/news" \
+			&& chmod g+w "${EROOT}/var/lib/gentoo/news"
+	fi
+}
-- 
cgit v1.2.3-65-gdbad