net-misc/nextcloud-client: 2.5.1 bump

Closes: https://bugs.gentoo.org/673528
Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

2 files changed, 94 insertions, 0 deletions

diff --git a/net-misc/nextcloud-client/Manifest b/net-misc/nextcloud-client/Manifest
index e9f6be437ac6..831f50005336 100644
--- a/net-misc/nextcloud-client/Manifest
+++ b/net-misc/nextcloud-client/Manifest
@@ -1,3 +1,4 @@
 DIST nextcloud-client-2.3.3.tar.gz 708611 BLAKE2B 8f0a1f433ad18743e7d78bf4ab523e57f2c40cc1527508e940bb14c75f944723d728a5ee188c06a181ded535b910bea68620e8eb950c290af7556423fc28264f SHA512 fd02c61a7a92b77f9063e4f15be426be84d02033bead4b176d876134f8b85d7385e4a361959b68c332f1ccb55d43e2a8b55e0d5c8e5a54f645a5816a37790bde
 DIST nextcloud-client-2.5.0.tar.gz 18914632 BLAKE2B b6a8e353a7894dac599b5ecfb7bed0f373ef6ce602a929b9daf709a91513b34ff92f9af0ba57acd3294561f30d37623280b043c779b52872bad2829e66315e10 SHA512 85591e3d5011a514472f179e48815134e12751849be9fa3457f631cdb262764801e8aecc774e0cff4d1dc4a4c34e3238a6ac1442e93ae847417d25560917ce99
+DIST nextcloud-client-2.5.1.tar.gz 18916053 BLAKE2B 98daa5abde8aa82e2d30be7c340f808c4cb7a1986bbb7e9e5208174b268ddacfaf08e91b54d6bce5039fd19f6729716285e2a45f913c0d0eb473bf753031678f SHA512 04301f4b6283c4003ec4fed7926e11e2a627903a1b20e0b7cb4bb24b522e133d41001f48c633cad4fe3b100496d3a7826893b78074c2e3985a4c9c90122e3108
 DIST owncloudclient-2.3.3.tar.xz 33801712 BLAKE2B 7642148a4f503a2702d56f920067202699b4a55bb6216337ecbd9df141e0a7467aaf2db8d7d6871502061d3866294f8c44c791fdbf9597ca8d761f360f7ffda1 SHA512 8cbffd4fdd4bd3bbbfb947498ec9bfbaceac3966ac29d61dea3db82405976230c1067c3a3afc9ddc4ce152c69c530ad44be154615a391f63524dc2fb40d5e5d2
diff --git a/net-misc/nextcloud-client/nextcloud-client-2.5.1.ebuild b/net-misc/nextcloud-client/nextcloud-client-2.5.1.ebuild
new file mode 100644
index 000000000000..29daa11a9dbe
--- /dev/null
+++ b/net-misc/nextcloud-client/nextcloud-client-2.5.1.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils gnome2-utils
+
+DESCRIPTION="Desktop Syncing Client for Nextcloud"
+HOMEPAGE="https://github.com/nextcloud/desktop"
+SRC_URI="https://github.com/nextcloud/desktop/archive/v${PV/_/-}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="CC-BY-3.0 GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc dolphin nautilus shibboleth test"
+
+COMMON_DEPEND=">=dev-db/sqlite-3.4:3
+	>=dev-libs/openssl-1.1.0:0=
+	dev-libs/qtkeychain[qt5(+)]
+	dev-qt/qtconcurrent:5
+	dev-qt/qtcore:5
+	dev-qt/qtdbus:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtsql:5
+	dev-qt/qtwebengine:5[widgets]
+	dev-qt/qtwidgets:5
+	dev-qt/qtxml:5
+	sys-fs/inotify-tools
+	dolphin? (
+		kde-frameworks/kcoreaddons:5
+		kde-frameworks/kio:5
+	)
+	nautilus? ( dev-python/nautilus-python )
+	shibboleth? ( dev-qt/qtwebkit:5 )
+"
+RDEPEND="${COMMON_DEPEND}
+	!net-misc/ocsync
+	!net-misc/owncloud-client
+"
+DEPEND="${COMMON_DEPEND}
+	dev-qt/linguist-tools:5
+	doc? (
+		dev-python/sphinx
+		dev-tex/latexmk
+		dev-texlive/texlive-latexextra
+		virtual/latex-base
+	)
+	dolphin? ( kde-frameworks/extra-cmake-modules )
+	test? (
+		dev-util/cmocka
+		dev-qt/qttest:5
+	)
+"
+
+S=${WORKDIR}/desktop-${PV/_/-}
+
+src_prepare() {
+	# Keep tests in ${T}
+	sed -i -e "s#\"/tmp#\"${T}#g" test/test*.cpp || die
+
+	if ! use nautilus; then
+		pushd shell_integration > /dev/null || die
+		cmake_comment_add_subdirectory nautilus
+		popd > /dev/null || die
+	fi
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSYSCONF_INSTALL_DIR="${EPREFIX}"/etc
+		-DCMAKE_INSTALL_DOCDIR=/usr/share/doc/${PF}
+		-DCMAKE_DISABLE_FIND_PACKAGE_Sphinx=$(usex !doc)
+		-DCMAKE_DISABLE_FIND_PACKAGE_KF5=$(usex !dolphin)
+		-DNO_SHIBBOLETH=$(usex !shibboleth)
+		-DUNIT_TESTING=$(usex test)
+	)
+
+	cmake-utils_src_configure
+}
+
+pkg_postinst() {
+	if ! use doc ; then
+		elog "Documentation and man pages not installed"
+		elog "Enable doc USE-flag to generate them"
+	fi
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+}