dev-db/sqlitebrowser: version bump and adoption

- update the `metadata.xml` file
- update dependencies: remove `dev-cpp/antlr-cpp:2`
  (see https://github.com/sqlitebrowser/sqlitebrowser/commit/ce66c1da20d15e8211a14db13f63cd42c2ede770/),
  update minimum required version of `x11-libs/qscintilla`
- add the live version

Closes: https://bugs.gentoo.org/735716
Signed-off-by: Mattéo Rossillol‑‑Laruelle <beatussum@protonmail.com>
Package-Manager: Portage-3.0.13, Repoman-3.0.2
Closes: https://github.com/gentoo/gentoo/pull/19246
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 67 insertions, 0 deletions

diff --git a/dev-db/sqlitebrowser/sqlitebrowser-9999.ebuild b/dev-db/sqlitebrowser/sqlitebrowser-9999.ebuild
new file mode 100644
index 000000000000..d094723adf0a
--- /dev/null
+++ b/dev-db/sqlitebrowser/sqlitebrowser-9999.ebuild
@@ -0,0 +1,67 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake xdg
+
+DESCRIPTION="A light GUI editor for SQLite databases"
+HOMEPAGE="https://sqlitebrowser.org/"
+
+if [[ "${PV}" = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}/${PN}.git"
+else
+	SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+ MPL-2.0"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	app-editors/qhexedit2
+	dev-db/sqlite:3
+	dev-libs/qcustomplot
+	>=dev-qt/qtconcurrent-5.5:5
+	>=dev-qt/qtcore-5.5:5
+	>=dev-qt/qtgui-5.5:5
+	>=dev-qt/qtnetwork-5.5:5[ssl]
+	>=dev-qt/qtprintsupport-5.5:5
+	>=dev-qt/qtwidgets-5.5:5
+	>=dev-qt/qtxml-5.5:5
+	>=x11-libs/qscintilla-2.8.10:=
+"
+
+BDEPEND="
+	>=dev-qt/linguist-tools-5.5:5
+	test? ( >=dev-qt/qttest-5.5:5 )
+"
+
+RDEPEND="
+	${DEPEND}
+	>=dev-qt/qtsvg-5.5:5
+"
+
+src_prepare() {
+	cmake_src_prepare
+
+	if ! use test; then
+		sed -i CMakeLists.txt \
+			-e "/find_package/ s/ Test//" \
+			-e "/set/ s/ Qt5::Test//" \
+			|| die "Cannot remove Qt Test from CMake dependencies"
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_TESTING=$(usex test)
+		-DFORCE_INTERNAL_QCUSTOMPLOT=OFF
+		-DFORCE_INTERNAL_QHEXEDIT=OFF
+	)
+
+	cmake_src_configure
+}