app-pda/libimobiledevice: version bump to 1.3.0

Signed-off-by: Jeffrey Lin <jeffrey@icurse.nl>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 110 insertions, 0 deletions

diff --git a/app-pda/libimobiledevice/Manifest b/app-pda/libimobiledevice/Manifest
index b2c3bec82174..1d40da80c875 100644
--- a/app-pda/libimobiledevice/Manifest
+++ b/app-pda/libimobiledevice/Manifest
@@ -3,3 +3,4 @@ DIST libimobiledevice-1.2.0-userpref-GnuTLS-Fix-3.6.0-SHA1-compatibility.patch 2
 DIST libimobiledevice-1.2.0-userpref-GnuTLS-Use-valid-serial-for-3.6.0.patch 2014 BLAKE2B 8a6e51af145cf9983aa92ad7febf8d48a64b81f4f4664079ee7df3d433626141e10af6700ad38aad81bbbf3be03d6b35bae4f10a595e97f6998a06b6b2a4fbd4 SHA512 1c6002f8da5524603b989613fc1b14e526bc6fcbf515890f8c4976fe5e1b3801f04f6b210264624990ff7dd7de01063ad53dbf9ec506a0645098692a948216b9
 DIST libimobiledevice-1.2.0.tar.bz2 631495 BLAKE2B b04d87906615710e9e143013d27f4a0735e444160cb9dad464cb63d568470397f504680b3faca3995932cc8a80970a5923128d356fad9c98372af4981373ed69 SHA512 0de5f768aeb5d62445892855d84ceaff776f6667733c351ed6c34bf9d500802762d1a06e5efdf57f33cafc9ee788041cd9b6748fb9bad6c2e4ae2f9b9aa93589
 DIST libimobiledevice-1.2.1_pre20200220.tar.bz2 193582 BLAKE2B 7fab2101ee96a5fcc5dc68bad1a6c9fef25d87f25660cbce9aef45f8830c0162179f07e3d8a0f1d7d60bb7a219b1c4ee2513d43f98e8e4ea0d891686600c370e SHA512 f9d04941685f1cb0e982d061a6ea92d88d1d90157a789460e09e6af72954ed7a7f0448efbef3fe3cbca380195ffa658f7d8119e812f8ba8003c1e8a242976865
+DIST libimobiledevice-1.3.0.tar.bz2 733949 BLAKE2B 40717280bb3424c7431aa93d06d10de817e6761acf2b19948d80b691cfb4dd4ef0e31b81c8458eed29a43c8c8aa256da7baa3648fb785cfbdb7316daaba119a3 SHA512 7b22040552a6561729c79c0846f571b0e608abb7c297567d2ecfdd1718ce86df08a5e34ba51f209bdee96a1917da15e7ba3aaef1d289a951d1d3470b1f89e6a8
diff --git a/app-pda/libimobiledevice/libimobiledevice-1.3.0.ebuild b/app-pda/libimobiledevice/libimobiledevice-1.3.0.ebuild
new file mode 100644
index 000000000000..2d8348441704
--- /dev/null
+++ b/app-pda/libimobiledevice/libimobiledevice-1.3.0.ebuild
@@ -0,0 +1,109 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{7,8} )
+
+inherit autotools python-r1
+
+DESCRIPTION="Support library to communicate with Apple iPhone/iPod Touch devices"
+HOMEPAGE="https://www.libimobiledevice.org/"
+SRC_URI="https://www.libimobiledevice.org/downloads/${P}.tar.bz2"
+
+# While COPYING* doesn't mention 'or any later version', all the headers do, hence use +
+LICENSE="GPL-2+ LGPL-2.1+"
+
+SLOT="0/6" # based on SONAME of libimobiledevice.so
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="doc gnutls libressl python static-libs"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="
+	>=app-pda/libplist-2.2.0:=
+	>=app-pda/libusbmuxd-2.0.2:=
+	gnutls? (
+		dev-libs/libgcrypt:0
+		>=dev-libs/libtasn1-1.1
+		>=net-libs/gnutls-2.2.0 )
+	!gnutls? (
+		!libressl? ( dev-libs/openssl:0= )
+		libressl? ( dev-libs/libressl:0= ) )
+	python? (
+		${PYTHON_DEPS}
+		app-pda/libplist[python(-),${PYTHON_USEDEP}] )
+"
+
+DEPEND="
+	${RDEPEND}
+"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	python? ( >=dev-python/cython-0.17[${PYTHON_USEDEP}] )
+"
+
+BUILD_DIR="${S}_build"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local ECONF_SOURCE=${S}
+
+	local myeconfargs=( $(use_enable static-libs static) )
+	use gnutls && myeconfargs+=( --disable-openssl )
+
+	do_configure() {
+		mkdir -p "${BUILD_DIR}" || die
+		pushd "${BUILD_DIR}" >/dev/null || die
+		econf "${myeconfargs[@]}" "${@}"
+		popd >/dev/null || die
+	}
+
+	do_configure_python() {
+		# Bug 567916
+		local -x PYTHON_LDFLAGS="$(python_get_LIBS)"
+		do_configure "$@"
+	}
+
+	do_configure --without-cython
+	use python && python_foreach_impl do_configure_python
+}
+
+src_compile() {
+	python_compile() {
+		emake -C "${BUILD_DIR}"/cython \
+			VPATH="${S}/cython:$1/cython" \
+			imobiledevice_la_LIBADD="$1/src/libimobiledevice.la"
+	}
+
+	emake -C "${BUILD_DIR}"
+	use python && python_foreach_impl python_compile "${BUILD_DIR}"
+
+	if use doc; then
+		doxygen "${BUILD_DIR}"/doxygen.cfg || die
+	fi
+}
+
+src_install() {
+	python_install() {
+		emake -C "${BUILD_DIR}/cython" install \
+			DESTDIR="${D}" \
+			VPATH="${S}/cython:$1/cython"
+	}
+
+	emake -C "${BUILD_DIR}" install DESTDIR="${D}"
+	use python && python_foreach_impl python_install "${BUILD_DIR}"
+	use doc && dodoc docs/html/*
+
+	if use python; then
+		insinto /usr/include/${PN}/cython
+		doins cython/imobiledevice.pxd
+	fi
+
+	find "${D}" -name '*.la' -delete || die
+}