summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAustin English <wizardedit@gentoo.org>2016-09-07 13:52:19 -0500
committerAustin English <wizardedit@gentoo.org>2016-09-07 13:52:19 -0500
commit5b30701ac9a35c560ccc6d360a9eca02bd32346d (patch)
treec274dd0be28ef3f50dbcfeebec83038ac1e0d53c
parentgames-board/grhino: remove deprecated games eclass (diff)
downloadgentoo-5b30701ac9a35c560ccc6d360a9eca02bd32346d.tar.gz
gentoo-5b30701ac9a35c560ccc6d360a9eca02bd32346d.tar.bz2
gentoo-5b30701ac9a35c560ccc6d360a9eca02bd32346d.zip
games-board/gnushogi: remove deprecated games eclass
Also update to EAPI 6 Gentoo-Bug: https://bugs.gentoo.org/574082 Package-Manager: portage-2.3.0
-rw-r--r--games-board/gnushogi/gnushogi-1.4.1-r1.ebuild51
1 files changed, 51 insertions, 0 deletions
diff --git a/games-board/gnushogi/gnushogi-1.4.1-r1.ebuild b/games-board/gnushogi/gnushogi-1.4.1-r1.ebuild
new file mode 100644
index 00000000000..9125f688f17
--- /dev/null
+++ b/games-board/gnushogi/gnushogi-1.4.1-r1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils
+
+DESCRIPTION="Japanese version of chess (commandline + X-Version)"
+HOMEPAGE="https://www.gnu.org/software/gnushogi/"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="X"
+
+RDEPEND="sys-libs/ncurses:0
+ X? ( x11-libs/libXaw )"
+DEPEND="${RDEPEND}
+ >=sys-devel/bison-1.34
+ >=sys-devel/flex-2.5"
+
+src_prepare() {
+ default
+
+ sed -i \
+ -e '/^bbk:/s/$/ gnushogi_compile pat2inc sizetest/' \
+ Makefile.in || die
+ sed -i \
+ -e "/^LIBDIR/s:=.*:=\"$(get_libdir)\":" \
+ gnushogi/Makefile.in || die
+}
+
+src_configure() {
+ econf \
+ $(use_with X x) \
+ $(use_enable X xshogi)
+}
+
+src_install() {
+ dobin gnushogi/gnushogi
+ doman doc/gnushogi.6
+ doinfo doc/gnushogi.info
+ if use X ; then
+ dobin xshogi/xshogi
+ doman doc/xshogi.6
+ make_desktop_entry xshogi XShogi
+ fi
+ dolib gnushogi/gnushogi.bbk
+ dodoc README NEWS CONTRIB doc/gnushogi/*.html
+}