app-office/gnucash: Version bump

Package-Manager: Portage-2.3.3, Repoman-2.3.1

3 files changed, 220 insertions, 0 deletions

diff --git a/app-office/gnucash/Manifest b/app-office/gnucash/Manifest
index a04c65d659f5..bc08614246b1 100644
--- a/app-office/gnucash/Manifest
+++ b/app-office/gnucash/Manifest
@@ -1 +1,2 @@
 DIST gnucash-2.6.13.tar.bz2 13564015 SHA256 0fe3c12c849cddee502da07edc8e3db286d32333f4e7cb327bed735f480ee735 SHA512 daad6d55485de6ce3ca6affe232c51252d853c803734f4737ab2477e7724c42fa2ea764f5fdeea00d956bcbaad338a30fe21c62a578a818d5e8b4f5878f060b5 WHIRLPOOL 6f1ed3e9eaf9e80e8131fc48ff5480790a15093f1d2ab9b2c074644feb3c4d5db60315ba9e480f9697c21f0be7908f922ceff51a284632d65eb4fa7bda551e3b
+DIST gnucash-2.6.15.tar.bz2 13406483 SHA256 1619eb8263439f547dd12afdc0b05b9a50593d5cd3d3e9ee5b05edaec3b6dbae SHA512 6ec0652565025ac8281152ed64f2f820ecdb17ead5f17738728e094d116e638a08af57a46c0d5b59679f30f142ce372a5f61bd164f68f6b608d09de37cec38c6 WHIRLPOOL a54e7a20bcf8b181d101d70c7b6c0f2c5a6921af50c151239d06c698aad7511b23f787d8dc0f8a32c41b5a2327085df5dbcadb73a35b9d239be2ecddfad1fcf0
diff --git a/app-office/gnucash/gnucash-2.6.15-r1.ebuild b/app-office/gnucash/gnucash-2.6.15-r1.ebuild
new file mode 100644
index 000000000000..9707d62a5324
--- /dev/null
+++ b/app-office/gnucash/gnucash-2.6.15-r1.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools gnome2 python-single-r1
+
+DESCRIPTION="A personal finance manager"
+HOMEPAGE="http://www.gnucash.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="chipcard debug +doc gnome-keyring hbci mysql ofx postgres python quotes sqlite"
+
+# FIXME: rdepend on dev-libs/qof when upstream fix their mess (see configure.ac)
+# libdbi version requirement for sqlite taken from bug #455134
+RDEPEND="
+	>=dev-libs/glib-2.32.0:2
+	>=dev-libs/popt-1.5
+	>=dev-libs/libxml2-2.5.10:2
+	dev-libs/libxslt
+	>=dev-scheme/guile-2.0.0:12=[deprecated,regex]
+	dev-scheme/guile-www
+	gnome-base/libgnomecanvas
+	>=net-libs/webkit-gtk-1.2:2
+	>=sys-libs/zlib-1.1.4
+	>=x11-libs/gtk+-2.24:2
+	>=x11-libs/goffice-0.7.0:0.8[gnome]
+	x11-libs/pango
+	gnome-keyring? ( >=app-crypt/libsecret-0.18 )
+	ofx? ( >=dev-libs/libofx-0.9.1 )
+	hbci? ( >=net-libs/aqbanking-5[gtk,ofx?]
+		sys-libs/gwenhywfar[gtk]
+		chipcard? ( sys-libs/libchipcard )
+	)
+	python? ( ${PYTHON_DEPS} )
+	quotes? ( dev-perl/Date-Manip
+		>=dev-perl/Finance-Quote-1.11
+		dev-perl/HTML-TableExtract )
+	sqlite? ( >=dev-db/libdbi-0.9.0
+		>=dev-db/libdbi-drivers-0.9.0[sqlite] )
+	postgres? ( dev-db/libdbi dev-db/libdbi-drivers[postgres] )
+	mysql? ( dev-db/libdbi dev-db/libdbi-drivers[mysql] )
+"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	gnome-base/gnome-common
+	sys-devel/libtool
+	virtual/pkgconfig
+"
+PDEPEND="doc? ( >=app-doc/gnucash-docs-2.2.0 )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# Skip test that needs some locales to be present
+	sed -i -e '/test_suite_gnc_date/d' src/libqof/qof/test/test-qof.c || die
+
+	# We need to run eautoreconf to prevent linking against system libs,
+	# this can be noticed, for example, when updating an old version
+	# compiled against guile-1.8 to a newer one relying on 2.0
+	# https://bugs.gentoo.org/show_bug.cgi?id=590536#c39
+	# https://bugzilla.gnome.org/show_bug.cgi?id=775634
+	eautoreconf
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf
+
+	DOCS="doc/README.OFX doc/README.HBCI"
+
+	if use sqlite || use mysql || use postgres ; then
+		myconf+=" --enable-dbi"
+	else
+		myconf+=" --disable-dbi"
+	fi
+
+	# gtkmm is experimental and shouldn't be enabled, upstream bug #684166
+	gnome2_src_configure \
+		$(use_enable debug) \
+		$(use_enable gnome-keyring password-storage) \
+		$(use_enable ofx) \
+		$(use_enable hbci aqbanking) \
+		$(use_enable python) \
+		--disable-doxygen \
+		--disable-gtkmm \
+		--enable-locale-specific-tax \
+		--disable-error-on-warning \
+		--with-guile=2.0 \
+		${myconf}
+}
+
+src_install() {
+	# Parallel installation fails from time to time, bug #359123
+	gnome2_src_install -j1 GNC_DOC_INSTALL_DIR=/usr/share/doc/${PF}
+
+	rm -rf "${ED}"/usr/share/doc/${PF}/{examples/,COPYING,INSTALL,*win32-bin.txt,projects.html}
+	mv "${ED}"/usr/share/doc/${PF} "${T}"/cantuseprepalldocs || die
+	dodoc "${T}"/cantuseprepalldocs/*
+}
diff --git a/app-office/gnucash/gnucash-2.6.15.ebuild b/app-office/gnucash/gnucash-2.6.15.ebuild
new file mode 100644
index 000000000000..613dc5706890
--- /dev/null
+++ b/app-office/gnucash/gnucash-2.6.15.ebuild
@@ -0,0 +1,110 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="6"
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools gnome2 python-single-r1
+
+DESCRIPTION="A personal finance manager"
+HOMEPAGE="http://www.gnucash.org/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="chipcard debug +doc gnome-keyring hbci mysql ofx postgres python quotes sqlite"
+
+# FIXME: rdepend on dev-libs/qof when upstream fix their mess (see configure.ac)
+# libdbi version requirement for sqlite taken from bug #455134
+RDEPEND="
+	>=dev-libs/glib-2.32.0:2
+	>=dev-libs/popt-1.5
+	>=dev-libs/libxml2-2.5.10:2
+	dev-libs/libxslt
+	>=dev-scheme/guile-1.8.3:12=[deprecated,regex]
+	<dev-scheme/guile-2:12
+	dev-scheme/guile-www
+	gnome-base/libgnomecanvas
+	>=net-libs/webkit-gtk-1.2:2
+	>=sys-libs/zlib-1.1.4
+	>=x11-libs/gtk+-2.24:2
+	>=x11-libs/goffice-0.7.0:0.8[gnome]
+	x11-libs/pango
+	gnome-keyring? ( >=app-crypt/libsecret-0.18 )
+	ofx? ( >=dev-libs/libofx-0.9.1 )
+	hbci? ( >=net-libs/aqbanking-5[gtk,ofx?]
+		sys-libs/gwenhywfar[gtk]
+		chipcard? ( sys-libs/libchipcard )
+	)
+	python? ( ${PYTHON_DEPS} )
+	quotes? ( dev-perl/Date-Manip
+		>=dev-perl/Finance-Quote-1.11
+		dev-perl/HTML-TableExtract )
+	sqlite? ( >=dev-db/libdbi-0.9.0
+		>=dev-db/libdbi-drivers-0.9.0[sqlite] )
+	postgres? ( dev-db/libdbi dev-db/libdbi-drivers[postgres] )
+	mysql? ( dev-db/libdbi dev-db/libdbi-drivers[mysql] )
+"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	gnome-base/gnome-common
+	sys-devel/libtool
+	virtual/pkgconfig
+"
+PDEPEND="doc? ( >=app-doc/gnucash-docs-2.2.0 )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	# Skip test that needs some locales to be present
+	sed -i -e '/test_suite_gnc_date/d' src/libqof/qof/test/test-qof.c || die
+
+	# We need to run eautoreconf to prevent linking against system libs,
+	# this can be noticed, for example, when updating an old version
+	# compiled against guile-1.8 to a newer one relying on 2.0
+	# https://bugs.gentoo.org/show_bug.cgi?id=590536#c39
+	# https://bugzilla.gnome.org/show_bug.cgi?id=775634
+	eautoreconf
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf
+
+	DOCS="doc/README.OFX doc/README.HBCI"
+
+	if use sqlite || use mysql || use postgres ; then
+		myconf+=" --enable-dbi"
+	else
+		myconf+=" --disable-dbi"
+	fi
+
+	# gtkmm is experimental and shouldn't be enabled, upstream bug #684166
+	gnome2_src_configure \
+		$(use_enable debug) \
+		$(use_enable gnome-keyring password-storage) \
+		$(use_enable ofx) \
+		$(use_enable hbci aqbanking) \
+		$(use_enable python) \
+		--disable-doxygen \
+		--disable-gtkmm \
+		--enable-locale-specific-tax \
+		--disable-error-on-warning \
+		--with-guile=1.8 \
+		${myconf}
+}
+
+src_install() {
+	# Parallel installation fails from time to time, bug #359123
+	gnome2_src_install -j1 GNC_DOC_INSTALL_DIR=/usr/share/doc/${PF}
+
+	rm -rf "${ED}"/usr/share/doc/${PF}/{examples/,COPYING,INSTALL,*win32-bin.txt,projects.html}
+	mv "${ED}"/usr/share/doc/${PF} "${T}"/cantuseprepalldocs || die
+	dodoc "${T}"/cantuseprepalldocs/*
+}