summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2019-03-22 23:46:01 +0100
committerAndreas Sturmlechner <asturm@gentoo.org>2019-03-23 01:43:38 +0100
commitbeae5a44d3675432865ccb1b530a688bc076f758 (patch)
treef5f4d46f759c07dcc3603d403e93f26d2d15a77f /app-text
parentkde-apps/kpat: Freeze FRAMEWORKS_MINIMAL and QT_MINIMAL (diff)
downloadgentoo-beae5a44d3675432865ccb1b530a688bc076f758.tar.gz
gentoo-beae5a44d3675432865ccb1b530a688bc076f758.tar.bz2
gentoo-beae5a44d3675432865ccb1b530a688bc076f758.zip
app-text/poppler: 0.75.0 version bump
Package-Manager: Portage-2.3.62, Repoman-2.3.12 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
Diffstat (limited to 'app-text')
-rw-r--r--app-text/poppler/Manifest1
-rw-r--r--app-text/poppler/poppler-0.75.0.ebuild127
-rw-r--r--app-text/poppler/poppler-9999.ebuild2
3 files changed, 129 insertions, 1 deletions
diff --git a/app-text/poppler/Manifest b/app-text/poppler/Manifest
index 02fdfba0686..100a810dc6f 100644
--- a/app-text/poppler/Manifest
+++ b/app-text/poppler/Manifest
@@ -1 +1,2 @@
DIST poppler-0.74.0.tar.xz 1514044 BLAKE2B af3821d5a5c68a3f2541cd9468fd7318ad0182cda66cea068dc42208fef6c2af78a401e50a6a5906cdc943de7339620937ddc6f69f0d8d1b15082aabc6cc3482 SHA512 4e48e2ffb559863ee693930db3b8594fd7e60e4b4ca3cdeb198faf90a6f4dbb5e102461492a12058221bc1218fe7e17c9085afb9e7956ae4bf26c11674315e66
+DIST poppler-0.75.0.tar.xz 1523872 BLAKE2B 245f574e985570a1d0923e732da8694728506fc59382c9e4532159867e1b18ad9f03f6b995891796d72a6e401d2c86ac18403c9219bf533e36c8a07a1dc85d61 SHA512 6a1b76cc5095b7c5809eaa5072aeb4ea615744ff8ffce537f40a3f73a81fc12cc18d596876ceda1c78b5312ad20535f72366e69c861b620d108616f24a98e6b8
diff --git a/app-text/poppler/poppler-0.75.0.ebuild b/app-text/poppler/poppler-0.75.0.ebuild
new file mode 100644
index 00000000000..4c97add33be
--- /dev/null
+++ b/app-text/poppler/poppler-0.75.0.ebuild
@@ -0,0 +1,127 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils flag-o-matic toolchain-funcs xdg-utils
+
+if [[ ${PV} == *9999* ]] ; then
+ inherit git-r3
+ EGIT_REPO_URI="https://anongit.freedesktop.org/git/poppler/poppler.git"
+ SLOT="0/9999"
+else
+ SRC_URI="https://poppler.freedesktop.org/${P}.tar.xz"
+ KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+ SLOT="0/86" # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
+fi
+
+DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
+HOMEPAGE="https://poppler.freedesktop.org/"
+
+LICENSE="GPL-2"
+IUSE="cairo cjk curl cxx debug doc +introspection +jpeg +jpeg2k +lcms nss png qt5 tiff +utils"
+
+# No test data provided
+RESTRICT="test"
+
+BDEPEND="
+ dev-util/glib-utils
+ virtual/pkgconfig
+"
+DEPEND="
+ media-libs/fontconfig
+ media-libs/freetype
+ sys-libs/zlib
+ cairo? (
+ dev-libs/glib:2
+ x11-libs/cairo
+ introspection? ( dev-libs/gobject-introspection:= )
+ )
+ curl? ( net-misc/curl )
+ jpeg? ( virtual/jpeg:0 )
+ jpeg2k? ( >=media-libs/openjpeg-2.3.0-r1:2= )
+ lcms? ( media-libs/lcms:2 )
+ nss? ( >=dev-libs/nss-3.19:0 )
+ png? ( media-libs/libpng:0= )
+ qt5? (
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtxml:5
+ )
+ tiff? ( media-libs/tiff:0 )
+"
+RDEPEND="${DEPEND}
+ cjk? ( app-text/poppler-data )
+"
+
+DOCS=( AUTHORS NEWS README README-XPDF )
+
+PATCHES=(
+ "${FILESDIR}/${PN}-0.60.1-qt5-dependencies.patch"
+ "${FILESDIR}/${PN}-0.28.1-fix-multilib-configuration.patch"
+ "${FILESDIR}/${PN}-0.71.0-respect-cflags.patch"
+ "${FILESDIR}/${PN}-0.61.0-respect-cflags.patch"
+ "${FILESDIR}/${PN}-0.57.0-disable-internal-jpx.patch"
+)
+
+src_prepare() {
+ cmake-utils_src_prepare
+
+ # Clang doesn't grok this flag, the configure nicely tests that, but
+ # cmake just uses it, so remove it if we use clang
+ if [[ ${CC} == clang ]] ; then
+ sed -e 's/-fno-check-new//' -i cmake/modules/PopplerMacros.cmake || die
+ fi
+
+ if ! grep -Fq 'cmake_policy(SET CMP0002 OLD)' CMakeLists.txt ; then
+ sed -e '/^cmake_minimum_required/acmake_policy(SET CMP0002 OLD)' \
+ -i CMakeLists.txt || die
+ else
+ einfo "policy(SET CMP0002 OLD) - workaround can be removed"
+ fi
+
+ # we need to up the C++ version, bug #622526, #643278
+ append-cxxflags -std=c++11
+}
+
+src_configure() {
+ xdg_environment_reset
+ local mycmakeargs=(
+ -DBUILD_GTK_TESTS=OFF
+ -DBUILD_QT5_TESTS=OFF
+ -DBUILD_CPP_TESTS=OFF
+ -DENABLE_SPLASH=ON
+ -DENABLE_ZLIB=ON
+ -DENABLE_ZLIB_UNCOMPRESS=OFF
+ -DENABLE_UNSTABLE_API_ABI_HEADERS=ON
+ -DSPLASH_CMYK=OFF
+ -DUSE_FIXEDPOINT=OFF
+ -DUSE_FLOAT=OFF
+ -DWITH_Cairo=$(usex cairo)
+ -DENABLE_LIBCURL=$(usex curl)
+ -DENABLE_CPP=$(usex cxx)
+ -DWITH_JPEG=$(usex jpeg)
+ -DENABLE_DCTDECODER=$(usex jpeg libjpeg none)
+ -DENABLE_LIBOPENJPEG=$(usex jpeg2k openjpeg2 none)
+ -DENABLE_CMS=$(usex lcms lcms2 none)
+ -DWITH_NSS3=$(usex nss)
+ -DWITH_PNG=$(usex png)
+ $(cmake-utils_use_find_package qt5 Qt5Core)
+ -DWITH_TIFF=$(usex tiff)
+ -DENABLE_UTILS=$(usex utils)
+ )
+ use cairo && mycmakeargs+=( -DWITH_GObjectIntrospection=$(usex introspection) )
+
+ cmake-utils_src_configure
+}
+
+src_install() {
+ cmake-utils_src_install
+
+ # live version doesn't provide html documentation
+ if use cairo && use doc && [[ ${PV} != *9999* ]]; then
+ # For now install gtk-doc there
+ insinto /usr/share/gtk-doc/html/poppler
+ doins -r "${S}"/glib/reference/html/*
+ fi
+}
diff --git a/app-text/poppler/poppler-9999.ebuild b/app-text/poppler/poppler-9999.ebuild
index d6fdf5f55a3..4c97add33be 100644
--- a/app-text/poppler/poppler-9999.ebuild
+++ b/app-text/poppler/poppler-9999.ebuild
@@ -12,7 +12,7 @@ if [[ ${PV} == *9999* ]] ; then
else
SRC_URI="https://poppler.freedesktop.org/${P}.tar.xz"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
- SLOT="0/85" # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
+ SLOT="0/86" # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
fi
DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"