From d4eea6844d07b4bacd9354ba58c25709cc21958a Mon Sep 17 00:00:00 2001
From: Marius Brehler <marbre@linux.sungazer.de>
Date: Wed, 23 Sep 2015 08:38:28 +0200
Subject: dev-python/nbconvert: Replace symlink

---
 dev-python/nbconvert/nbconvert-4.0.0-r1.ebuild | 79 +++++++++++++++++++++++++-
 dev-python/nbconvert/nbconvert-9999.ebuild     | 15 ++---
 2 files changed, 82 insertions(+), 12 deletions(-)
 mode change 120000 => 100644 dev-python/nbconvert/nbconvert-4.0.0-r1.ebuild

(limited to 'dev-python')

diff --git a/dev-python/nbconvert/nbconvert-4.0.0-r1.ebuild b/dev-python/nbconvert/nbconvert-4.0.0-r1.ebuild
deleted file mode 120000
index ac4dd4146..000000000
--- a/dev-python/nbconvert/nbconvert-4.0.0-r1.ebuild
+++ /dev/null
@@ -1 +0,0 @@
-nbconvert-9999.ebuild
\ No newline at end of file
diff --git a/dev-python/nbconvert/nbconvert-4.0.0-r1.ebuild b/dev-python/nbconvert/nbconvert-4.0.0-r1.ebuild
new file mode 100644
index 000000000..9e298f39c
--- /dev/null
+++ b/dev-python/nbconvert/nbconvert-4.0.0-r1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 python{3_3,3_4} )
+
+inherit distutils-r1
+
+MY_PN="nbconvert"
+
+DESCRIPTION="Converting Jupyter Notebooks"
+HOMEPAGE="http://jupyter.org"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="BSD"
+SLOT="0"
+IUSE="doc test"
+
+PATCHES=(
+	"${FILESDIR}/${P}"-docs-Makefile.patch
+	"${FILESDIR}/${P}"-pandoc-highlighting.patch
+)
+
+RDEPEND="
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	dev-python/mistune[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/traitlets[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	doc? (
+		dev-python/ipython[${PYTHON_USEDEP}]
+		dev-python/jupyter_client[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		app-text/pandoc
+	)
+	test? (
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/coverage[${PYTHON_USEDEP}]
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+	)
+	"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	if use doc; then
+		sed -e "/^    'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	fi
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	distutils_install_for_testing
+	cd "${TEST_DIR}"/lib || die
+	nosetests --with-coverage --cover-package=nbconvert nbconvert || die
+}
+
+python_install_all() {
+	use doc && HTML_DOCS=( docs/build/html/. )
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	if ! has_version app-text/pandoc ; then
+		einfo "Pandoc is required for converting to formats other than Python,"
+		einfo "HTML, and Markdown. If you need this functionality, install"
+		einfo "app-text/pandoc."
+	fi
+}
diff --git a/dev-python/nbconvert/nbconvert-9999.ebuild b/dev-python/nbconvert/nbconvert-9999.ebuild
index 297f7bf04..c97ed8a75 100644
--- a/dev-python/nbconvert/nbconvert-9999.ebuild
+++ b/dev-python/nbconvert/nbconvert-9999.ebuild
@@ -5,27 +5,20 @@
 EAPI=5
 PYTHON_COMPAT=( python2_7 python{3_3,3_4} )
 
-inherit distutils-r1
+inherit distutils-r1 git-r3
 
 MY_PN="nbconvert"
 
 DESCRIPTION="Converting Jupyter Notebooks"
 HOMEPAGE="http://jupyter.org"
-
-PATCHES=( "${FILESDIR}/${PN}"-4.0.0-docs-Makefile.patch )
-if [ ${PV} == "9999" ] ; then
-	inherit git-r3
-	EGIT_REPO_URI="https://github.com/jupyter/${MY_PN}.git git://github.com/jupyter/${MY_PN}.git"
-	else
-	SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
-	KEYWORDS="~amd64 ~x86"
-	PATCHES+=( "${FILESDIR}"/${P}-pandoc-highlighting.patch )
-fi
+EGIT_REPO_URI="https://github.com/jupyter/${MY_PN}.git git://github.com/jupyter/${MY_PN}.git"
 
 LICENSE="BSD"
 SLOT="0"
 IUSE="doc test"
 
+PATCHES=( "${FILESDIR}/${PN}"-4.0.0-docs-Makefile.patch )
+
 RDEPEND="
 	dev-python/jupyter_core[${PYTHON_USEDEP}]
 	dev-python/nbformat[${PYTHON_USEDEP}]
-- 
cgit v1.2.3-65-gdbad