blob: c98fb2ec19c6385fbffae2ba3443e11d7ca9bb11 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
# Copyright 1999-2012 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: $
EAPI=4
inherit cmake-utils alternatives-2 fortran-2 multilib
DESCRIPTION="C++ template library for linear algebra"
HOMEPAGE="http://eigen.tuxfamily.org/"
SRC_URI="http://bitbucket.org/eigen/eigen/get/${PV}.tar.bz2 -> ${P}.tar.bz2"
LICENSE="|| ( LGPL-3 GPL-2 )"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
SLOT="3"
IUSE="adolc fortran fftw doc gmp sparse static-libs test"
CDEPEND="adolc? ( sci-libs/adolc[sparse?] )
fftw? ( >=sci-libs/fftw-3 )
gmp? ( dev-libs/gmp dev-libs/mpfr )
sparse? ( dev-cpp/sparsehash
sci-libs/cholmod[metis]
sci-libs/superlu
sci-libs/umfpack )"
DEPEND="doc? ( app-doc/doxygen[dot,latex] )
test? ( ${CDEPEND} )"
RDEPEND="!dev-cpp/eigen:0
${CDEPEND}"
pkg_setup() {
use fortran && fortran-2_pkg_setup
}
src_unpack() {
unpack ${A} && mv ${PN}* ${P}
}
src_configure() {
# TOFIX: static-libs for blas are always built with PIC
# TOFIX: is it worth fixing all the automagic given no library is built?
mycmakeargs=(
-DEIGEN_BUILD_BTL=OFF
$(cmake-utils_use test EIGEN_BUILD_TESTS)
$(cmake-utils_use !fortran EIGEN_TEST_NO_FORTRAN)
)
CMAKE_BUILD_TYPE="release" cmake-utils_src_configure
use fortran && FORTRAN_LIBS="blas" # lapack not ready yet
}
src_compile() {
local targets="${FORTRAN_LIBS}"
use doc && targets+=" doc"
use test && targets+=" buildtests"
cmake-utils_src_compile ${targets}
}
src_install() {
cmake-utils_src_install
use doc && dohtml -r "${CMAKE_BUILD_DIR}"/doc/html/*
local x
for x in ${FORTRAN_LIBS}; do
local libname="eigen_${x}"
cd "${CMAKE_BUILD_DIR}"/${x}
dolib.so lib${libname}.so
use static-libs && newlib.a lib${libname}_static.a lib${libname}.a
cat > ${libname}.pc <<-EOF
prefix=${EPREFIX}/usr
libdir=\${prefix}/$(get_libdir)
includedir=\${prefix}/include
Name: ${PN}
Description: ${DESCRIPTION} ${x^^} implementation
Version: ${PV}
URL: ${HOMEPAGE}
Libs: -L\${libdir} -l${libname}
Libs.private: -lm
$([[ ${x} == lapack ]] && echo "Requires: blas")
EOF
alternatives_for ${x} eigen 0 \
/usr/$(get_libdir)/pkgconfig/${x}.pc ${libname}.pc
insinto /usr/$(get_libdir)/pkgconfig
doins ${libname}.pc
done
}
|
GitWeb