From 7508ba371a633fc9e06c10557a8a022d1d052378 Mon Sep 17 00:00:00 2001
From: Matthias Maier <tamiko@gentoo.org>
Date: Fri, 11 May 2018 17:11:59 -0500
Subject: sci-libs/dealii: version bump to 9.0.0

Package-Manager: Portage-2.3.36, Repoman-2.3.9
---
 sci-libs/dealii/Manifest            |   2 +
 sci-libs/dealii/dealii-9.0.0.ebuild | 144 ++++++++++++++++++++++++++++++++++++
 2 files changed, 146 insertions(+)
 create mode 100644 sci-libs/dealii/dealii-9.0.0.ebuild

(limited to 'sci-libs/dealii')

diff --git a/sci-libs/dealii/Manifest b/sci-libs/dealii/Manifest
index b4b53c1e7..5fca17349 100644
--- a/sci-libs/dealii/Manifest
+++ b/sci-libs/dealii/Manifest
@@ -2,3 +2,5 @@ DIST dealii-8.4.2-offline_documentation.tar.gz 154647046 SHA256 cdbe7625bd9b88a6
 DIST dealii-8.4.2.tar.gz 13973439 BLAKE2B 29d3c3975aaa666c6a0c9cf7fe1aab021f22cd972176c4682f7149dc172f4073b0f49590959e0d8ae61cf08cd11f1e3443f355c2e1782a98db11da4675829063 SHA512 a6e558b97d5753b03890a6d5a4192a62437dbe0ce6f87724124a9daf12fc4c44553729423ea7a3139fbb114292e04e7863a6f52b79eb5e223fecfd35c521c849
 DIST dealii-8.5.0-offline_documentation.tar.gz 158982121 SHA256 e003e2d863992855b977fbb6c4a050ee9e32b5cf95fd5dbaa04e51e64967aa85 SHA512 ccf5de81ab23f698d9d8331286524328fa8934ef36c251b9c5c999c9532114b550e4ab7899a02925a6b41fc7b4f9554c3796a62c0f4397e1cbe6abbf898fdab8 WHIRLPOOL 6044e9aa48731ce0e9ea3eef3c06d9f8b2a10dd0ab6a89c092e9995503e65aa9835e7a051019b0f77f1878433355dbe36c8a4009d7dda8b178edd50d7cb2aa66
 DIST dealii-8.5.0.tar.gz 14919546 BLAKE2B 686ff5d66ce20d2da8a37e44bdca04a249881da8ab09b1fbd1e6fb0496b53e14b05ce576dcf3539b30443cec680e89c5bae3f3442417c66af726709de39ccfa3 SHA512 58a8cb18aa166a46e25c03335d0b65515452080858593fe35b93623e45cd340fbc7bce1059388c055736c2f5c154c4b68df1620cf8ad9ff6b07644541b60accc
+DIST dealii-9.0.0-offline_documentation.tar.gz 192621253 BLAKE2B 9822e4bfda98f108624020b35831df6f4df8e53d12c4456532f7467868074631aa18dc9b1229d208385879690cd21b0a1f604157777273880a95d126db7989fe SHA512 8d53be928ef5af68bbef1b94381d8004fc8244d949992648734f18f28c5460e2be3fe0c76fefa2351a61c132013047b8fa06edb7a41cb81033ed95ac93c45248
+DIST dealii-9.0.0.tar.gz 17629427 BLAKE2B f9e175450565ef999dc0dac6f7cc6b7a48ce8ce2910ff5ebacb5b803438a1e008bd7382ae2a061fd6211bf5173aca5a2a76a2c2c7dded95480710c7d2d4530c1 SHA512 901b12157d5e58d2174b8a55839405a7c01219806dc3997094a5754a82e35709b36b61f158a87b219a41de1ab8dd034bbc621469c6be2b784563433fe2891a9d
diff --git a/sci-libs/dealii/dealii-9.0.0.ebuild b/sci-libs/dealii/dealii-9.0.0.ebuild
new file mode 100644
index 000000000..6992d107a
--- /dev/null
+++ b/sci-libs/dealii/dealii-9.0.0.ebuild
@@ -0,0 +1,144 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils eutils multilib
+
+# deal.II uses its own FindLAPACK.cmake file that calls into the system
+# FindLAPACK.cmake module and does additional internal setup. Do not remove
+# any of these modules:
+CMAKE_REMOVE_MODULES_LIST=""
+
+DESCRIPTION="Solving partial differential equations with the finite element method"
+HOMEPAGE="http://www.dealii.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/dealii/dealii.git"
+	SRC_URI=""
+	KEYWORDS=""
+else
+	MY_PV="${PV//0_rc/rc}"
+	MY_P="${PN}-${MY_PV}"
+	SRC_URI="https://github.com/dealii/dealii/archive/v${MY_PV}.tar.gz -> ${P}.tar.gz
+		doc? (
+			https://github.com/${PN}/${PN}/releases/download/v${MY_PV}/${MY_P}-offline_documentation.tar.gz
+			-> ${P}-offline_documentation.tar.gz
+			)"
+	KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+fi
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="
+	adolc assimp arpack cpu_flags_x86_avx cpu_flags_x86_sse2 cuda +debug
+	doc +examples gmsh +gsl hdf5 +lapack metis mpi muparser nanoflann
+	opencascade netcdf p4est petsc scalapack slepc +sparse static-libs
+	sundials +tbb trilinos
+"
+
+# TODO: add slepc use flag once slepc is packaged for gentoo-science
+REQUIRED_USE="
+	p4est? ( mpi )
+	slepc? ( petsc )
+	trilinos? ( mpi )"
+
+RDEPEND="dev-libs/boost
+	app-arch/bzip2
+	sys-libs/zlib
+	adolc? ( sci-libs/adolc )
+	arpack? ( sci-libs/arpack[mpi=] )
+	assimp? ( media-libs/assimp )
+	cuda? ( dev-util/nvidia-cuda-sdk )
+	gmsh? ( sci-libs/gmsh )
+	gsl? ( sci-libs/gsl )
+	hdf5? ( sci-libs/hdf5[mpi=] )
+	lapack? ( virtual/lapack )
+	metis? ( >=sci-libs/parmetis-4 )
+	mpi? ( virtual/mpi )
+	muparser? ( dev-cpp/muParser )
+	nanoflann? ( sci-libs/nanoflann )
+	netcdf? ( sci-libs/netcdf-cxx:0 )
+	opencascade? ( sci-libs/opencascade:* )
+	p4est? ( sci-libs/p4est[mpi] )
+	petsc? ( sci-mathematics/petsc[mpi=] )
+	scalapack? ( sci-libs/scalapack )
+	slepc? ( sci-mathematics/slepc[mpi=] )
+	sparse? ( sci-libs/umfpack )
+	sundials? ( sci-libs/sundials )
+	tbb? ( dev-cpp/tbb )
+	trilinos? ( sci-libs/trilinos )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen[dot] dev-lang/perl )"
+
+src_configure() {
+	# deal.II needs a custom build type:
+	local CMAKE_BUILD_TYPE=$(usex debug DebugRelease Release)
+
+	local mycmakeargs=(
+		-DDEAL_II_PACKAGE_VERSION=9999
+		-DCMAKE_INSTALL_RPATH_USE_LINK_PATH=OFF
+		-DDEAL_II_ALLOW_AUTODETECTION=OFF
+		-DDEAL_II_ALLOW_BUNDLED=OFF
+		-DDEAL_II_ALLOW_PLATFORM_INTROSPECTION=OFF
+		-DDEAL_II_COMPILE_EXAMPLES=OFF
+		-DDEAL_II_DOCHTML_RELDIR="share/doc/${P}/html"
+		-DDEAL_II_DOCREADME_RELDIR="share/doc/${P}"
+		-DDEAL_II_COMPILE_EXAMPLES=OFF
+		-DDEAL_II_EXAMPLES_RELDIR="share/doc/${P}/examples"
+		-DDEAL_II_LIBRARY_RELDIR="$(get_libdir)"
+		-DDEAL_II_SHARE_RELDIR="share/${PN}"
+		-DDEAL_II_WITH_BZIP2=ON
+		-DDEAL_II_WITH_ZLIB=ON
+		-DDEAL_II_WITH_ADOLC="$(usex adolc)"
+		-DDEAL_II_WITH_ASSIMP="$(usex assimp)"
+		-DDEAL_II_WITH_ARPACK="$(usex arpack)"
+		-DDEAL_II_HAVE_AVX="$(usex cpu_flags_x86_avx)"
+		-DDEAL_II_WITH_CUDA="$(usex cuda)"
+		-DDEAL_II_HAVE_SSE2="$(usex cpu_flags_x86_sse2)"
+		-DDEAL_II_COMPONENT_DOCUMENTATION="$(usex doc)"
+		-DDEAL_II_COMPONENT_EXAMPLES="$(usex examples)"
+		-DDEAL_II_WITH_GMSH="$(usex gmsh)"
+		-DDEAL_II_WITH_GSL="$(usex gsl)"
+		-DDEAL_II_WITH_HDF5="$(usex hdf5)"
+		-DDEAL_II_WITH_LAPACK="$(usex lapack)"
+		-DDEAL_II_WITH_METIS="$(usex metis)"
+		-DDEAL_II_WITH_MPI="$(usex mpi)"
+		-DDEAL_II_WITH_MUPARSER="$(usex muparser)"
+		-DDEAL_II_WITH_NANOFLANN="$(usex nanoflann)"
+		-DDEAL_II_WITH_NETCDF="$(usex netcdf)"
+		-DOPENCASCADE_DIR="${CASROOT}"
+		-DDEAL_II_WITH_OPENCASCADE="$(usex opencascade)"
+		-DDEAL_II_WITH_P4EST="$(usex p4est)"
+		-DDEAL_II_WITH_PETSC="$(usex petsc)"
+		-DDEAL_II_WITH_SCALAPACK="$(usex scalapack)"
+		-DDEAL_II_WITH_SLEPC="$(usex slepc)"
+		-DDEAL_II_WITH_SUNDIALS="$(usex sundials)"
+		-DDEAL_II_WITH_UMFPACK="$(usex sparse)"
+		-DBUILD_SHARED_LIBS="$(usex !static-libs)"
+		-DDEAL_II_PREFER_STATIC_LIBS="$(usex static-libs)"
+		-DDEAL_II_WITH_THREADS="$(usex tbb)"
+		-DDEAL_II_WITH_TRILINOS="$(usex trilinos)"
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	if use doc && [[ ${PV} != *9999* ]]; then
+		# copy missing images to the build directory:
+		cp -r "${WORKDIR}"/doc/doxygen/deal.II/images \
+			"${BUILD_DIR}"/doc/doxygen/deal.II || die
+		# replace links:
+		sed -i \
+			's#"http://www.dealii.org/images/steps/developer/\(step-.*\)"#"images/\1"#g' \
+			"${BUILD_DIR}"/doc/doxygen/deal.II/step_*.html || die "sed failed"
+	fi
+	cmake-utils_src_install
+
+	# decompress the installed example sources:
+	use examples && docompress -x /usr/share/doc/${PF}/examples
+}
-- 
cgit v1.2.3