summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorThomas Deutschmann <whissi@gentoo.org>2017-06-06 15:32:20 +0200
committerThomas Deutschmann <whissi@gentoo.org>2017-06-06 15:32:37 +0200
commitb7d7cf44be09d4e31261c8adfdcced02a73d8585 (patch)
tree2a5ad7cf39aa03fdeaee18dd9aad712d4b6c7e21 /app-pda
parentx11-plugins/purple-plugin_pack: Disable xmmsremote compilation (#605218) (diff)
downloadgentoo-b7d7cf44be09d4e31261c8adfdcced02a73d8585.tar.gz
gentoo-b7d7cf44be09d4e31261c8adfdcced02a73d8585.tar.bz2
gentoo-b7d7cf44be09d4e31261c8adfdcced02a73d8585.zip
app-pda/libplist: Security bump to v2.0.0 (bug #608040)
Package-Manager: Portage-2.3.5, Repoman-2.3.2
Diffstat (limited to 'app-pda')
-rw-r--r--app-pda/libplist/Manifest1
-rw-r--r--app-pda/libplist/libplist-2.0.0.ebuild87
-rw-r--r--app-pda/libplist/metadata.xml4
3 files changed, 92 insertions, 0 deletions
diff --git a/app-pda/libplist/Manifest b/app-pda/libplist/Manifest
index e8f6f1634b1..73f0e7344a0 100644
--- a/app-pda/libplist/Manifest
+++ b/app-pda/libplist/Manifest
@@ -1 +1,2 @@
DIST libplist-1.12.tar.bz2 384321 SHA256 0effdedcb3de128c4930d8c03a3854c74c426c16728b8ab5f0a5b6bdc0b644be SHA512 8af40d8f457ca9a8a9061e9429698c696200714cc05dcbe981e900106c52cd5222edb9dd8d8976bccd0c8997508ed14fb2e10f0ed29383f2ad4f7c5eb7eec0b3 WHIRLPOOL 7d3c4f7822683018b5b0e794d509b9cf5a703605ed772df849ad9ebba6e8191f2eb629444c07d2dcb265520d24c94f13287f200fec34779c9e6fe029536183a7
+DIST libplist-2.0.0.tar.bz2 421405 SHA256 3a7e9694c2d9a85174ba1fa92417cfabaea7f6d19631e544948dc7e17e82f602 SHA512 81508bf6773483528816725c3b5b868563b84fd7810999404072e5ea9efa7fc9f11ef997f32208e4421aa26b15edd0c65f87c67c1472e8c4e356f1e9fe7740ee WHIRLPOOL cfea767321dda602722281f189dae708969c7471bc4b9388638b671257f3808358e1227cdf29cba7751cb715a8ec92fccb1c0dd5c8d150ebac19fdf8633c6339
diff --git a/app-pda/libplist/libplist-2.0.0.ebuild b/app-pda/libplist/libplist-2.0.0.ebuild
new file mode 100644
index 00000000000..64e5408872f
--- /dev/null
+++ b/app-pda/libplist/libplist-2.0.0.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+inherit autotools eutils python-r1
+
+DESCRIPTION="Support library to deal with Apple Property Lists (Binary & XML)"
+HOMEPAGE="http://www.libimobiledevice.org/"
+SRC_URI="http://www.libimobiledevice.org/downloads/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0/3.1.0" # based on SONAME of libplist.so
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-fbsd"
+IUSE="python static-libs"
+
+RDEPEND="python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}
+ virtual/pkgconfig
+ python? ( >=dev-python/cython-0.17[${PYTHON_USEDEP}] )"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DOCS=( AUTHORS NEWS README )
+
+BUILD_DIR="${S}_build"
+
+src_prepare() {
+ default
+
+ eautoreconf
+}
+
+src_configure() {
+ local ECONF_SOURCE=${S}
+ local myeconfargs=( $(use_enable static-libs static) )
+
+ do_configure() {
+ mkdir -p "${BUILD_DIR}" || die
+ pushd "${BUILD_DIR}" >/dev/null || die
+ econf "${myeconfargs[@]}" "${@}"
+ popd >/dev/null || die
+ }
+
+ do_configure_python() {
+ PYTHON_LDFLAGS="$(python_get_LIBS)" do_configure "$@"
+ }
+
+ do_configure --without-cython
+ use python && python_foreach_impl do_configure_python
+}
+
+src_compile() {
+ python_compile() {
+ emake -C "${BUILD_DIR}"/cython -j1 \
+ VPATH="${S}/cython:${native_builddir}/cython" \
+ plist_la_LIBADD="${native_builddir}/src/libplist.la"
+ }
+
+ local native_builddir=${BUILD_DIR}
+ pushd "${BUILD_DIR}" >/dev/null || die
+ emake -j1
+ use python && python_foreach_impl python_compile
+ popd >/dev/null || die
+}
+
+src_install() {
+ python_install() {
+ emake -C "${BUILD_DIR}/cython" -j1 \
+ VPATH="${S}/cython:${native_builddir}/cython" \
+ DESTDIR="${D}" install
+ }
+
+ local native_builddir=${BUILD_DIR}
+ pushd "${BUILD_DIR}" >/dev/null || die
+ emake -j1 DESTDIR="${D}" install
+ use python && python_foreach_impl python_install
+ popd >/dev/null || die
+
+ einstalldocs
+
+ if use python ; then
+ insinto /usr/include/plist/cython
+ doins cython/plist.pxd
+ fi
+ prune_libtool_files --all
+}
diff --git a/app-pda/libplist/metadata.xml b/app-pda/libplist/metadata.xml
index 6f49eba8f49..7cae0531e52 100644
--- a/app-pda/libplist/metadata.xml
+++ b/app-pda/libplist/metadata.xml
@@ -2,4 +2,8 @@
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<!-- maintainer-needed -->
+ <upstream>
+ <bugs-to>https://github.com/libimobiledevice/libplist/issues</bugs-to>
+ <remote-id type="github">libimobiledevice/libplist</remote-id>
+ </upstream>
</pkgmetadata>