summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2020-04-09 22:00:29 +0200
committerAndreas Sturmlechner <asturm@gentoo.org>2020-04-09 23:36:28 +0200
commit56acf9bac388533631838ff019e20eb41af0bbe0 (patch)
treec07a708b057f14c3743b759772c8fb0d82704201 /dev-qt/qtdeclarative/qtdeclarative-5.14.2.ebuild
parentqt5-build.eclass: Drop obsolete in-source build workaround for >=5.14.2 (diff)
downloadgentoo-56acf9bac388533631838ff019e20eb41af0bbe0.tar.gz
gentoo-56acf9bac388533631838ff019e20eb41af0bbe0.tar.bz2
gentoo-56acf9bac388533631838ff019e20eb41af0bbe0.zip
dev-qt: Add Qt 5.14.2
Closes: https://bugs.gentoo.org/669994 Closes: https://bugs.gentoo.org/710866 Closes: https://bugs.gentoo.org/713722 Closes: https://bugs.gentoo.org/716754 Package-Manager: Portage-2.3.98, Repoman-2.3.22 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
Diffstat (limited to 'dev-qt/qtdeclarative/qtdeclarative-5.14.2.ebuild')
-rw-r--r--dev-qt/qtdeclarative/qtdeclarative-5.14.2.ebuild53
1 files changed, 53 insertions, 0 deletions
diff --git a/dev-qt/qtdeclarative/qtdeclarative-5.14.2.ebuild b/dev-qt/qtdeclarative/qtdeclarative-5.14.2.ebuild
new file mode 100644
index 000000000000..5e576bf96099
--- /dev/null
+++ b/dev-qt/qtdeclarative/qtdeclarative-5.14.2.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2009-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit python-any-r1 qt5-build
+
+DESCRIPTION="The QML and Quick modules for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+ KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+fi
+
+IUSE="gles2-only +jit localstorage vulkan +widgets"
+
+BDEPEND="${PYTHON_DEPS}"
+# qtgui[gles2-only=] is needed because of bug 504322
+DEPEND="
+ ~dev-qt/qtcore-${PV}
+ ~dev-qt/qtgui-${PV}[gles2-only=,vulkan=]
+ ~dev-qt/qtnetwork-${PV}
+ ~dev-qt/qttest-${PV}
+ localstorage? ( ~dev-qt/qtsql-${PV} )
+ widgets? ( ~dev-qt/qtwidgets-${PV}[gles2-only=] )
+"
+RDEPEND="${DEPEND}
+ !<dev-qt/qtquickcontrols-5.7:5
+"
+
+src_prepare() {
+ use jit || PATCHES+=("${FILESDIR}/${PN}-5.4.2-disable-jit.patch")
+
+ qt_use_disable_mod localstorage sql \
+ src/imports/imports.pro
+
+ qt_use_disable_mod widgets widgets \
+ src/src.pro \
+ src/qmltest/qmltest.pro \
+ tests/auto/auto.pro \
+ tools/tools.pro \
+ tools/qmlscene/qmlscene.pro \
+ tools/qml/qml.pro
+
+ qt5-build_src_prepare
+}
+
+src_configure() {
+ local myqmakeargs=(
+ --
+ -qml-debug
+ )
+ qt5-build_src_configure
+}