From 07de105b71bd799afbe176d17245cf44d8c742f5 Mon Sep 17 00:00:00 2001
From: Christoph Junghans <ottxor@gentoo.org>
Date: Thu, 4 Oct 2018 06:29:34 -0600
Subject: dev-cpp/kokkos: initial commit

Package-Manager: Portage-2.3.49, Repoman-2.3.10
Signed-off-by: Christoph Junghans <ottxor@gentoo.org>
---
 dev-cpp/kokkos/kokkos-2.7.00.ebuild | 47 +++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 dev-cpp/kokkos/kokkos-2.7.00.ebuild

(limited to 'dev-cpp/kokkos/kokkos-2.7.00.ebuild')

diff --git a/dev-cpp/kokkos/kokkos-2.7.00.ebuild b/dev-cpp/kokkos/kokkos-2.7.00.ebuild
new file mode 100644
index 000000000..f2adfa3d5
--- /dev/null
+++ b/dev-cpp/kokkos/kokkos-2.7.00.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils toolchain-funcs
+
+DESCRIPTION="Kokkos C++ Performance Portability Programming EcoSystem"
+HOMEPAGE="https://github.com/kokkos"
+SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="openmp +threads"
+REQUIRED_USE="?? ( openmp threads )"
+
+DEPEND="
+	sys-apps/hwloc
+	"
+RDEPEND="${DEPEND}"
+BDEPEND=""
+
+pkg_setup() {
+	if [[ ${MERGE_TYPE} != binary ]] && \
+		use openmp && ! tc-has-openmp ; then
+			die "Need an OpenMP capable compiler"
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DKOKKOS_ENABLE_HWLOC=ON
+		-DKOKKOS_HWLOC_DIR="${EPREFIX}/usr"
+		-DKOKKOS_ENABLE_OPENMP=$(usex openmp)
+		-DKOKKOS_ENABLE_PTHREAD=$(usex threads)
+		-DKOKKOS_ENABLE_SERIAL=ON
+		-DBUILD_SHARED_LIBS=ON
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	[[ $(get_libdir) = lib ]] || mv "${ED}"/usr/{lib,"$(get_libdir)"} || die
+}
-- 
cgit v1.2.3-65-gdbad