1 files changed, 77 insertions, 0 deletions
diff --git a/gnome-extra/nautilus-dropbox/nautilus-dropbox-0.6.1-r1.ebuild b/gnome-extra/nautilus-dropbox/nautilus-dropbox-0.6.1-r1.ebuild
new file mode 100644
index 000000000..07f852e4a
--- /dev/null
+++ b/gnome-extra/nautilus-dropbox/nautilus-dropbox-0.6.1-r1.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="2"
+
+inherit eutils libtool linux-info python gnome2
+
+DESCRIPTION="Store, Sync and Share Files Online"
+HOMEPAGE="http://www.getdropbox.com/"
+SRC_URI="http://www.getdropbox.com/download?dl=packages/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="static-libs"
+
+RDEPEND="gnome-base/nautilus
+	dev-python/pygtk
+	dev-python/docutils
+	net-misc/wget
+	x11-libs/libnotify
+	x11-libs/libXinerama"
+
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig"
+
+DOCS="AUTHORS ChangeLog NEWS README"
+
+CONFIG_CHECK="INOTIFY_USER"
+
+pkg_setup () {
+	linux-info_pkg_setup
+
+	# create the group for the daemon, if necessary
+	# truthfully this should be run for any dropbox plugin
+	enewgroup dropbox
+}
+
+src_configure () {
+	econf $(use_enable static-libs static)
+}
+
+src_install () {
+	emake DESTDIR="${D}" install || die
+
+	local extensiondir="$(pkg-config --variable=extensiondir libnautilus-extension)"
+	[ -z ${extensiondir} ] && die "pkg-config unable to get nautilus extensions dir"
+
+	if ! use static-libs; then
+		rm "${D}${extensiondir}"/lib${PN}.la || die "rm .la file failed"
+	fi
+}
+
+pkg_postinst () {
+	gnome2_pkg_postinst
+
+	# Allow only for users in the dropbox group
+	# see http://forums.getdropbox.com/topic.php?id=3329&replies=5#post-22898
+	local extensiondir="$(pkg-config --variable=extensiondir libnautilus-extension)"
+	[ -z ${extensiondir} ] && die "pkg-config unable to get nautilus extensions dir"
+
+	if use static-libs; then
+		chown root:dropbox "${ROOT}${extensiondir}"/lib${PN}.{a,la} || die "chown failed"
+		chmod o-rwx "${ROOT}${extensiondir}"/lib${PN}.{a,la} || die "chmod failed"
+	fi
+	chown root:dropbox "${ROOT}${extensiondir}"/lib${PN}.so || die "chown failed"
+	chmod o-rwx "${ROOT}${extensiondir}"/lib${PN}.so || die "chmod failed"
+
+	elog "Add any users who wish to have access to the dropbox nautilus"
+	elog "plugin to the group 'dropbox'."
+	elog
+	elog "If you've installed old version, Remove \${HOME}/.dropbox-dist first."
+	elog
+	elog " $ rm -rf \${HOME}/.dropbox-dist"
+	elog " $ dropbox start -i"
+}