blob: 772793be5018343ab1c824bc7a80685e3fa5f39e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{8..9} )
inherit distutils-r1 virtualx desktop xdg
DESCRIPTION="The Python IDE for scientific computing"
HOMEPAGE="https://pyzo.org/"
SRC_URI="https://github.com/${PN}/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~amd64"
# For some reason this requires network access
# Qt: Session management error: Could not open network socket
RESTRICT="test"
RDEPEND="
dev-python/QtPy[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/visvis[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
distutils_enable_sphinx doc
python_prepare_all() {
# Use relative path to avoid access violation
# Do not install the license file, install other data_files manually
sed -i \
-e 's:/usr/share/metainfo:share/metainfo:g' \
-e '/LICENSE.md/d' \
setup.py || die
distutils-r1_python_prepare_all
}
src_test() {
virtx python_foreach_impl python_test
}
python_install() {
distutils-r1_python_install
python_doscript pyzolauncher.py
}
python_install_all() {
insinto /usr/share/metainfo/
doins pyzo.appdata.xml
for size in 16 32 48 64 128; do
newicon -s ${size} "${PN}/resources/appicons/pyzologo${size}.png" pyzologo.png
done
domenu "${PN}/resources/${PN}.desktop"
distutils-r1_python_install_all
}
|
GitWeb
