From 83be9b55981b1e0f3ecc962306e48743913ec7cb Mon Sep 17 00:00:00 2001
From: Justin Lecher <jlec@gentoo.org>
Date: Sat, 30 Apr 2011 16:24:37 +0000
Subject: media-gfx/xaralx: Fix deps for gnome3, Make it compile again,
 included patches from debian

svn path=/sunrise/; revision=11985
---
 media-gfx/xaralx/xaralx-0.7_p1785.ebuild | 77 ++++++++++++++++++++++++++++++++
 1 file changed, 77 insertions(+)
 create mode 100644 media-gfx/xaralx/xaralx-0.7_p1785.ebuild

(limited to 'media-gfx/xaralx/xaralx-0.7_p1785.ebuild')

diff --git a/media-gfx/xaralx/xaralx-0.7_p1785.ebuild b/media-gfx/xaralx/xaralx-0.7_p1785.ebuild
new file mode 100644
index 000000000..f0ded12f1
--- /dev/null
+++ b/media-gfx/xaralx/xaralx-0.7_p1785.ebuild
@@ -0,0 +1,77 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI="4"
+
+WX_GTK_VER="2.8"
+
+inherit eutils wxwidgets autotools gnome2
+
+MY_P=XaraLX-${PV/_p/r}
+
+DESCRIPTION="General purpose vector graphics program"
+HOMEPAGE="http://www.xaraxtreme.org/"
+SRC_URI="http://downloads.xara.com/opensource/${MY_P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	x11-libs/gtk+:2
+	x11-libs/wxGTK:2.8[X]
+	virtual/libintl
+	media-libs/libpng
+	virtual/jpeg
+	app-arch/zip
+	dev-lang/perl
+	dev-libs/libxml2"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	>=sys-devel/gettext-0.14.3"
+
+S=${WORKDIR}/${MY_P/Src/}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${P}-pragma.patch
+	sed -i -e "s/CXFTreeDlg:://" Kernel/cxftree.h
+	sed -i -e "s:XaraLX:xaralx:g" Makefile.am
+	sed -i '/info_ptr->trans/s:trans:trans_alpha:' wxOil/outptpng.cpp
+	AT_M4DIR=". ${S}/m4" eautoreconf
+}
+
+src_configure() {
+	econf \
+		--with-wx-config=${WX_CONFIG} \
+		--with-wx-base-config=${WX_CONFIG} \
+		--enable-xarlib \
+		--enable-filters
+}
+
+src_install() {
+	default
+
+	dodoc doc/{gifutil.txt,mtrand.txt,XSVG.txt}
+
+	insinto /usr/share/${PN}
+	doins -r Designs Templates
+
+	doicon ${PN}.png
+	domenu ${PN}.desktop
+
+	insinto /usr/share/icons/hicolor/48x48/mimetypes
+	newins xaralx.png gnome-mime-application-vnd.xara.png
+	insinto /usr/share/mime/packages
+	doins Mime/xaralx.xml
+	insinto /usr/share/application-registry
+	doins Mime/mime-storage/gnome/xaralx.applications
+	insinto /usr/share/mime-info
+	doins Mime/mime-storage/gnome/xaralx.{keys,mime}
+
+	doman doc/xaralx.1
+	newdoc doc/en/LICENSE LICENSE-docs
+	dodir /usr/share/doc/${PF}/html
+	tar xzf doc/en/xaralxHelp.tar.gz -C "${D}"/usr/share/doc/${PF}/html
+}
-- 
cgit v1.2.3-65-gdbad