summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMichał Górny <mgorny@gentoo.org>2019-11-09 12:37:01 +0100
committerMichał Górny <mgorny@gentoo.org>2019-11-09 12:45:45 +0100
commit016ad58a39ab8f971b99e2d5f4e6f8240d2ffa32 (patch)
tree648a9089726704247e2be72146eab31a9297c965
parentapp-text/binfind: Bump to EAPI 7 (diff)
downloadgentoo-016ad58a39ab8f971b99e2d5f4e6f8240d2ffa32.tar.gz
gentoo-016ad58a39ab8f971b99e2d5f4e6f8240d2ffa32.tar.bz2
gentoo-016ad58a39ab8f971b99e2d5f4e6f8240d2ffa32.zip
dev-util/sgb: Bump to EAPI 7
Closes: https://bugs.gentoo.org/697328 Signed-off-by: Michał Górny <mgorny@gentoo.org>
-rw-r--r--dev-util/sgb/sgb-20030623-r1.ebuild59
-rw-r--r--dev-util/sgb/sgb-20030623.ebuild60
2 files changed, 59 insertions, 60 deletions
diff --git a/dev-util/sgb/sgb-20030623-r1.ebuild b/dev-util/sgb/sgb-20030623-r1.ebuild
new file mode 100644
index 00000000000..65303742afc
--- /dev/null
+++ b/dev-util/sgb/sgb-20030623-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="Stanford GraphBase"
+HOMEPAGE="ftp://labrea.stanford.edu/pub/sgb/"
+SRC_URI="ftp://labrea.stanford.edu/pub/sgb/sgb-${PV:0:4}-${PV:4:2}-${PV:6:2}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc x86"
+IUSE=""
+
+DEPEND="virtual/tex-base"
+
+S="${WORKDIR}"
+
+PATCHES=(
+ "${FILESDIR}"/sgb-20030623-parallel-make-fix.patch
+ "${FILESDIR}"/sgb-20030623-destdir.patch
+)
+
+src_compile() {
+ local vars=(
+ CFLAGS="${CFLAGS}"
+ SGBDIR=/usr/share/${PN}
+ INCLUDEDIR=/usr/include/sgb
+ LIBDIR=/usr/$(get_libdir)
+ BINDIR=/usr/bin
+ #CWEBINPUTS=/usr/share/${PN}/cweb
+ #LDFLAGS="${LDFLAGS}"
+ )
+ # bug #299028
+ emake -j1 "${vars[@]}" lib demos tests
+}
+
+src_test() {
+ emake tests
+}
+
+src_install() {
+ local vars=(
+ SGBDIR=/usr/share/${PN}
+ INCLUDEDIR=/usr/include/sgb
+ LIBDIR=/usr/$(get_libdir)
+ BINDIR=/usr/bin
+ CFLAGS="${CFLAGS}"
+ # TODO: why are they commented out above?
+ LDFLAGS="${LDFLAGS}"
+ CWEBINPUTS=/usr/share/${PN}/cweb
+ )
+ emake DESTDIR="${D}" "${vars[@]}" install
+
+ # we don't need no makefile
+ rm "${D}"/usr/include/sgb/Makefile || die
+
+ dodoc ERRATA README
+}
diff --git a/dev-util/sgb/sgb-20030623.ebuild b/dev-util/sgb/sgb-20030623.ebuild
deleted file mode 100644
index 9c6726cd8d9..00000000000
--- a/dev-util/sgb/sgb-20030623.ebuild
+++ /dev/null
@@ -1,60 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=0
-
-inherit eutils multilib
-
-DESCRIPTION="Stanford GraphBase"
-HOMEPAGE="ftp://labrea.stanford.edu/pub/sgb/"
-SRC_URI="ftp://labrea.stanford.edu/pub/sgb/sgb-${PV:0:4}-${PV:4:2}-${PV:6:2}.tar.gz"
-LICENSE="BSD"
-SLOT="0"
-KEYWORDS="~amd64 ~ppc x86"
-IUSE=""
-DEPEND="virtual/tex-base"
-S="${WORKDIR}"
-
-src_unpack() {
- unpack ${A}
- epatch "${FILESDIR}"/sgb-20030623-parallel-make-fix.patch
- epatch "${FILESDIR}"/sgb-20030623-destdir.patch
-}
-
-src_compile() {
- # bug #299028
- emake -j1 \
- CFLAGS="${CFLAGS}" \
- SGBDIR=/usr/share/${PN} \
- INCLUDEDIR=/usr/include/sgb \
- LIBDIR=/usr/$(get_libdir) \
- BINDIR=/usr/bin \
- CFLAGS="${CFLAGS}" \
- lib demos tests || die "Failed to build"
- #CWEBINPUTS=/usr/share/${PN}/cweb \
- #LDFLAGS="${LDFLAGS}" \
-}
-
-src_install() {
- dodir /usr/share/${PN} /usr/include/sgb /usr/lib /usr/bin /usr/share/${PN}/cweb
- emake \
- DESTDIR="${D}" \
- SGBDIR=/usr/share/${PN} \
- INCLUDEDIR=/usr/include/sgb \
- LIBDIR=/usr/$(get_libdir) \
- BINDIR=/usr/bin \
- CFLAGS="${CFLAGS}" \
- LDFLAGS="${LDFLAGS}" \
- CWEBINPUTS=/usr/share/${PN}/cweb \
- install \
- || die "Failed to install"
-
- # we don't need no makefile
- rm "${D}"/usr/include/sgb/Makefile
-
- dodoc ERRATA README
-}
-
-src_test() {
- emake tests
-}