summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorMarc Joliet <marcec@gmx.de>2015-10-25 20:05:02 +0100
committerMarc Joliet <marcec@gmx.de>2015-11-14 00:01:23 +0100
commit97e1ebd5c6ad7e84eb852fe2e874ee1ffd748485 (patch)
tree2d8e1fd80adc85156c008600e1432e4e242660ec /app-text/asciidoc/asciidoc-8.6.9-r2.ebuild
parentx11-drivers/nvidia-drivers: Stable for AMD64 x86 too. (diff)
downloadgentoo-97e1ebd5c6ad7e84eb852fe2e874ee1ffd748485.tar.gz
gentoo-97e1ebd5c6ad7e84eb852fe2e874ee1ffd748485.tar.bz2
gentoo-97e1ebd5c6ad7e84eb852fe2e874ee1ffd748485.zip
app-text/asciidoc: revbump to 8.6.9-r2 to add deps
Also, drop keywords to match app-text/dblatex. Gentoo-bug: 366763 Signed-off-by: Marc Joliet <marcec@gmx.de>
Diffstat (limited to 'app-text/asciidoc/asciidoc-8.6.9-r2.ebuild')
-rw-r--r--app-text/asciidoc/asciidoc-8.6.9-r2.ebuild82
1 files changed, 82 insertions, 0 deletions
diff --git a/app-text/asciidoc/asciidoc-8.6.9-r2.ebuild b/app-text/asciidoc/asciidoc-8.6.9-r2.ebuild
new file mode 100644
index 00000000000..83e955b6fbc
--- /dev/null
+++ b/app-text/asciidoc/asciidoc-8.6.9-r2.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 pypy )
+
+inherit python-single-r1
+
+DESCRIPTION="A text document format for writing short documents, articles, books and UNIX man pages"
+HOMEPAGE="http://asciidoc.org/"
+SRC_URI="mirror://sourceforge/project/${PN}/${PN}/${PV}/${P}.tar.gz"
+KEYWORDS="~amd64 ~x86"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="examples graphviz highlight test vim-syntax"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND=">=app-text/docbook-xsl-stylesheets-1.75
+ dev-libs/libxslt
+ graphviz? ( media-gfx/graphviz )
+ app-text/docbook-xml-dtd:4.5
+ app-text/dblatex
+ || ( www-client/w3m www-client/lynx )
+ highlight? ( || ( dev-python/pygments[${PYTHON_USEDEP}] dev-util/source-highlight ) )
+ ${PYTHON_DEPS}
+"
+DEPEND="test? ( dev-util/source-highlight
+ media-sound/lilypond
+ media-gfx/imagemagick
+ dev-texlive/texlive-latex
+ app-text/dvipng
+ media-gfx/graphviz
+ ${PYTHON_DEPS} )
+"
+
+src_prepare() {
+ if ! use vim-syntax; then
+ sed -i -e '/^install/s/install-vim//' Makefile.in || die
+ else
+ sed -i\
+ -e "/^vimdir/s:@sysconfdir@/vim:${EPREFIX}/usr/share/vim/vimfiles:" \
+ -e 's:/etc/vim::' \
+ Makefile.in || die
+ fi
+
+ # Only needed for prefix - harmless (does nothing) otherwise
+ sed -i -e "s:^CONF_DIR=.*:CONF_DIR='${EPREFIX}/etc/asciidoc':" \
+ "${S}/asciidoc.py" || die
+}
+
+src_configure() {
+ econf --sysconfdir="${EPREFIX}"/usr/share
+}
+
+src_install() {
+ use vim-syntax && dodir /usr/share/vim/vimfiles
+
+ emake DESTDIR="${D}" install
+
+ python_fix_shebang "${ED}"/usr/bin/*.py
+
+ dodoc BUGS CHANGELOG README docbook-xsl/asciidoc-docbook-xsl.txt \
+ dblatex/dblatex-readme.txt filters/code/code-filter-readme.txt
+
+ # Below results in some files being installed twice in different locations, but they are in the right place,
+ # uncompressed, and there won't be any broken links. See bug #483336.
+ if use examples; then
+ cp -rL examples/website "${D}"/usr/share/doc/${PF}/examples || die
+ fi
+ docompress -x /usr/share/doc/${PF}/examples
+}
+
+src_test() {
+ cd tests || die
+ local -x ASCIIDOC_PY=../asciidoc.py
+ "${PYTHON}" test${PN}.py update || die
+ "${PYTHON}" test${PN}.py run || die
+}