aboutsummaryrefslogtreecommitdiff
blob: 3548eb7c274f8f369288635f4a5f1f22c27f557b (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=5

PYTHON_COMPAT=( python2_7 )

inherit cmake-utils fortran-2 python-any-r1

MYP=lapack-${PV}

DESCRIPTION="Test Matrix Generator library for LAPACK"
HOMEPAGE="http://www.netlib.org/lapack/"
SRC_URI="http://www.netlib.org/lapack/${MYP}.tgz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="static-libs test"

REQUIRED_USE="test? ( ${PYTHON_REQUIRED_USE} )"

RDEPEND="
	virtual/blas
	virtual/lapack"
DEPEND="${RDEPEND}
	test? ( ${PYTHON_DEPS} )
	virtual/pkgconfig"

S="${WORKDIR}/${MYP}"

src_prepare() {
	use static-libs && mkdir "${WORKDIR}/${PN}_static"
}

src_configure() {
	tmg_configure() {
		local mycmakeargs=(
			-DUSE_OPTIMIZED_BLAS=ON
			-DUSE_OPTIMIZED_LAPACK=ON
			-DBLAS_LIBRARIES="$($(tc-getPKG_CONFIG) --libs blas)"
			-DLAPACK_LIBRARIES="$($(tc-getPKG_CONFIG) --libs lapack)"
			-DTESTING=ON
			$@
		)
		cmake-utils_src_configure
	}

	tmg_configure -DBUILD_SHARED_LIBS=ON -DBUILD_STATIC_LIBS=OFF
	use static-libs && \
		BUILD_DIR="${WORKDIR}/${PN}_static" tmg_configure \
		-DBUILD_SHARED_LIBS=OFF -DBUILD_STATIC_LIBS=ON
}

src_compile() {
	cmake-utils_src_compile -C TESTING/MATGEN
	use static-libs && BUILD_DIR="${WORKDIR}/${PN}_static" \
		cmake-utils_src_compile -C TESTING/MATGEN
}

src_install() {
	cmake-utils_src_install -C TESTING/MATGEN
	use static-libs && BUILD_DIR="${WORKDIR}/${PN}_static" \
			cmake-utils_src_install -C TESTING/MATGEN
}