aboutsummaryrefslogtreecommitdiff
blob: 3cceb80158ce0bc27969eec8f57891c4c3eb293d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5

inherit eutils toolchain-funcs

DESCRIPTION="Secure file transfer software with its own transfer protocol optimized for files larger than 2GB"
HOMEPAGE="http://doc.in2p3.fr/bbftp/"
SRC_URI="http://doc.in2p3.fr/bbftp/dist/${P}.tar.gz"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64"
IUSE="pam ssl"

DEPEND="ssl? ( dev-libs/openssl:0 )"
RDEPEND="${DEPEND}"

S="${WORKDIR}/${P}/bbftpd"

src_prepare() {
	epatch "${FILESDIR}"/${PV}-deffixes.patch

	sed \
		-e '/@INSTALL@\|mkdir/s:${\(prefix\|mandir\|bindir\)}:${DESTDIR}${\1}:' \
		-e '/\/etc/d' \
		-i Makefile.in

	tc-export CC
}

src_configure() {
	econf \
		$(use_with ssl) \
		$(use_with pam) \
		--with-gzip \
		--without-rfio \
		--without-afs
}

src_install() {
	DOCS=( ../README ../ChangeLog ../TODO ../doc/. )
	default

	newinitd "${FILESDIR}"/bbftpd.init.d bbftpd
	doman ../doc/bbftpd.1
	if use pam; then
		echo -e "#%PAM-1.0\nauth include system-auth\naccount include system-auth" >> "${T}"/bbftp.pam
		insinto /etc/pam.d
		newins "${T}"/bbftp.pam bbftp
	fi
}