summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2018-05-10 10:15:16 +0200
committerAndreas Sturmlechner <asturm@gentoo.org>2018-05-10 10:21:53 +0200
commitc009f3d53f64f0d278afede7ae74a33b64f512c1 (patch)
tree584df740851a136f7a08c1a9ae32787f5a5fafde /dev-python
parentapp-office/kmymoney: Fix build with Qt 5.11 (diff)
downloadgentoo-c009f3d53f64f0d278afede7ae74a33b64f512c1.tar.gz
gentoo-c009f3d53f64f0d278afede7ae74a33b64f512c1.tar.bz2
gentoo-c009f3d53f64f0d278afede7ae74a33b64f512c1.zip
dev-python/pyudev: Drop USE=qt4
Bug: https://bugs.gentoo.org/610826 Package-Manager: Portage-2.3.36, Repoman-2.3.9
Diffstat (limited to 'dev-python')
-rw-r--r--dev-python/pyudev/pyudev-0.20.0-r1.ebuild59
1 files changed, 59 insertions, 0 deletions
diff --git a/dev-python/pyudev/pyudev-0.20.0-r1.ebuild b/dev-python/pyudev/pyudev-0.20.0-r1.ebuild
new file mode 100644
index 00000000000..1bc6bf6e811
--- /dev/null
+++ b/dev-python/pyudev/pyudev-0.20.0-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python binding to libudev"
+HOMEPAGE="https://pyudev.readthedocs.io/en/latest/ https://github.com/pyudev/pyudev"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="amd64 arm ~arm64 x86"
+IUSE="pygobject test"
+
+RDEPEND="
+ dev-python/six[${PYTHON_USEDEP}]
+ virtual/udev
+ pygobject? ( dev-python/pygobject:2[$(python_gen_usedep 'python2*')] )"
+DEPEND="${RDEPEND}
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ test? (
+ dev-python/docutils[${PYTHON_USEDEP}]
+ dev-python/hypothesis[${PYTHON_USEDEP}]
+ dev-python/mock[${PYTHON_USEDEP}]
+ >=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+ )"
+
+DOCS=( CHANGES.rst README.rst )
+
+PATCHES=(
+ "${FILESDIR}/${PN}-0.19.0-skip-non-deterministic-test.patch"
+)
+
+REQUIRED_USE="pygobject? ( || ( $(python_gen_useflags 'python2*') ) )"
+
+python_prepare_all() {
+ if use test; then
+ ewarn "If your PORTAGE_TMPDIR is longer in length then '/var/tmp/',"
+ ewarn "change it to /var/tmp to ensure tests will pass."
+ fi
+
+ # tests are known to pass then fail on alternate runs
+ # tests: fix run_path
+ sed -i -e "s|== \('/run/udev'\)|in (\1,'/dev/.udev')|g" \
+ tests/test_core.py || die
+
+ # test needs needs newer dev-cpp/gccxml
+ rm -f tests/test_libudev.py
+
+ distutils-r1_python_prepare_all
+}
+
+python_test() {
+ py.test || die "Tests fail with ${EPYTHON}"
+}