summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorConrad Kostecki <conrad@kostecki.com>2018-10-28 19:44:06 +0100
committerCraig Andrews <candrews@gentoo.org>2018-11-07 13:16:37 -0500
commit58844a558b8223245bf32c6b61fb122830ec861a (patch)
tree3a3e7e96128d90dab25dcdcdfb412a100a6b796f /app-benchmarks
parentsci-physics/qmeq: Add support for installing examples (diff)
downloadgentoo-58844a558b8223245bf32c6b61fb122830ec861a.tar.gz
gentoo-58844a558b8223245bf32c6b61fb122830ec861a.tar.bz2
gentoo-58844a558b8223245bf32c6b61fb122830ec861a.zip
app-benchmarks/cpuburn: bump to EAPI=7
Also renamed patch, to match name. Signed-off-by: Conrad Kostecki <conrad@kostecki.com> Package-Manager: Portage-2.3.51, Repoman-2.3.11 Signed-off-by: Craig Andrews <candrews@gentoo.org>
Diffstat (limited to 'app-benchmarks')
-rw-r--r--app-benchmarks/cpuburn/cpuburn-1.4a-r1.ebuild4
-rw-r--r--app-benchmarks/cpuburn/cpuburn-1.4a-r2.ebuild4
-rw-r--r--app-benchmarks/cpuburn/cpuburn-1.4a-r3.ebuild59
-rw-r--r--app-benchmarks/cpuburn/files/cpuburn-1.4a-variables.patch (renamed from app-benchmarks/cpuburn/files/01-variables.patch)0
4 files changed, 63 insertions, 4 deletions
diff --git a/app-benchmarks/cpuburn/cpuburn-1.4a-r1.ebuild b/app-benchmarks/cpuburn/cpuburn-1.4a-r1.ebuild
index 3a72f5ced7c..10c2bf9df23 100644
--- a/app-benchmarks/cpuburn/cpuburn-1.4a-r1.ebuild
+++ b/app-benchmarks/cpuburn/cpuburn-1.4a-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2015 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=5
@@ -20,7 +20,7 @@ IUSE=""
src_prepare() {
epatch \
"${FILESDIR}"/${P}-flags.patch \
- "${FILESDIR}"/01-variables.patch
+ "${FILESDIR}"/${P}-variables.patch
use amd64 && append-flags -m32 #65719
tc-export CC
}
diff --git a/app-benchmarks/cpuburn/cpuburn-1.4a-r2.ebuild b/app-benchmarks/cpuburn/cpuburn-1.4a-r2.ebuild
index db1f520822b..ae6d819bc65 100644
--- a/app-benchmarks/cpuburn/cpuburn-1.4a-r2.ebuild
+++ b/app-benchmarks/cpuburn/cpuburn-1.4a-r2.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2018 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=6
@@ -13,7 +13,7 @@ KEYWORDS="-* ~amd64 ~arm ~x86"
LICENSE="GPL-2"
SLOT="0"
-PATCHES=( "${FILESDIR}/01-variables.patch" )
+PATCHES=( "${FILESDIR}/${P}-variables.patch" )
QA_FLAGS_IGNORED="usr/bin/burnBX
usr/bin/burnK6
diff --git a/app-benchmarks/cpuburn/cpuburn-1.4a-r3.ebuild b/app-benchmarks/cpuburn/cpuburn-1.4a-r3.ebuild
new file mode 100644
index 00000000000..1933ce1f6a6
--- /dev/null
+++ b/app-benchmarks/cpuburn/cpuburn-1.4a-r3.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+MY_PV="${PV/./_}"
+
+DESCRIPTION="CPU testing utilities in optimized assembler for maximum loading"
+HOMEPAGE="https://downloads.bl4ckb0x.de/pages.sbcglobal.net/redelm/"
+SRC_URI="https://downloads.bl4ckb0x.de/pages.sbcglobal.net/redelm/${PN}_${MY_PV}_tar.gz -> ${P}.tar.gz"
+
+KEYWORDS="-* ~amd64 ~arm ~x86"
+LICENSE="GPL-2"
+SLOT="0"
+
+PATCHES=( "${FILESDIR}/${P}-variables.patch" )
+
+QA_FLAGS_IGNORED="
+ usr/bin/burnBX
+ usr/bin/burnK6
+ usr/bin/burnK7
+ usr/bin/burnMMX
+ usr/bin/burnP5
+ usr/bin/burnP6
+"
+
+QA_TEXTRELS="${QA_FLAGS_IGNORED}"
+
+src_prepare() {
+ default
+
+ # Respect users compiler and users CFLAGS and LDFLAGS on x86/amd64
+ # Must be always compiled in 32-bit on amd64 arch
+ # See https://bugs.gentoo.org/65719
+ sed -i -e 's/gcc -s/$(CC) $(CFLAGS) -m32 $(LDFLAGS)/' Makefile || die
+
+ # Respect users compiler, CFLAGS and LDFLAGS on arm
+ sed -i -e '/CC :=/d' -e 's/^.*-mfloat-abi=softfp/ $(CC) $(CFLAGS) -nostdlib $(LDFLAGS)/' ARM/Makefile || die
+}
+
+src_compile() {
+ if use arm; then
+ cd "${S}"/ARM || die
+ fi
+
+ default
+}
+
+src_install() {
+ if use arm; then
+ dobin ARM/burnCortexA8 ARM/burnCortexA9
+ local DOCS=( "ARM/Design" "README" )
+ else
+ dobin burnBX burnK6 burnK7 burnMMX burnP5 burnP6
+ local DOCS=( "Design" "README" )
+ fi
+
+ einstalldocs
+}
diff --git a/app-benchmarks/cpuburn/files/01-variables.patch b/app-benchmarks/cpuburn/files/cpuburn-1.4a-variables.patch
index 3e8b666c29e..3e8b666c29e 100644
--- a/app-benchmarks/cpuburn/files/01-variables.patch
+++ b/app-benchmarks/cpuburn/files/cpuburn-1.4a-variables.patch