summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2019-09-11 12:08:12 +0200
committerAndreas Sturmlechner <asturm@gentoo.org>2019-09-12 09:30:35 +0200
commit78d7f867dc4fa787c5b5f44de86cd2cc043d3d45 (patch)
tree02f4ea207e9cad8f4321d7633a9f18bf7682fc5d /dev-qt/assistant/assistant-5.12.5.ebuild
parentdev-qt/qt-docs: 5.12.5_p201908230013 version bump (diff)
downloadgentoo-78d7f867dc4fa787c5b5f44de86cd2cc043d3d45.tar.gz
gentoo-78d7f867dc4fa787c5b5f44de86cd2cc043d3d45.tar.bz2
gentoo-78d7f867dc4fa787c5b5f44de86cd2cc043d3d45.zip
dev-qt: Add Qt 5.12.5
Package-Manager: Portage-2.3.75, Repoman-2.3.17 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
Diffstat (limited to 'dev-qt/assistant/assistant-5.12.5.ebuild')
-rw-r--r--dev-qt/assistant/assistant-5.12.5.ebuild55
1 files changed, 55 insertions, 0 deletions
diff --git a/dev-qt/assistant/assistant-5.12.5.ebuild b/dev-qt/assistant/assistant-5.12.5.ebuild
new file mode 100644
index 00000000000..ad1fb3981ef
--- /dev/null
+++ b/dev-qt/assistant/assistant-5.12.5.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+QT5_MODULE="qttools"
+inherit desktop qt5-build xdg-utils
+
+DESCRIPTION="Tool for viewing on-line documentation in Qt help file format"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+ KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc64 ~sparc ~x86"
+fi
+
+IUSE="webkit"
+
+DEPEND="
+ ~dev-qt/qtcore-${PV}
+ ~dev-qt/qtgui-${PV}
+ ~dev-qt/qthelp-${PV}
+ ~dev-qt/qtnetwork-${PV}
+ ~dev-qt/qtprintsupport-${PV}
+ ~dev-qt/qtsql-${PV}[sqlite]
+ ~dev-qt/qtwidgets-${PV}
+ webkit? ( >=dev-qt/qtwebkit-5.9.1:5 )
+"
+RDEPEND="${DEPEND}"
+
+QT5_TARGET_SUBDIRS=(
+ src/assistant/assistant
+)
+
+src_prepare() {
+ qt_use_disable_mod webkit webkitwidgets \
+ src/assistant/assistant/assistant.pro
+
+ qt5-build_src_prepare
+}
+
+src_install() {
+ qt5-build_src_install
+
+ doicon -s 32 src/assistant/assistant/images/assistant.png
+ newicon -s 128 src/assistant/assistant/images/assistant-128.png assistant.png
+ make_desktop_entry "${QT5_BINDIR}"/assistant 'Qt 5 Assistant' assistant 'Qt;Development;Documentation'
+}
+
+pkg_postinst() {
+ qt5-build_pkg_postinst
+ xdg_icon_cache_update
+}
+
+pkg_postrm() {
+ qt5-build_pkg_postrm
+ xdg_icon_cache_update
+}