summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMichael Palimaka <kensington@gentoo.org>2017-02-18 14:58:18 +1100
committerMichael Palimaka <kensington@gentoo.org>2017-02-18 14:59:43 +1100
commit14b829335ebccdb0b2ca546f4e1b1fb8f99e529e (patch)
tree35f0e986bce3d183a43477566c719dd7d3610e79
parentmail-client/alpine: remove two old revisions with permission from robbat2. (diff)
downloadgentoo-14b829335ebccdb0b2ca546f4e1b1fb8f99e529e.tar.gz
gentoo-14b829335ebccdb0b2ca546f4e1b1fb8f99e529e.tar.bz2
gentoo-14b829335ebccdb0b2ca546f4e1b1fb8f99e529e.zip
dev-libs/appstream: revision bump fixing two issues
* Fixes a build failure LINGUAS="" * Adds a missing dependency Gentoo-bug: 606624 Gentoo-bug: 609358 Package-Manager: Portage-2.3.3, Repoman-2.3.1
-rw-r--r--dev-libs/appstream/appstream-0.10.6-r1.ebuild72
1 files changed, 72 insertions, 0 deletions
diff --git a/dev-libs/appstream/appstream-0.10.6-r1.ebuild b/dev-libs/appstream/appstream-0.10.6-r1.ebuild
new file mode 100644
index 00000000000..5e83584ee68
--- /dev/null
+++ b/dev-libs/appstream/appstream-0.10.6-r1.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit cmake-utils xdg-utils
+
+if [[ ${PV} = 9999 ]]; then
+ inherit git-r3
+ EGIT_REPO_URI="https://github.com/ximion/${PN}"
+else
+ inherit versionator
+ MY_PV="$(replace_all_version_separators '_')"
+ MY_P="APPSTREAM_${MY_PV}"
+ SRC_URI="https://github.com/ximion/${PN}/archive/${MY_P}.tar.gz -> ${P}.tar.gz"
+ KEYWORDS="~amd64 ~arm ~x86"
+ S="${WORKDIR}/${PN}-${MY_P}"
+fi
+
+DESCRIPTION="Cross-distro effort for providing metadata for software in the Linux ecosystem"
+HOMEPAGE="https://www.freedesktop.org/wiki/Distributions/AppStream/"
+
+LICENSE="LGPL-2.1+ GPL-2+"
+# check APPSTREAM_LIB_API_LEVEL
+SLOT="0/4"
+IUSE="apt doc qt5 test"
+
+RDEPEND="
+ dev-libs/glib:2
+ dev-libs/gobject-introspection
+ dev-libs/libxml2:2
+ dev-libs/libyaml
+ dev-libs/snowball-stemmer
+ qt5? ( dev-qt/qtcore:5 )
+"
+DEPEND="${RDEPEND}
+ app-text/docbook-xml-dtd:4.5
+ dev-util/itstool
+ sys-devel/gettext
+ test? (
+ qt5? ( dev-qt/qttest:5 )
+ )
+"
+
+src_prepare() {
+ cmake-utils_src_prepare
+
+ if ! use test; then
+ pushd qt > /dev/null || die
+ cmake_comment_add_subdirectory tests
+ popd > /dev/null || die
+ fi
+}
+
+src_configure() {
+ xdg_environment_reset
+
+ local mycmakeargs=(
+ -DSTEMMING=ON
+ -DL18N=ON
+ -DVAPI=OFF
+ -DMAINTAINER=OFF
+ -DSANITIZERS=OFF
+ -DDOCUMENTATION=OFF
+ -DAPT_SUPPORT=$(usex apt)
+ -DINSTALL_PREBUILT_DOCS=$(usex doc)
+ -DQT=$(usex qt5)
+ )
+
+ cmake-utils_src_configure
+}