summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorJustin Lecher <jlec@gentoo.org>2017-06-04 12:49:28 +0100
committerJustin Lecher <jlec@gentoo.org>2017-06-04 12:49:50 +0100
commit33dfb15195aa23c778feac59c5112ffc1f2320c2 (patch)
tree1967c3ccdcf65b70544987aed1a8dc06c949a79c
parentsci-chemistry/xds-bin: Version Bump (diff)
downloadgentoo-33dfb15195aa23c778feac59c5112ffc1f2320c2.tar.gz
gentoo-33dfb15195aa23c778feac59c5112ffc1f2320c2.tar.bz2
gentoo-33dfb15195aa23c778feac59c5112ffc1f2320c2.zip
dev-python/pandas: Version Bump
Gentoo-Bug: https://bugs.gentoo.org/show_bug.cgi?id=620290 Package-Manager: Portage-2.3.6, Repoman-2.3.2 Signed-off-by: Justin Lecher <jlec@gentoo.org>
-rw-r--r--dev-python/pandas/Manifest1
-rw-r--r--dev-python/pandas/pandas-0.20.1.ebuild162
2 files changed, 163 insertions, 0 deletions
diff --git a/dev-python/pandas/Manifest b/dev-python/pandas/Manifest
index c7d4b01cb04..80b1bf9ae5b 100644
--- a/dev-python/pandas/Manifest
+++ b/dev-python/pandas/Manifest
@@ -2,3 +2,4 @@ DIST pandas-0.16.2.tar.gz 4931751 SHA256 e01853dfe111f3aea005315573400b7216ddbab
DIST pandas-0.17.0.tar.gz 6508621 SHA256 320d4fdf734b82adebc8fde9d8ca4b05fe155a72b6f7aa95d76242da8748d6a4 SHA512 bae6964e263c7ff6cac722cdfe23081f23c357d9bc39a670b5627bef4630c236a58aa8c0393eae921721bf7049c8e5266b4dea71dd957da5d89dafc14a04797b WHIRLPOOL d654eb2f9ffbfedbde60e4a6e6ce6f54650a8a68b4d20035744aa55111525d6bba4dae2ccbfce65acf71bb200e2e6029c7f6c9bcc9d0c582d808444738baedb1
DIST pandas-0.17.1.tar.gz 6674479 SHA256 cfd7214a7223703fe6999fbe34837749540efee1c985e6aee9933f30e3f72837 SHA512 9d9f9064585b1f3551625e0c8f4eedaaa1253790c2a5cb28e58e70eb805cc18f9770d793aa748cbd76798488ff60efdd01eb4b21daf5ad8f1dc4d9c050487234 WHIRLPOOL 5238575bd64b8d38db4f9a0ea987a7f78ffd1821e5a22bad65c84c407feca3af6f3b536a0a2f337291aa04e94c86fdb40382dad4ce50f8a33a5e26d655c628c2
DIST pandas-0.19.1.tar.gz 8360233 SHA256 2509feaeda72fce03675e2eccd2284bb1cadb6a0737008a5e741fe2431d47421 SHA512 6451990a7fae8c6db8ab0b014a13b4f1828754d3998f13c17b111f891fb9fd23f8e09b907623096dfa55668c42298eee1373210a9fddb95f56dd7d552b964e6f WHIRLPOOL 700c0d819ab62134baf56430b7fa8840636ea377d00397341d33ec5f13474d9eeefea245aede80a80f7c16348ef811788947e5fe0020c9770005c74dd1288ef3
+DIST pandas-0.20.1.tar.gz 10307434 SHA256 42707365577ef69f7c9c168ddcf045df2957595a9ee71bc13c7997eecb96b190 SHA512 d477a815914c825efd6430f7eb19f3f9115c1c4ab03000ca6d4f64023f7b5f53eff512792fea2d8b33c7febb3667fc3a3de55f11eeb453f285cae40e6b473707 WHIRLPOOL fca35c7178441e3cfe990740aecba923d8b3d56d70fa7b0285b09305a0d2f7a6ad01bb906d6d92748a038a3841cda783f01f75f93b67f15c53c9854a43819841
diff --git a/dev-python/pandas/pandas-0.20.1.ebuild b/dev-python/pandas/pandas-0.20.1.ebuild
new file mode 100644
index 00000000000..3195714ae4b
--- /dev/null
+++ b/dev-python/pandas/pandas-0.20.1.ebuild
@@ -0,0 +1,162 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+PYTHON_REQ_USE="threads(+)"
+
+VIRTUALX_REQUIRED="manual"
+
+inherit distutils-r1 eutils flag-o-matic virtualx
+
+DESCRIPTION="Powerful data structures for data analysis and statistics"
+HOMEPAGE="http://pandas.pydata.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc -minimal full-support test X"
+
+MINIMAL_DEPEND="
+ >dev-python/numpy-1.7[${PYTHON_USEDEP}]
+ >=dev-python/python-dateutil-2.0[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]
+ !<dev-python/numexpr-2.1[${PYTHON_USEDEP}]
+ !~dev-python/openpyxl-1.9.0[${PYTHON_USEDEP}]"
+RECOMMENDED_DEPEND="
+ dev-python/bottleneck[${PYTHON_USEDEP}]
+ >=dev-python/numexpr-2.1[${PYTHON_USEDEP}]"
+OPTIONAL_DEPEND="
+ dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+ dev-python/blosc[${PYTHON_USEDEP}]
+ dev-python/boto[${PYTHON_USEDEP}]
+ >=dev-python/google-api-python-client-1.2.0[$(python_gen_usedep python2_7 pypy)]
+ || ( dev-python/html5lib[${PYTHON_USEDEP}] dev-python/lxml[${PYTHON_USEDEP}] )
+ dev-python/httplib2[${PYTHON_USEDEP}]
+ dev-python/jinja[${PYTHON_USEDEP}]
+ dev-python/matplotlib[${PYTHON_USEDEP}]
+ || ( >=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}] dev-python/xlsxwriter[${PYTHON_USEDEP}] )
+ >=dev-python/pytables-3.2.1[${PYTHON_USEDEP}]
+ dev-python/python-gflags[$(python_gen_usedep python2_7 pypy)]
+ dev-python/rpy[${PYTHON_USEDEP}]
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ dev-python/statsmodels[${PYTHON_USEDEP}]
+ >=dev-python/sqlalchemy-0.8.1[${PYTHON_USEDEP}]
+ dev-python/xlrd[${PYTHON_USEDEP}]
+ dev-python/xlwt[${PYTHON_USEDEP}]
+ sci-libs/scipy[${PYTHON_USEDEP}]
+ X? (
+ || (
+ dev-python/PyQt4[${PYTHON_USEDEP}]
+ dev-python/pyside[${PYTHON_USEDEP}]
+ dev-python/pygtk[$(python_gen_usedep python2_7)]
+ )
+ || (
+ x11-misc/xclip
+ x11-misc/xsel
+ )
+ )
+ "
+
+DEPEND="${MINIMAL_DEPEND}
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ >=dev-python/cython-0.23[${PYTHON_USEDEP}]
+ doc? (
+ ${VIRTUALX_DEPEND}
+ dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+ dev-python/html5lib[${PYTHON_USEDEP}]
+ dev-python/ipython[${PYTHON_USEDEP}]
+ dev-python/lxml[${PYTHON_USEDEP}]
+ dev-python/matplotlib[${PYTHON_USEDEP}]
+ >=dev-python/openpyxl-1.6.1[${PYTHON_USEDEP}]
+ >=dev-python/pytables-3.0.0[${PYTHON_USEDEP}]
+ dev-python/pytz[${PYTHON_USEDEP}]
+ dev-python/rpy[${PYTHON_USEDEP}]
+ >=dev-python/sphinx-1.2.1[${PYTHON_USEDEP}]
+ dev-python/xlrd[${PYTHON_USEDEP}]
+ dev-python/xlwt[${PYTHON_USEDEP}]
+ sci-libs/scipy[${PYTHON_USEDEP}]
+ x11-misc/xclip
+ )
+ test? (
+ ${VIRTUALX_DEPEND}
+ ${RECOMMENDED_DEPEND}
+ ${OPTIONAL_DEPEND}
+ dev-python/beautifulsoup:4[${PYTHON_USEDEP}]
+ dev-python/nose[${PYTHON_USEDEP}]
+ dev-python/pymysql[${PYTHON_USEDEP}]
+ dev-python/psycopg:2[${PYTHON_USEDEP}]
+ x11-misc/xclip
+ x11-misc/xsel
+ )"
+# dev-python/statsmodels invokes a circular dep
+# hence rm from doc? ( ), again
+RDEPEND="
+ ${MINIMAL_DEPEND}
+ !minimal? ( ${RECOMMENDED_DEPEND} )
+ full-support? ( ${OPTIONAL_DEPEND} )"
+
+python_prepare_all() {
+ # Prevent un-needed download during build
+ sed \
+ -e "/^ 'sphinx.ext.intersphinx',/d" \
+ -i doc/source/conf.py || die
+
+ # https://github.com/pydata/pandas/issues/11299
+ sed \
+ -e 's:testOdArray:disable:g' \
+ -i pandas/tests/io/json/test_ujson.py || die
+
+ distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+ # To build docs the need be located in $BUILD_DIR,
+ # else PYTHONPATH points to unusable modules.
+ if use doc; then
+ cd "${BUILD_DIR}"/lib || die
+ cp -ar "${S}"/doc . && cd doc || die
+ LANG=C PYTHONPATH=. virtx ${EPYTHON} make.py html || die
+ fi
+}
+
+python_test() {
+ local test_pandas='not network and not disabled'
+ [[ -n "${FAST_PANDAS}" ]] && test_pandas+=' and not slow'
+ pushd "${BUILD_DIR}"/lib > /dev/null
+ "${EPYTHON}" -c "import pandas; pandas.show_versions()" || die
+ PYTHONPATH=. MPLCONFIGDIR=. \
+ virtx nosetests --verbosity=3 -A "${test_pandas}" pandas
+ popd > /dev/null
+}
+
+python_install_all() {
+ if use doc; then
+ dodoc -r "${BUILD_DIR}"/lib/doc/build/html
+ einfo "An initial build of docs is absent of references to statsmodels"
+ einfo "due to circular dependency. To have them included, emerge"
+ einfo "statsmodels next and re-emerge pandas with USE doc"
+ fi
+
+ distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+ optfeature "accelerating certain types of NaN evaluations, using specialized cython routines to achieve large speedups." dev-python/bottleneck
+ optfeature "accelerating certain numerical operations, using multiple cores as well as smart chunking and caching to achieve large speedups" >=dev-python/numexpr-2.1
+ optfeature "needed for pandas.io.html.read_html" dev-python/beautifulsoup:4 dev-python/html5lib dev-python/lxml
+ optfeature "for msgpack compression using ``blosc``" dev-python/blosc
+ optfeature "necessary for Amazon S3 access" dev-python/boto
+ optfeature "needed for pandas.io.gbq" dev-python/httplib2 dev-python/setuptools dev-python/python-gflags >=dev-python/google-api-python-client-1.2.0
+ optfeature "Template engine for conditional HTML formatting" dev-python/jinja
+ optfeature "Plotting support" dev-python/matplotlib
+ optfeature "Needed for Excel I/O" >=dev-python/openpyxl-1.6.1 dev-python/xlsxwriter dev-python/xlrd dev-python/xlwt
+ optfeature "necessary for HDF5-based storage" >=dev-python/pytables-3.2.1
+ optfeature "R I/O support" dev-python/rpy
+ optfeature "Needed for parts of :mod:`pandas.stats`" dev-python/statsmodels
+ optfeature "SQL database support" >=dev-python/sqlalchemy-0.8.1
+ optfeature "miscellaneous statistical functions" sci-libs/scipy
+ optfeature "necessary to use ~pandas.io.clipboard.read_clipboard support" dev-python/PyQt4 dev-python/pyside dev-python/pygtk x11-misc/xclip x11-misc/xsel
+}