summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2020-05-17 01:55:50 +0200
committerAndreas Sturmlechner <asturm@gentoo.org>2020-05-17 02:22:30 +0200
commitf499bdec65168fad8f0d12452210daf4bee338e8 (patch)
treec8b3475b94bdba34ca370593d148c5d4f68cd010 /dev-qt/qtdeclarative/qtdeclarative-5.14.2-r1.ebuild
parentmedia-video/vlc: Drop unused build option (diff)
downloadgentoo-f499bdec65168fad8f0d12452210daf4bee338e8.tar.gz
gentoo-f499bdec65168fad8f0d12452210daf4bee338e8.tar.bz2
gentoo-f499bdec65168fad8f0d12452210daf4bee338e8.zip
dev-qt/qtdeclarative: QQuickItemView: Fix max(X/Y)Extent()
KDE-Bug: https://bugs.kde.org/show_bug.cgi?id=419514 QTBUG: https://bugreports.qt.io/browse/QTBUG-83890 Bug: https://bugs.gentoo.org/716992 Package-Manager: Portage-2.3.99, Repoman-2.3.22 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
Diffstat (limited to 'dev-qt/qtdeclarative/qtdeclarative-5.14.2-r1.ebuild')
-rw-r--r--dev-qt/qtdeclarative/qtdeclarative-5.14.2-r1.ebuild55
1 files changed, 55 insertions, 0 deletions
diff --git a/dev-qt/qtdeclarative/qtdeclarative-5.14.2-r1.ebuild b/dev-qt/qtdeclarative/qtdeclarative-5.14.2-r1.ebuild
new file mode 100644
index 00000000000..5eb5c48069c
--- /dev/null
+++ b/dev-qt/qtdeclarative/qtdeclarative-5.14.2-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 2009-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit python-any-r1 qt5-build
+
+DESCRIPTION="The QML and Quick modules for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+ KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+IUSE="gles2-only +jit localstorage vulkan +widgets"
+
+BDEPEND="${PYTHON_DEPS}"
+# qtgui[gles2-only=] is needed because of bug 504322
+DEPEND="
+ ~dev-qt/qtcore-${PV}
+ ~dev-qt/qtgui-${PV}[gles2-only=,vulkan=]
+ ~dev-qt/qtnetwork-${PV}
+ ~dev-qt/qttest-${PV}
+ localstorage? ( ~dev-qt/qtsql-${PV} )
+ widgets? ( ~dev-qt/qtwidgets-${PV}[gles2-only=] )
+"
+RDEPEND="${DEPEND}
+ !<dev-qt/qtquickcontrols-5.7:5
+"
+
+PATCHES=("${FILESDIR}/${P}-QQuickItemView-fix-maxXY-extent.patch" ) # QTBUG-83890
+
+src_prepare() {
+ use jit || PATCHES+=("${FILESDIR}/${PN}-5.4.2-disable-jit.patch")
+
+ qt_use_disable_mod localstorage sql \
+ src/imports/imports.pro
+
+ qt_use_disable_mod widgets widgets \
+ src/src.pro \
+ src/qmltest/qmltest.pro \
+ tests/auto/auto.pro \
+ tools/tools.pro \
+ tools/qmlscene/qmlscene.pro \
+ tools/qml/qml.pro
+
+ qt5-build_src_prepare
+}
+
+src_configure() {
+ local myqmakeargs=(
+ --
+ -qml-debug
+ )
+ qt5-build_src_configure
+}