summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorThomas Deutschmann <whissi@gentoo.org>2020-01-18 10:03:50 +0100
committerThomas Deutschmann <whissi@gentoo.org>2020-01-18 10:51:27 +0100
commit68ee1b1855e70c799b23900a156842fbd7bb8d30 (patch)
tree4dbc52ae898d3a9e784874e00e3a67bcd0463a4e /dev-libs
parentnet-firewall/shorewall: bump to v5.2.3.5 (diff)
downloadgentoo-68ee1b1855e70c799b23900a156842fbd7bb8d30.tar.gz
gentoo-68ee1b1855e70c799b23900a156842fbd7bb8d30.tar.bz2
gentoo-68ee1b1855e70c799b23900a156842fbd7bb8d30.zip
dev-libs/librelp: bump to v1.5.0
Package-Manager: Portage-2.3.84, Repoman-2.3.20 Signed-off-by: Thomas Deutschmann <whissi@gentoo.org>
Diffstat (limited to 'dev-libs')
-rw-r--r--dev-libs/librelp/Manifest1
-rw-r--r--dev-libs/librelp/librelp-1.5.0.ebuild74
2 files changed, 75 insertions, 0 deletions
diff --git a/dev-libs/librelp/Manifest b/dev-libs/librelp/Manifest
index 014cc712da7..d3cdde4e4c9 100644
--- a/dev-libs/librelp/Manifest
+++ b/dev-libs/librelp/Manifest
@@ -1 +1,2 @@
DIST librelp-1.4.0.tar.gz 519235 BLAKE2B 9c1e52cc9f666e75f261db65f45e3d954afa033cac59f93394c30ba99ed772d71b2882bdbb9bed696e57ed99805d47e57fd5e331cc3bc3850c5f15041a0d70d0 SHA512 92d01a51b4ee3c66d1f65d2e26f214646d72b41a8411ab700fe5f9f30f805ef98dec962526ef95c8d8428bf7398d38f656c919f95a3e49382adc745ef9eb4239
+DIST librelp-1.5.0.tar.gz 521793 BLAKE2B f3fa42ab1df5bc7fea340bf87f241666535f61a5726df55f47f6f324347a1dbbede2a66d252fe654d21e79ee44684aa51e83cace32491778d6cc42698f578195 SHA512 b7fb35e4ddb5c3c14ef733699405f8aa62911adef305cd4f494170e111bc61a9208b84dab472a708582cd76ad9976894dae0e7574e60acdae2b56491aa7daf36
diff --git a/dev-libs/librelp/librelp-1.5.0.ebuild b/dev-libs/librelp/librelp-1.5.0.ebuild
new file mode 100644
index 00000000000..c5a14c6f2f4
--- /dev/null
+++ b/dev-libs/librelp/librelp-1.5.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=( python2_7 python3_{6,7,8} )
+
+inherit autotools python-any-r1
+
+DESCRIPTION="An easy to use library for the RELP protocol"
+HOMEPAGE="https://www.rsyslog.com/librelp/"
+SRC_URI="https://download.rsyslog.com/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3+ doc? ( FDL-1.3 )"
+
+# subslot = soname version
+SLOT="0/0.5.0"
+
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~sparc ~x86"
+IUSE="debug doc +ssl +gnutls libressl openssl static-libs test"
+REQUIRED_USE="ssl? ( ^^ ( gnutls openssl ) )"
+
+RDEPEND="
+ ssl? (
+ gnutls? ( >=net-libs/gnutls-3.3.17.1:0= )
+ openssl? (
+ !libressl? ( dev-libs/openssl:0= )
+ libressl? ( dev-libs/libressl:0= )
+ )
+ )"
+DEPEND="${RDEPEND}
+ test? ( ${PYTHON_DEPS} )
+ virtual/pkgconfig"
+
+RESTRICT="!test? ( test )"
+
+pkg_setup() {
+ use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+ sed -i \
+ -e 's/ -g"/"/g' \
+ configure.ac || die "sed failed"
+
+ default
+
+ eautoreconf
+}
+
+src_configure() {
+ local myeconfargs=(
+ --disable-valgrind
+ $(use_enable debug)
+ $(use_enable gnutls tls)
+ $(use_enable openssl tls-openssl)
+ $(use_enable static-libs static)
+ )
+
+ econf "${myeconfargs[@]}"
+}
+
+src_test() {
+ emake -j1 check
+}
+
+src_install() {
+ local DOCS=( ChangeLog )
+ use doc && local HTML_DOCS=( doc/relp.html )
+ default
+
+ if ! use static-libs; then
+ find "${D}" -name '*.la' -delete || die
+ fi
+}