summaryrefslogtreecommitdiff
diff options
context:
space:
mode:
authorAndreas Sturmlechner <asturm@gentoo.org>2020-07-25 20:55:32 +0200
committerAndreas Sturmlechner <asturm@gentoo.org>2020-07-30 12:10:57 +0200
commitbfdd93f95193a6677fe242c591fb0179a548d5a5 (patch)
tree19e150fd52ed5e6ea07ce0d743bff445b5d86cde /dev-qt/qtdeclarative
parentdev-perl/Digest-BubbleBabble: -r bump for EAPI7 + fixes (diff)
downloadgentoo-bfdd93f95193a6677fe242c591fb0179a548d5a5.tar.gz
gentoo-bfdd93f95193a6677fe242c591fb0179a548d5a5.tar.bz2
gentoo-bfdd93f95193a6677fe242c591fb0179a548d5a5.zip
dev-qt/qtdeclarative: Trigger rebuild on dev-qt/qtgui subslot update
Closes: https://bugs.gentoo.org/733674 Package-Manager: Portage-3.0.0, Repoman-2.3.23 Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
Diffstat (limited to 'dev-qt/qtdeclarative')
-rw-r--r--dev-qt/qtdeclarative/qtdeclarative-5.14.2-r4.ebuild59
-rw-r--r--dev-qt/qtdeclarative/qtdeclarative-5.15.0-r1.ebuild58
2 files changed, 117 insertions, 0 deletions
diff --git a/dev-qt/qtdeclarative/qtdeclarative-5.14.2-r4.ebuild b/dev-qt/qtdeclarative/qtdeclarative-5.14.2-r4.ebuild
new file mode 100644
index 00000000000..ee5e2c5a785
--- /dev/null
+++ b/dev-qt/qtdeclarative/qtdeclarative-5.14.2-r4.ebuild
@@ -0,0 +1,59 @@
+# Copyright 2009-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit python-any-r1 qt5-build
+
+DESCRIPTION="The QML and Quick modules for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+ KEYWORDS="amd64 arm arm64 ~hppa ppc ppc64 ~sparc x86"
+fi
+
+IUSE="gles2-only +jit localstorage vulkan +widgets"
+
+BDEPEND="${PYTHON_DEPS}"
+# qtgui[gles2-only=] is needed because of bug 504322
+DEPEND="
+ ~dev-qt/qtcore-${PV}
+ ~dev-qt/qtgui-${PV}:5=[gles2-only=,vulkan=]
+ ~dev-qt/qtnetwork-${PV}
+ ~dev-qt/qttest-${PV}
+ localstorage? ( ~dev-qt/qtsql-${PV} )
+ widgets? ( ~dev-qt/qtwidgets-${PV}[gles2-only=] )
+"
+RDEPEND="${DEPEND}
+ !<dev-qt/qtquickcontrols-5.7:5
+"
+
+PATCHES=(
+ "${FILESDIR}/${P}-QQuickItemView-fix-maxXY-extent.patch" # QTBUG-83890
+ "${FILESDIR}/${P}-fix-subpixel-positioned-text.patch" # QTBUG-49646
+ "${FILESDIR}/${P}-QQuickMouseArea-stuck-in-pressed-state.patch" # QTBUG-74987
+)
+
+src_prepare() {
+ use jit || PATCHES+=("${FILESDIR}/${PN}-5.4.2-disable-jit.patch")
+
+ qt_use_disable_mod localstorage sql \
+ src/imports/imports.pro
+
+ qt_use_disable_mod widgets widgets \
+ src/src.pro \
+ src/qmltest/qmltest.pro \
+ tests/auto/auto.pro \
+ tools/tools.pro \
+ tools/qmlscene/qmlscene.pro \
+ tools/qml/qml.pro
+
+ qt5-build_src_prepare
+}
+
+src_configure() {
+ local myqmakeargs=(
+ --
+ -qml-debug
+ )
+ qt5-build_src_configure
+}
diff --git a/dev-qt/qtdeclarative/qtdeclarative-5.15.0-r1.ebuild b/dev-qt/qtdeclarative/qtdeclarative-5.15.0-r1.ebuild
new file mode 100644
index 00000000000..0ee13270106
--- /dev/null
+++ b/dev-qt/qtdeclarative/qtdeclarative-5.15.0-r1.ebuild
@@ -0,0 +1,58 @@
+# Copyright 2009-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit python-any-r1 qt5-build
+
+DESCRIPTION="The QML and Quick modules for the Qt5 framework"
+
+if [[ ${QT5_BUILD_TYPE} == release ]]; then
+ KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+IUSE="gles2-only +jit localstorage vulkan +widgets"
+
+BDEPEND="${PYTHON_DEPS}"
+# qtgui[gles2-only=] is needed because of bug 504322
+DEPEND="
+ ~dev-qt/qtcore-${PV}
+ ~dev-qt/qtgui-${PV}:5=[gles2-only=,vulkan=]
+ ~dev-qt/qtnetwork-${PV}
+ ~dev-qt/qttest-${PV}
+ localstorage? ( ~dev-qt/qtsql-${PV} )
+ widgets? ( ~dev-qt/qtwidgets-${PV}[gles2-only=] )
+"
+RDEPEND="${DEPEND}
+ !<dev-qt/qtquickcontrols-5.7:5
+"
+
+PATCHES=(
+ "${FILESDIR}/${PN}-5.14.2-QQuickItemView-fix-maxXY-extent.patch" # QTBUG-83890
+ "${FILESDIR}/${PN}-5.14.2-fix-subpixel-positioned-text.patch" # QTBUG-49646
+)
+
+src_prepare() {
+ use jit || PATCHES+=("${FILESDIR}/${PN}-5.4.2-disable-jit.patch")
+
+ qt_use_disable_mod localstorage sql \
+ src/imports/imports.pro
+
+ qt_use_disable_mod widgets widgets \
+ src/src.pro \
+ src/qmltest/qmltest.pro \
+ tests/auto/auto.pro \
+ tools/tools.pro \
+ tools/qmlscene/qmlscene.pro \
+ tools/qml/qml.pro
+
+ qt5-build_src_prepare
+}
+
+src_configure() {
+ local myqmakeargs=(
+ --
+ -qml-debug
+ )
+ qt5-build_src_configure
+}