summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorPacho Ramos <pacho@gentoo.org>2016-06-25 10:53:21 +0200
committerPacho Ramos <pacho@gentoo.org>2016-06-25 14:19:22 +0200
commitd6154367f0a3d874700c1867c245a96bc00664a5 (patch)
treec58e657e253544cbecc7134b0c7f46cce520ec34 /dev-cpp/gtkmm/gtkmm-3.20.1.ebuild
parentdev-cpp/pangomm: Version bump (diff)
downloadgentoo-d6154367f0a3d874700c1867c245a96bc00664a5.tar.gz
gentoo-d6154367f0a3d874700c1867c245a96bc00664a5.tar.bz2
gentoo-d6154367f0a3d874700c1867c245a96bc00664a5.zip
dev-cpp/gtkmm: Version bump
Package-Manager: portage-2.3.0_rc1
Diffstat (limited to 'dev-cpp/gtkmm/gtkmm-3.20.1.ebuild')
-rw-r--r--dev-cpp/gtkmm/gtkmm-3.20.1.ebuild69
1 files changed, 69 insertions, 0 deletions
diff --git a/dev-cpp/gtkmm/gtkmm-3.20.1.ebuild b/dev-cpp/gtkmm/gtkmm-3.20.1.ebuild
new file mode 100644
index 00000000000..42be0f9d470
--- /dev/null
+++ b/dev-cpp/gtkmm/gtkmm-3.20.1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils gnome2 multilib-minimal virtualx
+
+DESCRIPTION="C++ interface for GTK+"
+HOMEPAGE="http://www.gtkmm.org"
+
+LICENSE="LGPL-2.1+"
+SLOT="3.0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~x86-solaris"
+
+IUSE="aqua doc examples test wayland X"
+REQUIRED_USE="|| ( aqua wayland X )"
+
+RDEPEND="
+ >=dev-cpp/glibmm-2.48.0:2[${MULTILIB_USEDEP}]
+ >=x11-libs/gtk+-3.20.0:3[aqua?,wayland?,X?,${MULTILIB_USEDEP}]
+ >=x11-libs/gdk-pixbuf-2.28:2[${MULTILIB_USEDEP}]
+ >=dev-cpp/atkmm-2.24.2[${MULTILIB_USEDEP}]
+ >=dev-cpp/cairomm-1.12.0[${MULTILIB_USEDEP}]
+ >=dev-cpp/pangomm-2.38.2:1.4[${MULTILIB_USEDEP}]
+ >=dev-libs/libsigc++-2.3.2:2[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}
+ virtual/pkgconfig
+ examples? ( >=media-libs/libepoxy-1.2[${MULTILIB_USEDEP}] )
+ doc? (
+ media-gfx/graphviz
+ dev-libs/libxslt
+ app-doc/doxygen )
+"
+# dev-cpp/mm-common"
+# eautoreconf needs mm-common
+
+src_prepare() {
+ if ! use test; then
+ # don't waste time building tests
+ sed 's/^\(SUBDIRS =.*\)tests\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
+ || die "sed 1 failed"
+ fi
+
+ if ! use examples; then
+ # don't waste time building tests
+ sed 's/^\(SUBDIRS =.*\)demos\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
+ || die "sed 2 failed"
+ fi
+
+ gnome2_src_prepare
+}
+
+multilib_src_configure() {
+ ECONF_SOURCE="${S}" gnome2_src_configure \
+ --enable-api-atkmm \
+ $(multilib_native_use_enable doc documentation) \
+ $(use_enable aqua quartz-backend) \
+ $(use_enable wayland wayland-backend) \
+ $(use_enable X x11-backend)
+}
+
+multilib_src_test() {
+ virtx emake check
+}
+
+multilib_src_install() {
+ gnome2_src_install
+}