From d45fc71a94a3141dab111822c3ba84dd64c06bfc Mon Sep 17 00:00:00 2001
From: "Andreas K. Huettel (dilfridge)" <mail@akhuettel.de>
Date: Tue, 15 Jun 2010 20:37:48 +0200
Subject: [sci-electronics/klayout] Imported from sunrise.

---
 sci-electronics/klayout/klayout-0.20.ebuild | 82 +++++++++++++++++++++++++++++
 1 file changed, 82 insertions(+)
 create mode 100644 sci-electronics/klayout/klayout-0.20.ebuild

(limited to 'sci-electronics/klayout/klayout-0.20.ebuild')

diff --git a/sci-electronics/klayout/klayout-0.20.ebuild b/sci-electronics/klayout/klayout-0.20.ebuild
new file mode 100644
index 000000000..916e1e022
--- /dev/null
+++ b/sci-electronics/klayout/klayout-0.20.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="2"
+
+inherit eutils multilib toolchain-funcs
+
+DESCRIPTION="Viewer and editor for GDS and OASIS integrated circuit layouts"
+HOMEPAGE="http://www.klayout.de/"
+SRC_URI="http://www.klayout.de/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ruby"
+
+RDEPEND="x11-libs/qt-gui:4[qt3support]
+	ruby? ( dev-lang/ruby )"
+
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	epatch "${FILESDIR}/${P}-configureonly.patch"
+
+	# now we generate the stub build configuration file for the home-brew build system
+	cp "${FILESDIR}/${P}-Makefile.conf.linux-gentoo" "${S}/config/Makefile.conf.linux-gentoo" || die
+}
+
+src_configure() {
+	local rbinc rblib rbflags
+
+	if use ruby ; then
+
+		# get the location of the ruby.h header file
+		rbinc=$(ruby -rrbconfig -e "puts Config::CONFIG['archdir'] || Config::CONFIG['rubyhdrdir']")
+
+		# get the filename of libruby.so
+		rblib=$(ruby -rrbconfig -e "puts Config::CONFIG['LIBRUBY']")
+
+		rbflags="-rblib /usr/$(get_libdir)/${rblib} -rbinc ${rbinc}"
+
+	fi
+
+	./build.sh \
+		-platform linux-gentoo \
+		-bin bin \
+		-qtbin /usr/bin \
+		-qtinc /usr/include/qt4 \
+		-qtlib /usr/$(get_libdir)/qt4 \
+		${rbflags} || die "Configuration failed"
+}
+
+src_compile() {
+	cd build.linux-gentoo
+	tc-export CC CXX AR LD RANLIB
+	export AR="${AR} -r"
+	emake all || die "Build failed"
+}
+
+src_install() {
+	cd build.linux-gentoo
+	emake install || die "make install failed"
+
+	cd ..
+	dobin \
+		bin/klayout \
+		bin/strm2gds \
+		bin/strm2oas \
+		bin/strmclip \
+		bin/strmcmp || die "Installation of binaries failed"
+
+	insinto /usr/share/${PN}/testdata/gds
+	doins testdata/gds/*.gds || die "Installation of gds testdata failed"
+	insinto /usr/share/${PN}/testdata/oasis
+	doins testdata/oasis/*.oas testdata/oasis/*.ot || die "Installation of oasis testdata failed"
+
+	if use ruby; then
+		insinto /usr/share/${PN}
+		doins -r testdata/ruby || die "Installation of ruby testdata failed"
+	fi
+}
-- 
cgit v1.2.3