summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2020-02-26 22:43:03 +0100
committerAndreas Sturmlechner <asturm@gentoo.org>2020-02-26 22:56:44 +0100
commit52e33ecce45082b463edb683ef33ddc729c1d690 (patch)
tree0a42a6b29e0328e2758e70ec5ee1dd6e8ecdb560 /dev-qt/qtdeclarative
parentdev-qt/qtwayland: Drop 5.14.1 (r0) (diff)
downloadgentoo-52e33ecce45082b463edb683ef33ddc729c1d690.tar.gz
gentoo-52e33ecce45082b463edb683ef33ddc729c1d690.tar.bz2
gentoo-52e33ecce45082b463edb683ef33ddc729c1d690.zip
dev-qt/qtdeclarative: Add USE vulkan
Bug: https://bugs.gentoo.org/703594 Package-Manager: Portage-2.3.89, Repoman-2.3.20 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
Diffstat (limited to 'dev-qt/qtdeclarative')
-rw-r--r--dev-qt/qtdeclarative/metadata.xml1
-rw-r--r--dev-qt/qtdeclarative/qtdeclarative-5.14.1-r1.ebuild53
2 files changed, 54 insertions, 0 deletions
diff --git a/dev-qt/qtdeclarative/metadata.xml b/dev-qt/qtdeclarative/metadata.xml
index cffb0c60697..9fc8265089e 100644
--- a/dev-qt/qtdeclarative/metadata.xml
+++ b/dev-qt/qtdeclarative/metadata.xml
@@ -8,6 +8,7 @@
<use>
<flag name="gles2">Use GLES 2.0 or later instead of full OpenGL</flag>
<flag name="localstorage">Build the LocalStorage import for QtQuick (requires QtSql)</flag>
+ <flag name="vulkan">Enable support for Vulkan</flag>
<flag name="widgets">Enable QtWidgets support</flag>
</use>
<upstream>
diff --git a/dev-qt/qtdeclarative/qtdeclarative-5.14.1-r1.ebuild b/dev-qt/qtdeclarative/qtdeclarative-5.14.1-r1.ebuild
new file mode 100644
index 00000000000..74bb692c392
--- /dev/null
+++ b/dev-qt/qtdeclarative/qtdeclarative-5.14.1-r1.ebuild
@@ -0,0 +1,53 @@
+# Copyright 2009-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit python-any-r1 qt5-build
+
+DESCRIPTION="The QML and Quick modules for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+ KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
+fi
+
+IUSE="gles2 +jit localstorage vulkan +widgets"
+
+BDEPEND="${PYTHON_DEPS}"
+# qtgui[gles2=] is needed because of bug 504322
+DEPEND="
+ ~dev-qt/qtcore-${PV}
+ ~dev-qt/qtgui-${PV}[gles2=,vulkan=]
+ ~dev-qt/qtnetwork-${PV}
+ ~dev-qt/qttest-${PV}
+ localstorage? ( ~dev-qt/qtsql-${PV} )
+ widgets? ( ~dev-qt/qtwidgets-${PV}[gles2=] )
+"
+RDEPEND="${DEPEND}
+ !<dev-qt/qtquickcontrols-5.7:5
+"
+
+src_prepare() {
+ use jit || PATCHES+=("${FILESDIR}/${PN}-5.4.2-disable-jit.patch")
+
+ qt_use_disable_mod localstorage sql \
+ src/imports/imports.pro
+
+ qt_use_disable_mod widgets widgets \
+ src/src.pro \
+ src/qmltest/qmltest.pro \
+ tests/auto/auto.pro \
+ tools/tools.pro \
+ tools/qmlscene/qmlscene.pro \
+ tools/qml/qml.pro
+
+ qt5-build_src_prepare
+}
+
+src_configure() {
+ local myqmakeargs=(
+ --
+ -qml-debug
+ )
+ qt5-build_src_configure
+}