Add initscript license, bug 425898

Package-Manager: portage-2.2.0_alpha183

5 files changed, 249 insertions, 9 deletions

diff --git a/app-emulation/vmware-player/Manifest b/app-emulation/vmware-player/Manifest
index fed4de8..d06e95b 100644
--- a/app-emulation/vmware-player/Manifest
+++ b/app-emulation/vmware-player/Manifest
@@ -1,5 +1,7 @@
 DIST VMware-Player-3.1.6-744570.i386.bundle 107116126 SHA256 e612fd4dbe45e14426f8fe72cc5eb88325001952f740b560fdd330e529be0272 SHA512 1399a40a3d357805ad585b60ab60cac2b4cd85bd9c78fe397a7bc313759c904e9d071732108128587612bcac43f311a1de80fdbc1817055e20e6c73b6a7e5149 WHIRLPOOL 297182b1a13e9c44796ad869cbf696cbc5d38b73866cf42283504a2175f7ac1e928c7c430d4f713b24b9a8c050d52f6f5171aa7c9448fa3d7721e5427e1a0dd2
 DIST VMware-Player-3.1.6-744570.x86_64.bundle 103054014 SHA256 ebf74c876bcce6a06c16dceab6116ab9daab057b8276ee337bf54a9f59cce79d SHA512 023e0ed0f5c4e695b738beb4df6286fce9572485c40acfaaf46e4ffbf49b574ac048f297b219dbea7fafa119dcdc700809cb0943309c328d34d92c30f96d8332 WHIRLPOOL e40a5353a2841aa50687e092aee424aa9d77cf7df32acfc2e66c11b6ff04adce5441b123dacedc68896ab7d7c744f69ca834020344425ea9edb77888e81cc560
+DIST VMware-Player-4.0.4-744019.i386.bundle.tar 131993600 SHA256 d06881c512a11fbc76f1c23d7a6c9d7bd3888c613b1678719fa77ed76243d678 SHA512 c1d763374a5d54759cd791669e846479e3ef009dd3d13f16192ca6fdb8727081b5ec510c0b2bf4a311e3e8f3ad905512c0b33be2c70e33e9b4f7037b8349e560 WHIRLPOOL e21bfdf308ee905d8bc6aefb7097b9e30c546186fa7e8750d556a4d3cb144648da36aae2622e54159918cfb5ddab848ee64f225148a0bfb6111264ce763ab067
+DIST VMware-Player-4.0.4-744019.x86_64.bundle.tar 129710080 SHA256 8584e18a4cbed8ce19bd239f8e1cbc2cccd17e2d016faba93fd685a160dade21 SHA512 ba3894fc942e67940d4c2f98f567ee46786a77dc21615ced01314b6dca9919469924bf4c96fdf08ab2443365de03f6a652ca595b6cbb13990ca3671282d01679 WHIRLPOOL ed123a9b22eb1d4fd03afa3b854f3e7d1f12400da75882892f561de3f44860ec67a18a779510ec70715534c03aa21c858721dd92be66a2384152d6a964728ce9
 DIST VMware-Player-4.0.5-893925.i386.bundle.tar 129781760 SHA256 34b48f6603ad204eb019ea07ace4381bdb53b0fb99ae2deebe8e98abdf0c2e41 SHA512 a09c4cddede03a953d63cb5892a88d3abbbf86d91a45e18a5c02f4461810d2ec38a4e5a8af9859082a002aa076e833f84c95043aa0b5e9d4cbc4abf38e65fd64 WHIRLPOOL 9e7c17dac258f9df2a211cfda364548d813f470bfea5790fa8737c02858aa0fad8ffc79a242fd16af54b24f2b298883a5f40502a91c738c5e21ecd99844e2412
 DIST VMware-Player-4.0.5-893925.x86_64.bundle.tar 127262720 SHA256 93454b17065dea2bdb5dd62da74122590162e5e3ef8e5218cc1ebe348189afca SHA512 0b012dd0b28a525500b931fc688286d20c6fac37e2c8e078f3999d9bb5c663e9600e610e9030fbbe3cc55a4dc4b05cf3727cdecb96630cb4ff9010878a471734 WHIRLPOOL 55d8363baced467e97b8718945e7dedd013718353c7a4b4e86234dc774db3456a5ae9ace54e457acd1c724b67df73dcfb95a8d9380aff7ef0e1a07df8db018d0
 DIST VMware-Player-5.0.2-1031769.i386.bundle.tar 220037120 SHA256 9ed94f5137f96d5ab1b4898abb7bdc1ab84edf7eb8b6477ca3f33a9b18e4d0be SHA512 5fac9dc97ff36631c40765fe4e63c734176891441f3dfbeb417d1dae7db02db7b65c799ae706cbbb8edd91c8aed3fe6d11ebbae8c69a82d37b3ddc48261bff5c WHIRLPOOL c7e634f59c6852e58f7665de7db9c4295451592ba61de738e4cac927907b9d662a9b944579aca1474b5bf5c241d1a5bbcc1ed8c07aff1c31d1d39d4a66309fe4
diff --git a/app-emulation/vmware-player/vmware-player-3.1.6.744570.ebuild b/app-emulation/vmware-player/vmware-player-3.1.6.744570.ebuild
index b17e449..541d029 100644
--- a/app-emulation/vmware-player/vmware-player-3.1.6.744570.ebuild
+++ b/app-emulation/vmware-player/vmware-player-3.1.6.744570.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2012 Gentoo Foundation
+# Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/vmware-player/vmware-player-3.1.6.744570.ebuild,v 1.1 2012/06/17 13:09:54 vadimk Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/vmware-player/vmware-player-3.1.6.744570.ebuild,v 1.3 2013/06/22 22:37:55 dilfridge Exp $
 
 EAPI="2"
 
@@ -18,11 +18,11 @@ SRC_URI="
 	amd64? ( ${MY_P}.x86_64.bundle )
 	"
 
-LICENSE="vmware"
+LICENSE="vmware GPL-2"
 SLOT="0"
 KEYWORDS="-* ~amd64 ~x86"
 IUSE="doc +vmware-tools"
-RESTRICT="binchecks fetch strip"
+RESTRICT="fetch strip"
 
 # vmware-workstation should not use virtual/libc as this is a
 # precompiled binary package thats linked to glibc.
diff --git a/app-emulation/vmware-player/vmware-player-4.0.4.744019-r1.ebuild b/app-emulation/vmware-player/vmware-player-4.0.4.744019-r1.ebuild
new file mode 100644
index 0000000..58f4ede
--- /dev/null
+++ b/app-emulation/vmware-player/vmware-player-4.0.4.744019-r1.ebuild
@@ -0,0 +1,238 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/vmware-player/vmware-player-4.0.4.744019-r1.ebuild,v 1.3 2013/06/22 22:37:55 dilfridge Exp $
+
+EAPI="4"
+
+inherit eutils versionator fdo-mime gnome2-utils pax-utils vmware-bundle
+
+MY_PN="VMware-Player"
+MY_PV=$(get_version_component_range 1-3)
+PV_MINOR=$(get_version_component_range 3)
+PV_BUILD=$(get_version_component_range 4)
+MY_P="${MY_PN}-${MY_PV}-${PV_BUILD}"
+
+DESCRIPTION="Emulate a complete PC on your PC without the usual performance overhead of most emulators"
+HOMEPAGE="http://www.vmware.com/products/player/"
+BASE_URI="https://softwareupdate.vmware.com/cds/vmw-desktop/player/${MY_PV}/${PV_BUILD}/linux/core/"
+SRC_URI="
+	x86? ( ${BASE_URI}${MY_P}.i386.bundle.tar )
+	amd64? ( ${BASE_URI}${MY_P}.x86_64.bundle.tar )
+	"
+
+LICENSE="vmware GPL-2"
+SLOT="0"
+KEYWORDS="-* ~amd64 ~x86"
+IUSE="cups doc +vmware-tools"
+RESTRICT="strip"
+
+# vmware-workstation should not use virtual/libc as this is a
+# precompiled binary package thats linked to glibc.
+RDEPEND="dev-cpp/cairomm
+	dev-cpp/glibmm:2
+	dev-cpp/gtkmm:2.4
+	dev-cpp/libgnomecanvasmm:2.6
+	dev-cpp/libsexymm
+	dev-cpp/pangomm:1.4
+	dev-libs/atk
+	dev-libs/glib:2
+	dev-libs/libaio
+	dev-libs/libsigc++
+	dev-libs/libxml2
+	=dev-libs/openssl-0.9.8*
+	dev-libs/xmlrpc-c
+	gnome-base/libgnomecanvas
+	gnome-base/libgtop:2
+	gnome-base/librsvg:2
+	gnome-base/orbit
+	media-libs/fontconfig
+	media-libs/freetype
+	media-libs/libart_lgpl
+	=media-libs/libpng-1.2*
+	net-misc/curl
+	cups? ( net-print/cups )
+	sys-devel/gcc
+	sys-fs/fuse
+	sys-libs/glibc
+	sys-libs/zlib
+	x11-libs/cairo
+	x11-libs/gtk+:2
+	x11-libs/libgksu
+	x11-libs/libICE
+	x11-libs/libsexy
+	x11-libs/libSM
+	x11-libs/libX11
+	x11-libs/libXau
+	x11-libs/libxcb
+	x11-libs/libXcomposite
+	x11-libs/libXcursor
+	x11-libs/libXdamage
+	x11-libs/libXdmcp
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXft
+	x11-libs/libXi
+	x11-libs/libXinerama
+	x11-libs/libXrandr
+	x11-libs/libXrender
+	x11-libs/libXtst
+	x11-libs/pango
+	x11-libs/startup-notification
+	!app-emulation/vmware-workstation"
+PDEPEND="~app-emulation/vmware-modules-264.${PV_MINOR}
+	vmware-tools? ( app-emulation/vmware-tools )"
+
+S=${WORKDIR}
+VM_INSTALL_DIR="/opt/vmware"
+
+src_unpack() {
+	default
+	local bundle=${A%.tar}
+
+	local component ; for component in \
+			vmware-player \
+			vmware-player-app \
+			vmware-vmx \
+			vmware-usbarbitrator \
+			vmware-network-editor \
+			vmware-player-setup
+			#vmware-ovftool
+	do
+		vmware-bundle_extract-bundle-component "${bundle}" "${component}" "${S}"
+	done
+}
+
+src_prepare() {
+	rm -f bin/vmware-modconfig
+	rm -rf lib/modules/binary
+}
+
+clean_bundled_libs() {
+	ebegin 'Removing superfluous libraries'
+	# exclude OpenSSL from unbundling until the AES-NI patch gets into the tree
+	# see http://forums.gentoo.org/viewtopic-t-835867.html
+	# must use shipped libgcr.so.0 or else "undefined symbol: gcr_certificate_widget_new"
+	ldconfig -p | sed 's:^\s\+\([^(]*[^( ]\).*=> \(/.*\)$:\1 \2:g;t;d' | fgrep -v 'libcrypto.so.0.9.8
+libssl.so.0.9.8
+libgcr.so.0' | while read -r libname libpath ; do
+		dosym "${libpath}" "${VM_INSTALL_DIR}/lib/vmware/lib/${libname}/${libname}"
+	done
+	eend
+}
+
+src_install() {
+	# install the binaries
+	into "${VM_INSTALL_DIR}"
+	dobin bin/* || die "failed to install bin"
+
+	# install the libraries
+	insinto "${VM_INSTALL_DIR}"/lib/vmware
+	doins -r lib/*
+
+	# install the ancillaries
+	insinto /usr
+	doins -r share
+
+	if use cups; then
+		exeinto $(cups-config --serverbin)/filter
+		doexe extras/thnucups
+
+		insinto /etc/cups
+		doins -r etc/cups/*
+	fi
+
+	# install documentation
+	if use doc; then
+		dodoc doc/*
+	fi
+
+	exeinto "${VM_INSTALL_DIR}"/lib/vmware/setup
+	doexe vmware-config
+
+	# create symlinks for the various tools
+	local tool ; for tool in thnuclnt vmplayer{,-daemon} \
+			vmware-{acetool,unity-helper,modconfig{,-console},gksu,fuseUI} ; do
+		dosym appLoader "${VM_INSTALL_DIR}"/lib/vmware/bin/"${tool}"
+	done
+	dosym "${VM_INSTALL_DIR}"/lib/vmware/bin/vmplayer "${VM_INSTALL_DIR}"/bin/vmplayer
+	dosym "${VM_INSTALL_DIR}"/lib/vmware/icu /etc/vmware/icu
+
+	# fix permissions
+	fperms 0755 "${VM_INSTALL_DIR}"/lib/vmware/bin/{appLoader,fusermount,launcher.sh,mkisofs,vmware-remotemks}
+	fperms 0755 "${VM_INSTALL_DIR}"/lib/vmware/lib/{wrapper-gtk24.sh,libgksu2.so.0/gksu-run-helper}
+	fperms 4711 "${VM_INSTALL_DIR}"/lib/vmware/bin/vmware-vmx{,-debug,-stats}
+
+	pax-mark -m "${D}${VM_INSTALL_DIR}"/lib/vmware/bin/vmware-vmx
+
+	# create the environment
+	local envd="${T}/90vmware"
+	cat > "${envd}" <<-EOF
+		PATH='${VM_INSTALL_DIR}/bin'
+		ROOTPATH='${VM_INSTALL_DIR}/bin'
+	EOF
+	doenvd "${envd}" || die
+
+	# create the configuration
+	dodir /etc/vmware || die
+
+	cat > "${D}"/etc/vmware/bootstrap <<-EOF
+		BINDIR='${VM_INSTALL_DIR}/bin'
+		LIBDIR='${VM_INSTALL_DIR}/lib'
+	EOF
+
+	cat > "${D}"/etc/vmware/config <<-EOF
+		bindir = "${VM_INSTALL_DIR}/bin"
+		libdir = "${VM_INSTALL_DIR}/lib/vmware"
+		initscriptdir = "/etc/init.d"
+		authd.fullpath = "${VM_INSTALL_DIR}/sbin/vmware-authd"
+		gksu.rootMethod = "su"
+		VMCI_CONFED = "yes"
+		VMBLOCK_CONFED = "yes"
+		VSOCK_CONFED = "yes"
+		NETWORKING = "yes"
+		player.product.version = "${MY_PV}"
+		product.buildNumber = "${PV_BUILD}"
+	EOF
+
+	# install the init.d script
+	local initscript="${T}/vmware.rc"
+
+	sed -e "s:@@BINDIR@@:${VM_INSTALL_DIR}/bin:g" \
+		"${FILESDIR}/vmware-3.0.rc" > "${initscript}" || die
+	newinitd "${initscript}" vmware || die
+
+	# fill in variable placeholders
+	sed -e "s:@@LIBCONF_DIR@@:${VM_INSTALL_DIR}/lib/vmware/libconf:g" \
+		-i "${D}${VM_INSTALL_DIR}"/lib/vmware/libconf/etc/{gtk-2.0/{gdk-pixbuf.loaders,gtk.immodules},pango/pango{.modules,rc}} || die
+	sed -e "s:@@BINARY@@:${VM_INSTALL_DIR}/bin/vmplayer:g" \
+		-i "${D}/usr/share/applications/${PN}.desktop" || die
+}
+
+pkg_config() {
+	"${VM_INSTALL_DIR}"/bin/vmware-networks --postinstall ${PN},old,new
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+
+	ewarn "/etc/env.d was updated. Please run:"
+	ewarn "env-update && source /etc/profile"
+	ewarn ""
+	ewarn "Before you can use vmware-player, you must configure a default network setup."
+	ewarn "You can do this by running 'emerge --config ${PN}'."
+}
+
+pkg_prerm() {
+	einfo "Stopping ${PN} for safe unmerge"
+	/etc/init.d/vmware stop
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	gnome2_icon_cache_update
+}
diff --git a/app-emulation/vmware-player/vmware-player-4.0.5.893925.ebuild b/app-emulation/vmware-player/vmware-player-4.0.5.893925.ebuild
index f41144d..33c8cb5 100644
--- a/app-emulation/vmware-player/vmware-player-4.0.5.893925.ebuild
+++ b/app-emulation/vmware-player/vmware-player-4.0.5.893925.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/vmware-player/vmware-player-4.0.5.893925.ebuild,v 1.3 2013/06/22 22:37:55 dilfridge Exp $
 
 EAPI="4"
 
@@ -20,7 +20,7 @@ SRC_URI="
 	amd64? ( ${BASE_URI}${MY_P}.x86_64.bundle.tar )
 	"
 
-LICENSE="vmware"
+LICENSE="vmware GPL-2"
 SLOT="0"
 KEYWORDS="-* ~amd64 ~x86"
 IUSE="cups doc +vmware-tools"
@@ -129,7 +129,7 @@ src_install() {
 	insinto "${VM_INSTALL_DIR}"/lib/vmware
 	doins -r lib/*
 
-	# Bug 432918 
+	# Bug 432918
 	dosym "${VM_INSTALL_DIR}"/lib/vmware/lib/libcrypto.so.0.9.8/libcrypto.so.0.9.8 \
 		"${VM_INSTALL_DIR}"/lib/vmware/lib/libvmwarebase.so.0/libcrypto.so.0.9.8
 	dosym "${VM_INSTALL_DIR}"/lib/vmware/lib/libssl.so.0.9.8/libssl.so.0.9.8 \
diff --git a/app-emulation/vmware-player/vmware-player-5.0.2.1031769.ebuild b/app-emulation/vmware-player/vmware-player-5.0.2.1031769.ebuild
index c4e93c0..8776e08 100644
--- a/app-emulation/vmware-player/vmware-player-5.0.2.1031769.ebuild
+++ b/app-emulation/vmware-player/vmware-player-5.0.2.1031769.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/vmware-player/vmware-player-5.0.1.894247.ebuild,v 1.3 2013/01/07 21:03:01 vadimk Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/vmware-player/vmware-player-5.0.2.1031769.ebuild,v 1.2 2013/06/22 22:37:55 dilfridge Exp $
 
 EAPI="4"
 
@@ -20,7 +20,7 @@ SRC_URI="
 	amd64? ( ${BASE_URI}${MY_P}.x86_64.bundle.tar )
 	"
 
-LICENSE="vmware"
+LICENSE="vmware GPL-2"
 SLOT="0"
 KEYWORDS="-* ~amd64 ~x86"
 IUSE="cups doc +vmware-tools"